m4/truncf.m4

   1 # truncf.m4 serial 1
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TRUNCF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare truncf().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   dnl Test whether truncf() is declared.
  13   AC_CHECK_DECLS([truncf], , , [#include <math.h>])
  14   if test "$ac_cv_have_decl_truncf" = yes; then
  15     dnl Test whether truncf() can be used without libm.
  16     TRUNCF_LIBM=?
  17     AC_TRY_LINK([
  18        #ifndef __NO_MATH_INLINES
  19        # define __NO_MATH_INLINES 1 /* for glibc */
  20        #endif
  21        #include <math.h>
  22        float x;],
  23       [x = truncf(x);],
  24       [TRUNCF_LIBM=])
  25     if test "$TRUNCF_LIBM" = "?"; then
  26       save_LIBS="$LIBS"
  27       LIBS="$LIBS -lm"
  28       AC_TRY_LINK([
  29          #ifndef __NO_MATH_INLINES
  30          # define __NO_MATH_INLINES 1 /* for glibc */
  31          #endif
  32          #include <math.h>
  33          float x;],
  34         [x = truncf(x);],
  35         [TRUNCF_LIBM="-lm"])
  36       LIBS="$save_LIBS"
  37     fi
  38     if test "$TRUNCF_LIBM" = "?"; then
  39       TRUNCF_LIBM=
  40     fi
  41   else
  42     HAVE_DECL_TRUNCF=0
  43     AC_LIBOBJ([truncf])
  44     TRUNCF_LIBM=
  45   fi
  46   AC_SUBST([HAVE_DECL_TRUNCF])
  47   AC_SUBST([TRUNCF_LIBM])
  48 ])