m4/wmemmove.m4

   1 # wmemmove.m4 serial 3
   2 dnl Copyright (C) 2011-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WMEMMOVE],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   dnl We cannot use AC_CHECK_FUNCS here, because the MSVC 9 header files
  11   dnl provide this function as an inline function definition.
  12   AC_CACHE_CHECK([for wmemmove], [gl_cv_func_wmemmove],
  13     [AC_COMPILE_IFELSE(
  14        [AC_LANG_PROGRAM([[
  15 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  16    <wchar.h>.
  17    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  18    before <wchar.h>.  */
  19 #include <stddef.h>
  20 #include <stdio.h>
  21 #include <time.h>
  22 #include <wchar.h>
  23 ]],
  24           [[return ! wmemmove ((wchar_t *) 0, (const wchar_t *) 0, 0);]])
  25        ],
  26        [gl_cv_func_wmemmove=yes],
  27        [gl_cv_func_wmemmove=no])
  28     ])
  29   if test $gl_cv_func_wmemmove = no; then
  30     HAVE_WMEMMOVE=0
  31   fi
  32 ])