m4/utimens.m4

   1 dnl Copyright (C) 2003-2011 Free Software Foundation, Inc.
   2 dnl This file is free software; the Free Software Foundation
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl serial 6
   7
   8 AC_DEFUN([gl_UTIMENS],
   9 [
  10   dnl Prerequisites of lib/utimens.c.
  11   AC_REQUIRE([gl_FUNC_UTIMES])
  12   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_TIMESPEC])
  13   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_UTIMBUF])
  14   AC_CHECK_FUNCS_ONCE([futimes futimesat futimens utimensat lutimes])
  15
  16   if test $ac_cv_func_futimens = no && test $ac_cv_func_futimesat = yes; then
  17     dnl FreeBSD 8.0-rc2 mishandles futimesat(fd,NULL,time).  It is not
  18     dnl standardized, but Solaris implemented it first and uses it as
  19     dnl its only means to set fd time.
  20     AC_CACHE_CHECK([whether futimesat handles NULL file],
  21       [gl_cv_func_futimesat_works],
  22       [touch conftest.file
  23        AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  24 #include <stddef.h>
  25 #include <sys/times.h>
  26 #include <fcntl.h>
  27 ]], [[    int fd = open ("conftest.file", O_RDWR);
  28           if (fd < 0) return 1;
  29           if (futimesat (fd, NULL, NULL)) return 2;
  30         ]])],
  31         [gl_cv_func_futimesat_works=yes],
  32         [gl_cv_func_futimesat_works=no],
  33         [gl_cv_func_futimesat_works="guessing no"])
  34       rm -f conftest.file])
  35     if test "$gl_cv_func_futimesat_works" != yes; then
  36       AC_DEFINE([FUTIMESAT_NULL_BUG], [1],
  37         [Define to 1 if futimesat mishandles a NULL file name.])
  38     fi
  39   fi
  40 ])