m4/vasnprintf-posix.m4

   1 # vasnprintf-posix.m4 serial 3
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  13   AC_REQUIRE([gl_PRINTF_POSITIONS])
  14   gl_cv_func_vasnprintf_posix=no
  15   AC_CHECK_FUNCS_ONCE([vasnprintf])
  16   case "$gl_cv_func_printf_sizes_c99" in
  17     *yes)
  18       case "$gl_cv_func_printf_directive_a" in
  19         *yes)
  20           case "$gl_cv_func_printf_directive_n" in
  21             *yes)
  22               case "$gl_cv_func_printf_positions" in
  23                 *yes)
  24                   if test $ac_cv_func_vasnprintf = yes; then
  25                     # vasnprintf exists and is already POSIX compliant.
  26                     gl_cv_func_vasnprintf_posix=yes
  27                   fi
  28                   ;;
  29               esac
  30               ;;
  31           esac
  32           ;;
  33       esac
  34       ;;
  35   esac
  36   if test $gl_cv_func_vasnprintf_posix = no; then
  37     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  38     gl_REPLACE_VASNPRINTF
  39   fi
  40 ])