m4/vasnprintf.m4

   1 # vasnprintf.m4 serial 11
   2 dnl Copyright (C) 2002-2004, 2006-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASNPRINTF],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_CHECK_FUNCS_ONCE([vasnprintf])
  11   if test $ac_cv_func_vasnprintf = no; then
  12     gl_REPLACE_VASNPRINTF
  13   fi
  14 ])
  15
  16 AC_DEFUN([gl_REPLACE_VASNPRINTF],
  17 [
  18   AC_CHECK_FUNCS_ONCE([vasnprintf])
  19   AC_LIBOBJ([vasnprintf])
  20   AC_LIBOBJ([printf-args])
  21   AC_LIBOBJ([printf-parse])
  22   AC_LIBOBJ([asnprintf])
  23   if test $ac_cv_func_vasnprintf = yes; then
  24     AC_DEFINE([REPLACE_VASNPRINTF], 1,
  25       [Define if vasnprintf exists but is overridden by gnulib.])
  26   fi
  27   gl_PREREQ_PRINTF_ARGS
  28   gl_PREREQ_PRINTF_PARSE
  29   gl_PREREQ_VASNPRINTF
  30   gl_PREREQ_ASNPRINTF
  31 ])
  32
  33 # Prequisites of lib/printf-args.h, lib/printf-args.c.
  34 AC_DEFUN([gl_PREREQ_PRINTF_ARGS],
  35 [
  36   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  37   AC_REQUIRE([gt_TYPE_LONGDOUBLE])
  38   AC_REQUIRE([gt_TYPE_WCHAR_T])
  39   AC_REQUIRE([gt_TYPE_WINT_T])
  40 ])
  41
  42 # Prequisites of lib/printf-parse.h, lib/printf-parse.c.
  43 AC_DEFUN([gl_PREREQ_PRINTF_PARSE],
  44 [
  45   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  46   AC_REQUIRE([gt_TYPE_LONGDOUBLE])
  47   AC_REQUIRE([gt_TYPE_WCHAR_T])
  48   AC_REQUIRE([gt_TYPE_WINT_T])
  49   AC_REQUIRE([AC_TYPE_SIZE_T])
  50   AC_CHECK_TYPES(ptrdiff_t)
  51   AC_REQUIRE([gt_AC_TYPE_INTMAX_T])
  52 ])
  53
  54 # Prerequisites of lib/vasnprintf.c.
  55 AC_DEFUN([gl_PREREQ_VASNPRINTF],
  56 [
  57   AC_REQUIRE([AC_FUNC_ALLOCA])
  58   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  59   AC_REQUIRE([gt_TYPE_LONGDOUBLE])
  60   AC_REQUIRE([gt_TYPE_WCHAR_T])
  61   AC_REQUIRE([gt_TYPE_WINT_T])
  62   AC_CHECK_FUNCS(snprintf wcslen)
  63 ])
  64
  65 # Extra prerequisites of lib/vasnprintf.c for supporting the 'a' directive.
  66 AC_DEFUN([gl_PREREQ_VASNPRINTF_DIRECTIVE_A],
  67 [
  68   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  69   case "$gl_cv_func_printf_directive_a" in
  70     *yes)
  71       ;;
  72     *)
  73       AC_DEFINE([NEED_PRINTF_DIRECTIVE_A], 1,
  74         [Define if the vasnprintf implementation needs special code for
  75          the 'a' and 'A' directives.])
  76       AC_CHECK_FUNCS([nl_langinfo])
  77       ;;
  78   esac
  79 ])
  80
  81 # Prerequisites of lib/asnprintf.c.
  82 AC_DEFUN([gl_PREREQ_ASNPRINTF],
  83 [
  84 ])