m4/truncl.m4

   1 # truncl.m4 serial 11
   2 dnl Copyright (C) 2007-2008, 2010-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TRUNCL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_truncl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  13
  14   dnl Persuade glibc <math.h> to declare truncl().
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl Test whether truncl() is declared.
  18   AC_CHECK_DECLS([truncl], , , [[#include <math.h>]])
  19   if test "$ac_cv_have_decl_truncl" = yes; then
  20     dnl Test whether truncl() can be used without libm.
  21     TRUNCL_LIBM=?
  22     AC_LINK_IFELSE(
  23       [AC_LANG_PROGRAM(
  24          [[#ifndef __NO_MATH_INLINES
  25            # define __NO_MATH_INLINES 1 /* for glibc */
  26            #endif
  27            #include <math.h>
  28            long double x;]],
  29          [[x = truncl(x);]])],
  30       [TRUNCL_LIBM=])
  31     if test "$TRUNCL_LIBM" = "?"; then
  32       save_LIBS="$LIBS"
  33       LIBS="$LIBS -lm"
  34       AC_LINK_IFELSE(
  35         [AC_LANG_PROGRAM(
  36            [[#ifndef __NO_MATH_INLINES
  37              # define __NO_MATH_INLINES 1 /* for glibc */
  38              #endif
  39              #include <math.h>
  40              long double x;]],
  41            [[x = truncl(x);]])],
  42         [TRUNCL_LIBM="-lm"])
  43       LIBS="$save_LIBS"
  44     fi
  45     if test "$TRUNCL_LIBM" = "?"; then
  46       TRUNCL_LIBM=
  47     fi
  48     dnl Test whether truncl() works. It crashes on OSF/1 4.0d.
  49     save_LIBS="$LIBS"
  50     LIBS="$LIBS $TRUNCL_LIBM"
  51     AC_CACHE_CHECK([whether truncl works], [gl_cv_func_truncl_works],
  52       [
  53         AC_RUN_IFELSE(
  54           [AC_LANG_SOURCE([[
  55 #include <math.h>
  56 long double x;
  57 int main()
  58 {
  59   x = truncl (0.0L);
  60   return 0;
  61 }]])],
  62           [gl_cv_func_truncl_works=yes],
  63           [gl_cv_func_truncl_works=no],
  64           [case "$host_os" in
  65              osf4*) gl_cv_func_truncl_works="guessing no";;
  66              *)     gl_cv_func_truncl_works="guessing yes";;
  67            esac
  68           ])
  69       ])
  70     LIBS="$save_LIBS"
  71     case "$gl_cv_func_truncl_works" in
  72       *yes) ;;
  73       *) REPLACE_TRUNCL=1 ;;
  74     esac
  75     m4_ifdef([gl_FUNC_TRUNCL_IEEE], [
  76       if test $gl_truncl_required = ieee && test $REPLACE_TRUNCL = 0; then
  77         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  78         AC_CACHE_CHECK([whether truncl works according to ISO C 99 with IEC 60559],
  79           [gl_cv_func_truncl_ieee],
  80           [
  81             save_LIBS="$LIBS"
  82             LIBS="$LIBS $TRUNCL_LIBM"
  83             AC_RUN_IFELSE(
  84               [AC_LANG_SOURCE([[
  85 #ifndef __NO_MATH_INLINES
  86 # define __NO_MATH_INLINES 1 /* for glibc */
  87 #endif
  88 #include <math.h>
  89 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  90 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  91 static long double dummy (long double f) { return 0; }
  92 int main (int argc, char *argv[])
  93 {
  94   long double (*my_truncl) (long double) = argc ? truncl : dummy;
  95   /* Test whether truncl (-0.3L) is -0.0L.  */
  96   if (signbitl (minus_zerol) && !signbitl (my_truncl (-0.3L)))
  97     return 1;
  98   return 0;
  99 }
 100               ]])],
 101               [gl_cv_func_truncl_ieee=yes],
 102               [gl_cv_func_truncl_ieee=no],
 103               [case "$host_os" in
 104                          # Guess yes on glibc systems.
 105                  *-gnu*) gl_cv_func_truncl_ieee="guessing yes" ;;
 106                          # If we don't know, assume the worst.
 107                  *)      gl_cv_func_truncl_ieee="guessing no" ;;
 108                esac
 109               ])
 110             LIBS="$save_LIBS"
 111           ])
 112         case "$gl_cv_func_truncl_ieee" in
 113           *yes) ;;
 114           *) REPLACE_TRUNCL=1 ;;
 115         esac
 116       fi
 117     ])
 118   else
 119     HAVE_DECL_TRUNCL=0
 120   fi
 121   if test $HAVE_DECL_TRUNCL = 0 || test $REPLACE_TRUNCL = 1; then
 122     dnl Find libraries needed to link lib/truncl.c.
 123     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
 124       AC_REQUIRE([gl_FUNC_TRUNC])
 125       TRUNCL_LIBM="$TRUNC_LIBM"
 126     else
 127       TRUNCL_LIBM=
 128     fi
 129   fi
 130   AC_SUBST([TRUNCL_LIBM])
 131 ])