cbrtl: Bypass broken implementation in OpenBSD 5.1/SPARC.

* m4/cbrtl.m4 (gl_FUNC_CBRTL_WORKS): New macro.
(gl_FUNC_CBRTL): Invoke it. If the function does not work, set
REPLACE_CBRTL to 1.
* doc/posix-functions/cbrtl.texi: Mention the OpenBSD 5.1/SPARC bug.

diff --git a/ChangeLog b/ChangeLog
index 7184981..2e6e8c7 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,13 @@
 2012-03-13  Bruno Haible  <bruno@clisp.org>
 
+       cbrtl: Bypass broken implementation in OpenBSD 5.1/SPARC.
+       * m4/cbrtl.m4 (gl_FUNC_CBRTL_WORKS): New macro.
+       (gl_FUNC_CBRTL): Invoke it. If the function does not work, set
+       REPLACE_CBRTL to 1.
+       * doc/posix-functions/cbrtl.texi: Mention the OpenBSD 5.1/SPARC bug.
+
+2012-03-13  Bruno Haible  <bruno@clisp.org>
+
        remainderl: Avoid compilation error on AIX >= 5.2.
        * lib/math.in.h (remainderl): Undefine macro from the system header.
 

diff --git a/doc/posix-functions/cbrtl.texi b/doc/posix-functions/cbrtl.texi
index a97c585..10a7f93 100644 (file)
--- a/doc/posix-functions/cbrtl.texi
+++ b/doc/posix-functions/cbrtl.texi
@@ -14,6 +14,9 @@ FreeBSD 6.0, NetBSD 5.0, OpenBSD 3.8, Minix 3.1.8, AIX 5.1, HP-UX 11, Solaris 9,
 @item
 This function is not declared on some platforms:
 IRIX 6.5.
+@item
+This function produces grossly wrong results on some platforms:
+OpenBSD 5.1/SPARC.
 @end itemize
 
 Portability problems fixed by Gnulib module @code{cbrtl-ieee}:

diff --git a/m4/cbrtl.m4 b/m4/cbrtl.m4
index b2a1a7c..64bd0bf 100644 (file)
--- a/m4/cbrtl.m4
+++ b/m4/cbrtl.m4
@@ -1,4 +1,4 @@
-# cbrtl.m4 serial 3
+# cbrtl.m4 serial 4
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -25,6 +25,16 @@ AC_DEFUN([gl_FUNC_CBRTL],
     dnl Also check whether it's declared.
     dnl IRIX 6.5 has cbrtl() in libm but doesn't declare it in <math.h>.
     AC_CHECK_DECL([cbrtl], , [HAVE_DECL_CBRTL=0], [[#include <math.h>]])
+
+    save_LIBS="$LIBS"
+    LIBS="$LIBS $CBRTL_LIBM"
+    gl_FUNC_CBRTL_WORKS
+    LIBS="$save_LIBS"
+    case "$gl_cv_func_cbrtl_works" in
+      *yes) ;;
+      *) REPLACE_CBRTL=1 ;;
+    esac
+
     m4_ifdef([gl_FUNC_CBRTL_IEEE], [
       if test $gl_cbrtl_required = ieee && test $REPLACE_CBRTL = 0; then
         AC_CACHE_CHECK([whether cbrtl works according to ISO C 99 with IEC 60559],
@@ -95,3 +105,40 @@ int main (int argc, char *argv[])
   fi
   AC_SUBST([CBRTL_LIBM])
 ])
+
+dnl Test whether cbrtl() works.
+dnl On OpenBSD 5.1/SPARC, cbrtl(16.0L) is = 1.2599...
+AC_DEFUN([gl_FUNC_CBRTL_WORKS],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CACHE_CHECK([whether cbrtl works], [gl_cv_func_cbrtl_works],
+    [
+      AC_RUN_IFELSE(
+        [AC_LANG_SOURCE([[
+#include <math.h>
+extern
+#ifdef __cplusplus
+"C"
+#endif
+long double cbrtl (long double);
+volatile long double x;
+long double y;
+int main ()
+{
+  x = 16.0L;
+  y = cbrtl (x);
+  if (y < 2.0L)
+    return 1;
+  return 0;
+}
+]])],
+        [gl_cv_func_cbrtl_works=yes],
+        [gl_cv_func_cbrtl_works=no],
+        [case "$host_os" in
+           osf*) gl_cv_func_cbrtl_works="guessing no";;
+           *)    gl_cv_func_cbrtl_works="guessing yes";;
+         esac
+        ])
+    ])
+])