hypotf-ieee: Work around test failure on OSF/1 and native Windows.

* m4/hypotf-ieee.m4: New file.
* m4/hypotf.m4 (gl_FUNC_HYPOTF): If gl_FUNC_HYPOTF_IEEE is present,
test whether hypotf works with mixed NaN and Infinity arguments.
Replace it if not.
* modules/hypotf-ieee (Files): Add m4/hypotf-ieee.m4.
(Depends-on): Add hypot-ieee.
(configure.ac): Invoke gl_FUNC_HYPOTF_IEEE.
* doc/posix-functions/hypotf.texi: Mention the hypotf-ieee module.

diff --git a/ChangeLog b/ChangeLog
index ab60280..aba334a 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,15 @@
 2012-02-29  Bruno Haible  <bruno@clisp.org>
 
+       hypotf-ieee: Work around test failure on OSF/1 and native Windows.
+       * m4/hypotf-ieee.m4: New file.
+       * m4/hypotf.m4 (gl_FUNC_HYPOTF): If gl_FUNC_HYPOTF_IEEE is present,
+       test whether hypotf works with mixed NaN and Infinity arguments.
+       Replace it if not.
+       * modules/hypotf-ieee (Files): Add m4/hypotf-ieee.m4.
+       (Depends-on): Add hypot-ieee.
+       (configure.ac): Invoke gl_FUNC_HYPOTF_IEEE.
+       * doc/posix-functions/hypotf.texi: Mention the hypotf-ieee module.
+
        hypot-ieee: Work around test failure on OSF/1 and native Windows.
        * lib/math.in.h (hypot): New declaration.
        * lib/hypot.c: New file.

diff --git a/doc/posix-functions/hypotf.texi b/doc/posix-functions/hypotf.texi
index debdc5e..2af0921 100644 (file)
--- a/doc/posix-functions/hypotf.texi
+++ b/doc/posix-functions/hypotf.texi
@@ -4,9 +4,9 @@
 
 POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/functions/hypotf.html}
 
-Gnulib module: hypotf
+Gnulib module: hypotf or hypotf-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{hypotf} or @code{hypotf-ieee}:
 @itemize
 @item
 This function is missing on some platforms:
@@ -16,6 +16,14 @@ This function produces wrong values on some platforms:
 NetBSD 5.1, OpenBSD 4.9.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{hypot-ieee}:
+@itemize
+@item
+When the arguments are mixed NaN and Infinity, this function returns a wrong
+value on some platforms:
+OSF/1 5.1, mingw, MSVC 9.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize

diff --git a/m4/hypotf-ieee.m4 b/m4/hypotf-ieee.m4
new file mode 100644 (file)
index 0000000..235b5dd
--- /dev/null
+++ b/m4/hypotf-ieee.m4
@@ -0,0 +1,15 @@
+# hypotf-ieee.m4 serial 1
+dnl Copyright (C) 2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in hypotf.m4 and not inlined in the
+dnl module description), so that gl_FUNC_HYPOTF can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_HYPOTF_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_hypotf_required=ieee])
+  AC_REQUIRE([gl_FUNC_HYPOTF])
+])

diff --git a/m4/hypotf.m4 b/m4/hypotf.m4
index fd1b1eb..c6185a5 100644 (file)
--- a/m4/hypotf.m4
+++ b/m4/hypotf.m4
@@ -1,4 +1,4 @@
-# hypotf.m4 serial 1
+# hypotf.m4 serial 2
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_HYPOTF],
 [
+  m4_divert_text([DEFAULTS], [gl_hypotf_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   AC_REQUIRE([gl_FUNC_HYPOT])
 
@@ -25,6 +26,53 @@ AC_DEFUN([gl_FUNC_HYPOTF],
       *yes) ;;
       *) REPLACE_HYPOTF=1 ;;
     esac
+    m4_ifdef([gl_FUNC_HYPOTF_IEEE], [
+      if test $gl_hypotf_required = ieee && test $REPLACE_HYPOTF = 0; then
+        AC_CACHE_CHECK([whether hypotf works according to ISO C 99 with IEC 60559],
+          [gl_cv_func_hypotf_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $HYPOTF_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (float x, float y)
+{
+  return x == y;
+}
+static float dummy (float x, float y) { return 0; }
+float zero;
+float one = 1.0f;
+int main (int argc, char *argv[])
+{
+  float (*my_hypotf) (float, float) = argc ? hypotf : dummy;
+  float f;
+  /* Test hypotf(NaN,Infinity).
+     This test fails on OSF/1 5.1 and native Windows.  */
+  f = my_hypotf (zero / zero, one / zero);
+  if (!numeric_equal (f, f))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_hypotf_ieee=yes],
+              [gl_cv_func_hypotf_ieee=no],
+              [gl_cv_func_hypotf_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_hypotf_ieee" in
+          *yes) ;;
+          *) REPLACE_HYPOTF=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_HYPOTF=0
   fi

diff --git a/modules/hypotf-ieee b/modules/hypotf-ieee
index 3e416cf..0efc2e6 100644 (file)
--- a/modules/hypotf-ieee
+++ b/modules/hypotf-ieee
@@ -2,12 +2,15 @@ Description:
 hypotf() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/hypotf-ieee.m4
 
 Depends-on:
 hypotf
 fpieee
+hypot-ieee      [test $HAVE_HYPOTF = 0 || test $REPLACE_HYPOTF = 1]
 
 configure.ac:
+gl_FUNC_HYPOTF_IEEE
 
 Makefile.am: