m4/wchar_h.m4

   1 dnl A placeholder for ISO C99 <wchar.h>, for platforms that have issues.
   2
   3 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Written by Eric Blake.
   9
  10 # wchar_h.m4 serial 37
  11
  12 AC_DEFUN([gl_WCHAR_H],
  13 [
  14   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  15   AC_REQUIRE([gl_WCHAR_H_INLINE_OK])
  16   dnl Prepare for creating substitute <wchar.h>.
  17   dnl Check for <wchar.h> (missing in Linux uClibc when built without wide
  18   dnl character support).
  19   dnl <wchar.h> is always overridden, because of GNULIB_POSIXCHECK.
  20   gl_CHECK_NEXT_HEADERS([wchar.h])
  21   if test $ac_cv_header_wchar_h = yes; then
  22     HAVE_WCHAR_H=1
  23   else
  24     HAVE_WCHAR_H=0
  25   fi
  26   AC_SUBST([HAVE_WCHAR_H])
  27
  28   AC_REQUIRE([gl_FEATURES_H])
  29
  30   AC_REQUIRE([gt_TYPE_WINT_T])
  31   if test $gt_cv_c_wint_t = yes; then
  32     HAVE_WINT_T=1
  33   else
  34     HAVE_WINT_T=0
  35   fi
  36   AC_SUBST([HAVE_WINT_T])
  37
  38   dnl Check for declarations of anything we want to poison if the
  39   dnl corresponding gnulib module is not in use.
  40   gl_WARN_ON_USE_PREPARE([[
  41 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  42    <wchar.h>.
  43    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
  44    included before <wchar.h>.  */
  45 #if !(defined __GLIBC__ && !defined __UCLIBC__)
  46 # include <stddef.h>
  47 # include <stdio.h>
  48 # include <time.h>
  49 #endif
  50 #include <wchar.h>
  51     ]], [btowc wctob mbsinit mbrtowc mbrlen mbsrtowcs mbsnrtowcs wcrtomb
  52     wcsrtombs wcsnrtombs wcwidth])
  53 ])
  54
  55 dnl Check whether <wchar.h> is usable at all.
  56 AC_DEFUN([gl_WCHAR_H_INLINE_OK],
  57 [
  58   dnl Test whether <wchar.h> suffers due to the transition from '__inline' to
  59   dnl 'gnu_inline'. See <http://sourceware.org/bugzilla/show_bug.cgi?id=4022>
  60   dnl and <http://gcc.gnu.org/bugzilla/show_bug.cgi?id=42440>. In summary,
  61   dnl glibc version 2.5 or older, together with gcc version 4.3 or newer and
  62   dnl the option -std=c99 or -std=gnu99, leads to a broken <wchar.h>.
  63   AC_CACHE_CHECK([whether <wchar.h> uses 'inline' correctly],
  64     [gl_cv_header_wchar_h_correct_inline],
  65     [gl_cv_header_wchar_h_correct_inline=yes
  66      AC_LANG_CONFTEST([
  67        AC_LANG_SOURCE([[#define wcstod renamed_wcstod
  68 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  69    <wchar.h>.
  70    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
  71    included before <wchar.h>.  */
  72 #include <stddef.h>
  73 #include <stdio.h>
  74 #include <time.h>
  75 #include <wchar.h>
  76 extern int zero (void);
  77 int main () { return zero(); }
  78 ]])])
  79      if AC_TRY_EVAL([ac_compile]); then
  80        mv conftest.$ac_objext conftest1.$ac_objext
  81        AC_LANG_CONFTEST([
  82          AC_LANG_SOURCE([[#define wcstod renamed_wcstod
  83 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  84    <wchar.h>.
  85    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
  86    included before <wchar.h>.  */
  87 #include <stddef.h>
  88 #include <stdio.h>
  89 #include <time.h>
  90 #include <wchar.h>
  91 int zero (void) { return 0; }
  92 ]])])
  93        if AC_TRY_EVAL([ac_compile]); then
  94          mv conftest.$ac_objext conftest2.$ac_objext
  95          if $CC -o conftest$ac_exeext $CFLAGS $LDFLAGS conftest1.$ac_objext conftest2.$ac_objext $LIBS >&AS_MESSAGE_LOG_FD 2>&1; then
  96            :
  97          else
  98            gl_cv_header_wchar_h_correct_inline=no
  99          fi
 100        fi
 101      fi
 102      rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 103     ])
 104   if test $gl_cv_header_wchar_h_correct_inline = no; then
 105     AC_MSG_ERROR([<wchar.h> cannot be used with this compiler ($CC $CFLAGS $CPPFLAGS).
 106 This is a known interoperability problem of glibc <= 2.5 with gcc >= 4.3 in
 107 C99 mode. You have four options:
 108   - Add the flag -fgnu89-inline to CC and reconfigure, or
 109   - Fix your include files, using parts of
 110     <http://sourceware.org/git/?p=glibc.git;a=commitdiff;h=b037a293a48718af30d706c2e18c929d0e69a621>, or
 111   - Use a gcc version older than 4.3, or
 112   - Don't use the flags -std=c99 or -std=gnu99.
 113 Configuration aborted.])
 114   fi
 115 ])
 116
 117 dnl Unconditionally enables the replacement of <wchar.h>.
 118 AC_DEFUN([gl_REPLACE_WCHAR_H],
 119 [
 120   dnl This is a no-op, because <wchar.h> is always overridden.
 121   :
 122 ])
 123
 124 AC_DEFUN([gl_WCHAR_MODULE_INDICATOR],
 125 [
 126   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
 127   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
 128   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
 129   dnl Define it also as a C macro, for the benefit of the unit tests.
 130   gl_MODULE_INDICATOR_FOR_TESTS([$1])
 131 ])
 132
 133 AC_DEFUN([gl_WCHAR_H_DEFAULTS],
 134 [
 135   GNULIB_BTOWC=0;      AC_SUBST([GNULIB_BTOWC])
 136   GNULIB_WCTOB=0;      AC_SUBST([GNULIB_WCTOB])
 137   GNULIB_MBSINIT=0;    AC_SUBST([GNULIB_MBSINIT])
 138   GNULIB_MBRTOWC=0;    AC_SUBST([GNULIB_MBRTOWC])
 139   GNULIB_MBRLEN=0;     AC_SUBST([GNULIB_MBRLEN])
 140   GNULIB_MBSRTOWCS=0;  AC_SUBST([GNULIB_MBSRTOWCS])
 141   GNULIB_MBSNRTOWCS=0; AC_SUBST([GNULIB_MBSNRTOWCS])
 142   GNULIB_WCRTOMB=0;    AC_SUBST([GNULIB_WCRTOMB])
 143   GNULIB_WCSRTOMBS=0;  AC_SUBST([GNULIB_WCSRTOMBS])
 144   GNULIB_WCSNRTOMBS=0; AC_SUBST([GNULIB_WCSNRTOMBS])
 145   GNULIB_WCWIDTH=0;    AC_SUBST([GNULIB_WCWIDTH])
 146   dnl Assume proper GNU behavior unless another module says otherwise.
 147   HAVE_BTOWC=1;         AC_SUBST([HAVE_BTOWC])
 148   HAVE_MBSINIT=1;       AC_SUBST([HAVE_MBSINIT])
 149   HAVE_MBRTOWC=1;       AC_SUBST([HAVE_MBRTOWC])
 150   HAVE_MBRLEN=1;        AC_SUBST([HAVE_MBRLEN])
 151   HAVE_MBSRTOWCS=1;     AC_SUBST([HAVE_MBSRTOWCS])
 152   HAVE_MBSNRTOWCS=1;    AC_SUBST([HAVE_MBSNRTOWCS])
 153   HAVE_WCRTOMB=1;       AC_SUBST([HAVE_WCRTOMB])
 154   HAVE_WCSRTOMBS=1;     AC_SUBST([HAVE_WCSRTOMBS])
 155   HAVE_WCSNRTOMBS=1;    AC_SUBST([HAVE_WCSNRTOMBS])
 156   HAVE_DECL_WCTOB=1;    AC_SUBST([HAVE_DECL_WCTOB])
 157   HAVE_DECL_WCWIDTH=1;  AC_SUBST([HAVE_DECL_WCWIDTH])
 158   REPLACE_MBSTATE_T=0;  AC_SUBST([REPLACE_MBSTATE_T])
 159   REPLACE_BTOWC=0;      AC_SUBST([REPLACE_BTOWC])
 160   REPLACE_WCTOB=0;      AC_SUBST([REPLACE_WCTOB])
 161   REPLACE_MBSINIT=0;    AC_SUBST([REPLACE_MBSINIT])
 162   REPLACE_MBRTOWC=0;    AC_SUBST([REPLACE_MBRTOWC])
 163   REPLACE_MBRLEN=0;     AC_SUBST([REPLACE_MBRLEN])
 164   REPLACE_MBSRTOWCS=0;  AC_SUBST([REPLACE_MBSRTOWCS])
 165   REPLACE_MBSNRTOWCS=0; AC_SUBST([REPLACE_MBSNRTOWCS])
 166   REPLACE_WCRTOMB=0;    AC_SUBST([REPLACE_WCRTOMB])
 167   REPLACE_WCSRTOMBS=0;  AC_SUBST([REPLACE_WCSRTOMBS])
 168   REPLACE_WCSNRTOMBS=0; AC_SUBST([REPLACE_WCSNRTOMBS])
 169   REPLACE_WCWIDTH=0;    AC_SUBST([REPLACE_WCWIDTH])
 170 ])