m4/sys_socket_h.m4

   1 # sys_socket_h.m4 serial 12
   2 dnl Copyright (C) 2005-2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson.
   8
   9 AC_DEFUN([gl_HEADER_SYS_SOCKET],
  10 [
  11   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
  12   AC_REQUIRE([AC_C_INLINE])
  13
  14   AC_CACHE_CHECK([whether <sys/socket.h> is self-contained],
  15     [gl_cv_header_sys_socket_h_selfcontained],
  16     [
  17       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]], [[]])],
  18         [gl_cv_header_sys_socket_h_selfcontained=yes],
  19         [gl_cv_header_sys_socket_h_selfcontained=no])
  20     ])
  21   if test $gl_cv_header_sys_socket_h_selfcontained = yes; then
  22     SYS_SOCKET_H=''
  23     dnl If the shutdown function exists, <sys/socket.h> should define
  24     dnl SHUT_RD, SHUT_WR, SHUT_RDWR.
  25     AC_CHECK_FUNCS([shutdown])
  26     if test $ac_cv_func_shutdown = yes; then
  27       AC_CACHE_CHECK([whether <sys/socket.h> defines the SHUT_* macros],
  28         [gl_cv_header_sys_socket_h_shut],
  29         [
  30           AC_COMPILE_IFELSE(
  31             [AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  32                [[int a[] = { SHUT_RD, SHUT_WR, SHUT_RDWR };]])],
  33             [gl_cv_header_sys_socket_h_shut=yes],
  34             [gl_cv_header_sys_socket_h_shut=no])
  35         ])
  36       if test $gl_cv_header_sys_socket_h_shut = no; then
  37         SYS_SOCKET_H='sys/socket.h'
  38       fi
  39     fi
  40   else
  41     SYS_SOCKET_H='sys/socket.h'
  42   fi
  43   # We need to check for ws2tcpip.h now.
  44   gl_PREREQ_SYS_H_SOCKET
  45   AC_CHECK_TYPES([struct sockaddr_storage, sa_family_t],,,[
  46   /* sys/types.h is not needed according to POSIX, but the
  47      sys/socket.h in i386-unknown-freebsd4.10 and
  48      powerpc-apple-darwin5.5 required it. */
  49 #include <sys/types.h>
  50 #ifdef HAVE_SYS_SOCKET_H
  51 #include <sys/socket.h>
  52 #endif
  53 #ifdef HAVE_WS2TCPIP_H
  54 #include <ws2tcpip.h>
  55 #endif
  56 ])
  57   if test $ac_cv_type_struct_sockaddr_storage = no; then
  58     HAVE_STRUCT_SOCKADDR_STORAGE=0
  59     SYS_SOCKET_H='sys/socket.h'
  60   fi
  61   if test $ac_cv_type_sa_family_t = no; then
  62     HAVE_SA_FAMILY_T=0
  63     SYS_SOCKET_H='sys/socket.h'
  64   fi
  65   if test -n "$SYS_SOCKET_H"; then
  66     gl_PREREQ_SYS_H_WINSOCK2
  67   fi
  68   AC_SUBST([SYS_SOCKET_H])
  69 ])
  70
  71 AC_DEFUN([gl_PREREQ_SYS_H_SOCKET],
  72 [
  73   dnl Check prerequisites of the <sys/socket.h> replacement.
  74   gl_CHECK_NEXT_HEADERS([sys/socket.h])
  75   if test $ac_cv_header_sys_socket_h = yes; then
  76     HAVE_SYS_SOCKET_H=1
  77     HAVE_WS2TCPIP_H=0
  78   else
  79     HAVE_SYS_SOCKET_H=0
  80     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
  81     dnl the check for those headers unconditional; yet cygwin reports
  82     dnl that the headers are present but cannot be compiled (since on
  83     dnl cygwin, all socket information should come from sys/socket.h).
  84     AC_CHECK_HEADERS([ws2tcpip.h])
  85     if test $ac_cv_header_ws2tcpip_h = yes; then
  86       HAVE_WS2TCPIP_H=1
  87     else
  88       HAVE_WS2TCPIP_H=0
  89     fi
  90   fi
  91   AC_SUBST([HAVE_SYS_SOCKET_H])
  92   AC_SUBST([HAVE_WS2TCPIP_H])
  93 ])
  94
  95 # Common prerequisites of the <sys/socket.h> replacement and of the
  96 # <sys/select.h> replacement.
  97 # Sets and substitutes HAVE_WINSOCK2_H.
  98 AC_DEFUN([gl_PREREQ_SYS_H_WINSOCK2],
  99 [
 100   m4_ifdef([gl_UNISTD_H_DEFAULTS], [AC_REQUIRE([gl_UNISTD_H_DEFAULTS])])
 101   m4_ifdef([gl_SYS_IOCTL_H_DEFAULTS], [AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])])
 102   AC_CHECK_HEADERS_ONCE([sys/socket.h])
 103   if test $ac_cv_header_sys_socket_h != yes; then
 104     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
 105     dnl the check for those headers unconditional; yet cygwin reports
 106     dnl that the headers are present but cannot be compiled (since on
 107     dnl cygwin, all socket information should come from sys/socket.h).
 108     AC_CHECK_HEADERS([winsock2.h])
 109   fi
 110   if test "$ac_cv_header_winsock2_h" = yes; then
 111     HAVE_WINSOCK2_H=1
 112     UNISTD_H_HAVE_WINSOCK2_H=1
 113     SYS_IOCTL_H_HAVE_WINSOCK2_H=1
 114   else
 115     HAVE_WINSOCK2_H=0
 116   fi
 117   AC_SUBST([HAVE_WINSOCK2_H])
 118 ])
 119
 120 AC_DEFUN([gl_SYS_SOCKET_MODULE_INDICATOR],
 121 [
 122   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
 123   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
 124   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
 125 ])
 126
 127 AC_DEFUN([gl_SYS_SOCKET_H_DEFAULTS],
 128 [
 129   GNULIB_SOCKET=0;      AC_SUBST([GNULIB_SOCKET])
 130   GNULIB_CONNECT=0;     AC_SUBST([GNULIB_CONNECT])
 131   GNULIB_ACCEPT=0;      AC_SUBST([GNULIB_ACCEPT])
 132   GNULIB_BIND=0;        AC_SUBST([GNULIB_BIND])
 133   GNULIB_GETPEERNAME=0; AC_SUBST([GNULIB_GETPEERNAME])
 134   GNULIB_GETSOCKNAME=0; AC_SUBST([GNULIB_GETSOCKNAME])
 135   GNULIB_GETSOCKOPT=0;  AC_SUBST([GNULIB_GETSOCKOPT])
 136   GNULIB_LISTEN=0;      AC_SUBST([GNULIB_LISTEN])
 137   GNULIB_RECV=0;        AC_SUBST([GNULIB_RECV])
 138   GNULIB_SEND=0;        AC_SUBST([GNULIB_SEND])
 139   GNULIB_RECVFROM=0;    AC_SUBST([GNULIB_RECVFROM])
 140   GNULIB_SENDTO=0;      AC_SUBST([GNULIB_SENDTO])
 141   GNULIB_SETSOCKOPT=0;  AC_SUBST([GNULIB_SETSOCKOPT])
 142   GNULIB_SHUTDOWN=0;    AC_SUBST([GNULIB_SHUTDOWN])
 143   HAVE_STRUCT_SOCKADDR_STORAGE=1; AC_SUBST([HAVE_STRUCT_SOCKADDR_STORAGE])
 144   HAVE_SA_FAMILY_T=1;   AC_SUBST([HAVE_SA_FAMILY_T])
 145 ])