m4/wctype_h.m4

   1 # wctype_h.m4 serial 14
   2
   3 dnl A placeholder for ISO C99 <wctype.h>, for platforms that lack it.
   4
   5 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   6 dnl This file is free software; the Free Software Foundation
   7 dnl gives unlimited permission to copy and/or distribute it,
   8 dnl with or without modifications, as long as this notice is preserved.
   9
  10 dnl Written by Paul Eggert.
  11
  12 AC_DEFUN([gl_WCTYPE_H],
  13 [
  14   AC_REQUIRE([gl_WCTYPE_H_DEFAULTS])
  15   AC_REQUIRE([AC_PROG_CC])
  16   AC_REQUIRE([AC_CANONICAL_HOST])
  17   AC_CHECK_FUNCS_ONCE([iswcntrl])
  18   if test $ac_cv_func_iswcntrl = yes; then
  19     HAVE_ISWCNTRL=1
  20   else
  21     HAVE_ISWCNTRL=0
  22   fi
  23   AC_SUBST([HAVE_ISWCNTRL])
  24
  25   AC_REQUIRE([AC_C_INLINE])
  26
  27   AC_REQUIRE([gt_TYPE_WINT_T])
  28   if test $gt_cv_c_wint_t = yes; then
  29     HAVE_WINT_T=1
  30   else
  31     HAVE_WINT_T=0
  32   fi
  33   AC_SUBST([HAVE_WINT_T])
  34
  35   gl_CHECK_NEXT_HEADERS([wctype.h])
  36   if test $ac_cv_header_wctype_h = yes; then
  37     if test $ac_cv_func_iswcntrl = yes; then
  38       dnl Linux libc5 has an iswprint function that returns 0 for all arguments.
  39       dnl The other functions are likely broken in the same way.
  40       AC_CACHE_CHECK([whether iswcntrl works], [gl_cv_func_iswcntrl_works],
  41         [
  42           AC_RUN_IFELSE(
  43             [AC_LANG_SOURCE([[
  44                /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
  45                   included before <wchar.h>.
  46                   BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
  47                   must be included before <wchar.h>.  */
  48                #include <stddef.h>
  49                #include <stdio.h>
  50                #include <time.h>
  51                #include <wchar.h>
  52                #include <wctype.h>
  53                int main () { return iswprint ('x') == 0; }
  54             ]])],
  55             [gl_cv_func_iswcntrl_works=yes], [gl_cv_func_iswcntrl_works=no],
  56             [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
  57                           #if __GNU_LIBRARY__ == 1
  58                           Linux libc5 i18n is broken.
  59                           #endif]], [])],
  60               [gl_cv_func_iswcntrl_works=yes], [gl_cv_func_iswcntrl_works=no])
  61             ])
  62         ])
  63     fi
  64     HAVE_WCTYPE_H=1
  65   else
  66     HAVE_WCTYPE_H=0
  67   fi
  68   AC_SUBST([HAVE_WCTYPE_H])
  69
  70   if test "$gl_cv_func_iswcntrl_works" = no; then
  71     REPLACE_ISWCNTRL=1
  72   else
  73     REPLACE_ISWCNTRL=0
  74   fi
  75   AC_SUBST([REPLACE_ISWCNTRL])
  76
  77   if test $HAVE_ISWCNTRL = 0 || test $REPLACE_ISWCNTRL = 1; then
  78     dnl Redefine all of iswcntrl, ..., towupper in <wctype.h>.
  79     :
  80   fi
  81
  82   dnl We assume that the wctype() and iswctype() functions exist if and only
  83   dnl if the type wctype_t is defined in <wchar.h> or in <wctype.h> if that
  84   dnl exists.
  85   dnl HP-UX 11.00 declares all these in <wchar.h> and lacks <wctype.h>.
  86   AC_CACHE_CHECK([for wctype_t], [gl_cv_type_wctype_t],
  87     [AC_COMPILE_IFELSE(
  88        [AC_LANG_PROGRAM(
  89           [[/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
  90                included before <wchar.h>.
  91                BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
  92                must be included before <wchar.h>.  */
  93             #include <stddef.h>
  94             #include <stdio.h>
  95             #include <time.h>
  96             #include <wchar.h>
  97             #if HAVE_WCTYPE_H
  98             # include <wctype.h>
  99             #endif
 100             wctype_t a;
 101           ]],
 102           [[]])],
 103        [gl_cv_type_wctype_t=yes],
 104        [gl_cv_type_wctype_t=no])
 105     ])
 106   if test $gl_cv_type_wctype_t = no; then
 107     HAVE_WCTYPE_T=0
 108   fi
 109
 110   dnl We assume that the wctrans() and towctrans() functions exist if and only
 111   dnl if the type wctrans_t is defined in <wctype.h>.
 112   AC_CACHE_CHECK([for wctrans_t], [gl_cv_type_wctrans_t],
 113     [AC_COMPILE_IFELSE(
 114        [AC_LANG_PROGRAM(
 115           [[/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
 116                included before <wchar.h>.
 117                BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
 118                must be included before <wchar.h>.  */
 119             #include <stddef.h>
 120             #include <stdio.h>
 121             #include <time.h>
 122             #include <wchar.h>
 123             #include <wctype.h>
 124             wctrans_t a;
 125           ]],
 126           [[]])],
 127        [gl_cv_type_wctrans_t=yes],
 128        [gl_cv_type_wctrans_t=no])
 129     ])
 130   if test $gl_cv_type_wctrans_t = no; then
 131     HAVE_WCTRANS_T=0
 132   fi
 133
 134   dnl Check for declarations of anything we want to poison if the
 135   dnl corresponding gnulib module is not in use.
 136   gl_WARN_ON_USE_PREPARE([[
 137 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
 138    <wchar.h>.
 139    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 140    included before <wchar.h>.  */
 141 #if !(defined __GLIBC__ && !defined __UCLIBC__)
 142 # include <stddef.h>
 143 # include <stdio.h>
 144 # include <time.h>
 145 # include <wchar.h>
 146 #endif
 147 #include <wctype.h>
 148     ]],
 149     [wctype iswctype wctrans towctrans
 150     ])
 151 ])
 152
 153 AC_DEFUN([gl_WCTYPE_MODULE_INDICATOR],
 154 [
 155   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
 156   AC_REQUIRE([gl_WCTYPE_H_DEFAULTS])
 157   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
 158   dnl Define it also as a C macro, for the benefit of the unit tests.
 159   gl_MODULE_INDICATOR_FOR_TESTS([$1])
 160 ])
 161
 162 AC_DEFUN([gl_WCTYPE_H_DEFAULTS],
 163 [
 164   GNULIB_ISWBLANK=0;    AC_SUBST([GNULIB_ISWBLANK])
 165   GNULIB_WCTYPE=0;      AC_SUBST([GNULIB_WCTYPE])
 166   GNULIB_ISWCTYPE=0;    AC_SUBST([GNULIB_ISWCTYPE])
 167   GNULIB_WCTRANS=0;     AC_SUBST([GNULIB_WCTRANS])
 168   GNULIB_TOWCTRANS=0;   AC_SUBST([GNULIB_TOWCTRANS])
 169   dnl Assume proper GNU behavior unless another module says otherwise.
 170   HAVE_ISWBLANK=1;      AC_SUBST([HAVE_ISWBLANK])
 171   HAVE_WCTYPE_T=1;      AC_SUBST([HAVE_WCTYPE_T])
 172   HAVE_WCTRANS_T=1;     AC_SUBST([HAVE_WCTRANS_T])
 173   REPLACE_ISWBLANK=0;   AC_SUBST([REPLACE_ISWBLANK])
 174 ])