logf-ieee: Work around test failure on NetBSD 5.1.

* m4/logf-ieee.m4: New file.
* m4/logf.m4 (gl_FUNC_LOGF): If gl_FUNC_LOGF_IEEE is present, test
whether logf works with a negative argument. Replace it if not.
* lib/logf.c (logf): For negative arguments, return NaN.
* modules/logf-ieee (Files): Add m4/logf-ieee.m4.
(configure.ac): Invoke gl_FUNC_LOGF_IEEE.
* doc/posix-functions/logf.texi: Mention the logf-ieee module.

diff --git a/ChangeLog b/ChangeLog
index c704591..ef956bd 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,14 @@
 2012-03-10  Bruno Haible  <bruno@clisp.org>
 
+       logf-ieee: Work around test failure on NetBSD 5.1.
+       * m4/logf-ieee.m4: New file.
+       * m4/logf.m4 (gl_FUNC_LOGF): If gl_FUNC_LOGF_IEEE is present, test
+       whether logf works with a negative argument. Replace it if not.
+       * lib/logf.c (logf): For negative arguments, return NaN.
+       * modules/logf-ieee (Files): Add m4/logf-ieee.m4.
+       (configure.ac): Invoke gl_FUNC_LOGF_IEEE.
+       * doc/posix-functions/logf.texi: Mention the logf-ieee module.
+
        logf-ieee: Work around test failure on Solaris 9.
        * modules/logf-ieee (Depends-on): Add log-ieee.
        (configure.ac): Require gl_FUNC_LOGF.

diff --git a/doc/posix-functions/logf.texi b/doc/posix-functions/logf.texi
index 21b5f74..38965a7 100644 (file)
--- a/doc/posix-functions/logf.texi
+++ b/doc/posix-functions/logf.texi
@@ -4,9 +4,9 @@
 
 POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/functions/logf.html}
 
-Gnulib module: logf
+Gnulib module: logf or logf-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{logf} or @code{logf-ieee}:
 @itemize
 @item
 This function is missing on some platforms:
@@ -19,6 +19,13 @@ This function returns a wrong value for a minus zero argument on some platforms:
 OSF/1 5.1.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{logf-ieee}:
+@itemize
+@item
+This function returns a wrong value for a negative argument on some platforms:
+NetBSD 5.1.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize

diff --git a/lib/logf.c b/lib/logf.c
index 3bf0f13..f2d5250 100644 (file)
--- a/lib/logf.c
+++ b/lib/logf.c
@@ -24,10 +24,17 @@ logf (float x)
 #undef logf
 {
 #if HAVE_LOGF
-  /* Work around the OSF/1 5.1 bug.  */
-  if (x == 0.0f)
-    /* Return -Infinity.  */
-    return -1.0f / 0.0f;
+  if (x <= 0.0f)
+    {
+      /* Work around the OSF/1 5.1 bug.  */
+      if (x == 0.0f)
+        /* Return -Infinity.  */
+        return -1.0f / 0.0f;
+      /* Work around the NetBSD 5.1 bug.  */
+      else /* x < 0.0 */
+        /* Return NaN.  */
+        return 0.0f / 0.0f;
+    }
   return logf (x);
 #else
   return (float) log ((double) x);

diff --git a/m4/logf-ieee.m4 b/m4/logf-ieee.m4
new file mode 100644 (file)
index 0000000..e57f875
--- /dev/null
+++ b/m4/logf-ieee.m4
@@ -0,0 +1,15 @@
+# logf-ieee.m4 serial 1
+dnl Copyright (C) 2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in remainder.m4 and not inlined in the
+dnl module description), so that gl_FUNC_LOGF can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_LOGF_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_logf_required=ieee])
+  AC_REQUIRE([gl_FUNC_LOGF])
+])

diff --git a/m4/logf.m4 b/m4/logf.m4
index 0e4fa5d..3d000c0 100644 (file)
--- a/m4/logf.m4
+++ b/m4/logf.m4
@@ -1,4 +1,4 @@
-# logf.m4 serial 3
+# logf.m4 serial 4
 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_LOGF],
 [
+  m4_divert_text([DEFAULTS], [gl_logf_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   AC_REQUIRE([gl_FUNC_LOG])
 
@@ -20,6 +21,7 @@ AC_DEFUN([gl_FUNC_LOGF],
   LIBS="$save_LIBS"
   if test $ac_cv_func_logf = yes; then
     LOGF_LIBM="$LOG_LIBM"
+
     save_LIBS="$LIBS"
     LIBS="$LIBS $LOGF_LIBM"
     gl_FUNC_LOGF_WORKS
@@ -28,6 +30,51 @@ AC_DEFUN([gl_FUNC_LOGF],
       *yes) ;;
       *) REPLACE_LOGF=1 ;;
     esac
+
+    m4_ifdef([gl_FUNC_LOGF_IEEE], [
+      if test $gl_logf_required = ieee && test $REPLACE_LOGF = 0; then
+        AC_CACHE_CHECK([whether logf works according to ISO C 99 with IEC 60559],
+          [gl_cv_func_logf_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $LOGF_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (float x, float y)
+{
+  return x == y;
+}
+static float dummy (float x) { return 0; }
+int main (int argc, char *argv[])
+{
+  float (*my_log) (float) = argc ? logf : dummy;
+  /* Test logf(negative).
+     This test fails on NetBSD 5.1.  */
+  float y = my_logf (-1.0f);
+  if (numeric_equal (y, y))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_logf_ieee=yes],
+              [gl_cv_func_logf_ieee=no],
+              [gl_cv_func_logf_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_logf_ieee" in
+          *yes) ;;
+          *) REPLACE_LOGF=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_LOGF=0
   fi

diff --git a/modules/logf-ieee b/modules/logf-ieee
index 1d77dbe..061db33 100644 (file)
--- a/modules/logf-ieee
+++ b/modules/logf-ieee
@@ -2,6 +2,7 @@ Description:
 logf() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/logf-ieee.m4
 
 Depends-on:
 logf
@@ -9,7 +10,7 @@ fpieee
 log-ieee        [test $HAVE_LOGF = 0 || test $REPLACE_LOGF = 1]
 
 configure.ac:
-AC_REQUIRE([gl_FUNC_LOGF])
+gl_FUNC_LOGF_IEEE
 
 Makefile.am: