m4/sys_times_h.m4

   1 # Configure a replacement for <sys/times.h>.
   2 # serial 3
   3
   4 # Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Simon Josefsson.
  10
  11 AC_DEFUN([gl_SYS_TIMES_H],
  12 [
  13   AC_REQUIRE([gl_SYS_TIMES_H_DEFAULTS])
  14
  15   gl_CHECK_NEXT_HEADERS([sys/times.h])
  16   AC_CHECK_HEADERS_ONCE([sys/times.h])
  17   if test $ac_cv_header_sys_times_h = yes; then
  18     HAVE_SYS_TIMES_H=1
  19     AC_CHECK_TYPES([struct tms], [], [HAVE_STRUCT_TMS=0], [[
  20 #include <sys/times.h>
  21       ]])
  22   else
  23     HAVE_SYS_TIMES_H=0
  24     HAVE_STRUCT_TMS=0
  25   fi
  26   AC_SUBST([HAVE_SYS_TIMES_H])
  27 ])
  28
  29 AC_DEFUN([gl_SYS_TIMES_MODULE_INDICATOR],
  30 [
  31   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  32   AC_REQUIRE([gl_SYS_TIMES_H_DEFAULTS])
  33   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  34 ])
  35
  36 AC_DEFUN([gl_SYS_TIMES_H_DEFAULTS],
  37 [
  38   GNULIB_TIMES=0;     AC_SUBST([GNULIB_TIMES])
  39   HAVE_STRUCT_TMS=1;  AC_SUBST([HAVE_STRUCT_TMS])
  40   HAVE_TIMES=1;       AC_SUBST([HAVE_TIMES])
  41 ])