log2f-ieee: Work around test failure on NetBSD 5.1 and Solaris 10.

* m4/log2f-ieee.m4: New file.
* m4/log2f.m4 (gl_FUNC_LOG2F): If gl_FUNC_LOG2F_IEEE is present, test
whether log2f works with a minus zero argument. Replace it if not.
* modules/log2f-ieee (Files): Add m4/log2f-ieee.m4.
(Depends-on): Add log2-ieee.
(configure.ac): Invoke gl_FUNC_LOG2F_IEEE.
* doc/posix-functions/log2f.texi: Mention the log2f-ieee module.

diff --git a/ChangeLog b/ChangeLog
index e4963bd..e286b73 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,14 @@
 2012-03-11  Bruno Haible  <bruno@clisp.org>
 
+       log2f-ieee: Work around test failure on NetBSD 5.1 and Solaris 10.
+       * m4/log2f-ieee.m4: New file.
+       * m4/log2f.m4 (gl_FUNC_LOG2F): If gl_FUNC_LOG2F_IEEE is present, test
+       whether log2f works with a minus zero argument. Replace it if not.
+       * modules/log2f-ieee (Files): Add m4/log2f-ieee.m4.
+       (Depends-on): Add log2-ieee.
+       (configure.ac): Invoke gl_FUNC_LOG2F_IEEE.
+       * doc/posix-functions/log2f.texi: Mention the log2f-ieee module.
+
        log2-ieee: Work around test failure on NetBSD 5.1 and Solaris 10.
        * m4/log2-ieee.m4: New file.
        * m4/log2.m4 (gl_FUNC_LOG2): If gl_FUNC_LOG2_IEEE is present, test

diff --git a/doc/posix-functions/log2f.texi b/doc/posix-functions/log2f.texi
index ac6d182..f137ed1 100644 (file)
--- a/doc/posix-functions/log2f.texi
+++ b/doc/posix-functions/log2f.texi
@@ -4,9 +4,9 @@
 
 POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/functions/log2f.html}
 
-Gnulib module: log2f
+Gnulib module: log2f or log2f-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{log2f} or @code{log2f-ieee}:
 @itemize
 @item
 This function is missing on some platforms:
@@ -26,6 +26,13 @@ This function returns slightly wrong values for exact powers of 2 on some platfo
 Cygwin 1.7.9.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{log2f-ieee}:
+@itemize
+@item
+This function returns a wrong value for a negative argument on some platforms:
+NetBSD 5.1, Solaris 11 2011-11.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize

diff --git a/m4/log2f-ieee.m4 b/m4/log2f-ieee.m4
new file mode 100644 (file)
index 0000000..8b699ee
--- /dev/null
+++ b/m4/log2f-ieee.m4
@@ -0,0 +1,15 @@
+# log2f-ieee.m4 serial 1
+dnl Copyright (C) 2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in remainder.m4 and not inlined in the
+dnl module description), so that gl_FUNC_LOG2F can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_LOG2F_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_log2f_required=ieee])
+  AC_REQUIRE([gl_FUNC_LOG2F])
+])

diff --git a/m4/log2f.m4 b/m4/log2f.m4
index 4ff32d8..d9fffd0 100644 (file)
--- a/m4/log2f.m4
+++ b/m4/log2f.m4
@@ -1,4 +1,4 @@
-# log2f.m4 serial 1
+# log2f.m4 serial 2
 dnl Copyright (C) 2010-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_LOG2F],
 [
+  m4_divert_text([DEFAULTS], [gl_log2f_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   AC_REQUIRE([gl_FUNC_LOG2])
 
@@ -34,6 +35,58 @@ AC_DEFUN([gl_FUNC_LOG2F],
       *yes) ;;
       *) REPLACE_LOG2F=1 ;;
     esac
+
+    m4_ifdef([gl_FUNC_LOG2F_IEEE], [
+      if test $gl_log2f_required = ieee && test $REPLACE_LOG2F = 0; then
+        AC_CACHE_CHECK([whether log2f works according to ISO C 99 with IEC 60559],
+          [gl_cv_func_log2f_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $LOG2F_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+#ifndef log2f /* for Cygwin 1.7.x */
+extern
+#ifdef __cplusplus
+"C"
+#endif
+float log2f (float);
+#endif
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (float x, float y)
+{
+  return x == y;
+}
+static float dummy (float x) { return 0; }
+int main (int argc, char *argv[])
+{
+  float (*my_log2f) (float) = argc ? log2f : dummy;
+  /* Test log2f(negative).
+     This test fails on NetBSD 5.1 and Solaris 11 2011-11.  */
+  float y = my_log2f (-1.0f);
+  if (numeric_equal (y, y))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_log2f_ieee=yes],
+              [gl_cv_func_log2f_ieee=no],
+              [gl_cv_func_log2f_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_log2f_ieee" in
+          *yes) ;;
+          *) REPLACE_LOG2F=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_LOG2F=0
     HAVE_DECL_LOG2F=0

diff --git a/modules/log2f-ieee b/modules/log2f-ieee
index 5849a91..27ed2d0 100644 (file)
--- a/modules/log2f-ieee
+++ b/modules/log2f-ieee
@@ -2,12 +2,15 @@ Description:
 log2f() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/log2f-ieee.m4
 
 Depends-on:
 log2f
 fpieee
+log2-ieee       [test $HAVE_LOG2F = 0 || test $REPLACE_LOG2F = 1]
 
 configure.ac:
+gl_FUNC_LOG2F_IEEE
 
 Makefile.am: