m4/wcsrtombs.m4

   1 # wcsrtombs.m4 serial 4
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCSRTOMBS],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   AC_REQUIRE([AC_TYPE_MBSTATE_T])
  12   gl_MBSTATE_T_BROKEN
  13   if test $REPLACE_MBSTATE_T = 1; then
  14     REPLACE_WCSRTOMBS=1
  15   fi
  16   AC_CHECK_FUNCS_ONCE([wcsrtombs])
  17   if test $ac_cv_func_wcsrtombs = no; then
  18     HAVE_WCSRTOMBS=0
  19   fi
  20   if test $HAVE_WCSRTOMBS != 0 && test $REPLACE_WCSRTOMBS != 1; then
  21     gl_WCSRTOMBS_TERMINATION
  22     gl_WCSRTOMBS_NULL
  23     case "$gl_cv_func_wcsrtombs_termination" in
  24       *yes) ;;
  25       *) AC_DEFINE([WCSRTOMBS_TERMINATION_BUG], [1],
  26            [Define if the wcsrtombs function may set the source pointer to NULL without NUL-terminating the destination.])
  27          REPLACE_WCSRTOMBS=1 ;;
  28     esac
  29     case "$gl_cv_func_wcsrtombs_null" in
  30       *yes) ;;
  31       *) AC_DEFINE([WCSRTOMBS_NULL_ARG_BUG], [1],
  32            [Define if the wcsrtombs function has the NULL destination argument bug.])
  33          REPLACE_WCSRTOMBS=1 ;;
  34     esac
  35   fi
  36   if test $HAVE_WCSRTOMBS = 0 || test $REPLACE_WCSRTOMBS = 1; then
  37     gl_REPLACE_WCHAR_H
  38     AC_LIBOBJ([wcsrtombs])
  39     AC_LIBOBJ([wcsrtombs-state])
  40     gl_PREREQ_WCSRTOMBS
  41   fi
  42 ])
  43
  44 dnl Test whether the wcsrtombs implementation stores a non-NULL source pointer
  45 dnl as long as it has not written the final NUL byte to the destination string.
  46 dnl The OSF/1 5.1 implementation stores a NULL pointer already after storing
  47 dnl the last non-NUL character, even if there is no more room for the
  48 dnl terminating NUL character.
  49 dnl Result is gl_cv_func_wcsrtombs_termination.
  50
  51 AC_DEFUN([gl_WCSRTOMBS_TERMINATION],
  52 [
  53   AC_REQUIRE([AC_PROG_CC])
  54   AC_REQUIRE([gt_LOCALE_FR])
  55   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  56   AC_CACHE_CHECK([whether wcsrtombs updates the source pointer correctly],
  57     [gl_cv_func_wcsrtombs_termination],
  58     [
  59       dnl Initial guess, used when cross-compiling or when no suitable locale
  60       dnl is present.
  61 changequote(,)dnl
  62       case "$host_os" in
  63               # Guess no on OSF/1.
  64         osf*) gl_cv_func_wcsrtombs_termination="guessing no" ;;
  65               # Guess yes otherwise.
  66         *)    gl_cv_func_wcsrtombs_termination="guessing yes" ;;
  67       esac
  68 changequote([,])dnl
  69       if test $LOCALE_FR != none; then
  70         AC_TRY_RUN([
  71 #include <locale.h>
  72 #include <stdlib.h>
  73 #include <wchar.h>
  74 int main ()
  75 {
  76   if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
  77     {
  78       const char original[] = "B\374\337er";
  79       wchar_t input[10];
  80
  81       if (mbstowcs (input, original, 10) == 5)
  82         {
  83           const wchar_t *src = input;
  84           char output[5];
  85           wcsrtombs (output, &src, 5, NULL);
  86           if (src != input + 5)
  87             return 1;
  88         }
  89     }
  90   return 0;
  91 }],
  92           [gl_cv_func_wcsrtombs_termination=yes],
  93           [gl_cv_func_wcsrtombs_termination=no],
  94           [:])
  95       fi
  96     ])
  97 ])
  98
  99 dnl Test whether the wcsrtombs implementation supports a NULL argument
 100 dnl correctly. This is not the case on HP-UX 11.11 and OSF/1 5.1: These
 101 dnl implementations updates the source pointer also if the destination argument
 102 dnl is NULL.
 103 dnl Result is gl_cv_func_wcsrtombs_null.
 104
 105 AC_DEFUN([gl_WCSRTOMBS_NULL],
 106 [
 107   AC_REQUIRE([AC_PROG_CC])
 108   AC_REQUIRE([gt_LOCALE_FR])
 109   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 110   AC_CACHE_CHECK([whether wcsrtombs supports a NULL argument correctly],
 111     [gl_cv_func_wcsrtombs_null],
 112     [
 113       dnl Initial guess, used when cross-compiling or when no suitable locale
 114       dnl is present.
 115 changequote(,)dnl
 116       case "$host_os" in
 117                       # Guess no on HP-UX and OSF/1.
 118         hpux* | osf*) gl_cv_func_wcsrtombs_null="guessing no" ;;
 119                       # Guess yes otherwise.
 120         *)            gl_cv_func_wcsrtombs_null="guessing yes" ;;
 121       esac
 122 changequote([,])dnl
 123       if test $LOCALE_FR != none; then
 124         AC_TRY_RUN([
 125 #include <locale.h>
 126 #include <stdlib.h>
 127 #include <wchar.h>
 128 int main ()
 129 {
 130   if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
 131     {
 132       const char original[] = "B\374\337er";
 133       wchar_t input[10];
 134
 135       if (mbstowcs (input, original, 10) == 5)
 136         {
 137           const wchar_t *src = input;
 138           wcsrtombs (NULL, &src, 10, NULL);
 139           if (src != input)
 140             return 1;
 141         }
 142     }
 143   return 0;
 144 }],
 145           [gl_cv_func_wcsrtombs_null=yes],
 146           [gl_cv_func_wcsrtombs_null=no],
 147           [:])
 148       fi
 149     ])
 150 ])
 151
 152 # Prerequisites of lib/wcsrtombs.c.
 153 AC_DEFUN([gl_PREREQ_WCSRTOMBS], [
 154   :
 155 ])