fmodl-ieee: Work around test failures on OSF/1, MSVC 9.

* m4/fmodl-ieee.m4: New file.
* m4/fmodl.m4 (gl_FUNC_FMODL): If gl_FUNC_FMODL_IEEE is present, test
whether fmodl works with zero arguments. Replace it if not.
* modules/fmodl-ieee (Files): Add m4/fmodl-ieee.m4.
(Depends-on): Add fmod-ieee.
(configure.ac): Invoke gl_FUNC_FMODL_IEEE.
* doc/posix-functions/fmodl.texi: Mention the fmodl-ieee module.

diff --git a/ChangeLog b/ChangeLog
index cbd2273..db18f1b 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,14 @@
 2012-02-27  Bruno Haible  <bruno@clisp.org>
 
+       fmodl-ieee: Work around test failures on OSF/1, MSVC 9.
+       * m4/fmodl-ieee.m4: New file.
+       * m4/fmodl.m4 (gl_FUNC_FMODL): If gl_FUNC_FMODL_IEEE is present, test
+       whether fmodl works with zero arguments. Replace it if not.
+       * modules/fmodl-ieee (Files): Add m4/fmodl-ieee.m4.
+       (Depends-on): Add fmod-ieee.
+       (configure.ac): Invoke gl_FUNC_FMODL_IEEE.
+       * doc/posix-functions/fmodl.texi: Mention the fmodl-ieee module.
+
        fmodf-ieee: Work around test failure on OSF/1.
        * m4/fmodf-ieee.m4: New file.
        * m4/fmodf.m4 (gl_FUNC_FMODF): If gl_FUNC_FMODF_IEEE is present, test

diff --git a/doc/posix-functions/fmodl.texi b/doc/posix-functions/fmodl.texi
index 7dc3627..b9a72e1 100644 (file)
--- a/doc/posix-functions/fmodl.texi
+++ b/doc/posix-functions/fmodl.texi
@@ -4,9 +4,9 @@
 
 POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/functions/fmodl.html}
 
-Gnulib module: fmodl
+Gnulib module: fmodl or fmodl-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{fmodl} or @code{fmodl-ieee}:
 @itemize
 @item
 This function is missing on some platforms:
@@ -19,6 +19,17 @@ This function is not declared and does not work on some platforms:
 AIX 5.1.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{fmodl-ieee}:
+@itemize
+@item
+This function has problems when the second argument is zero on some platforms:
+OSF/1 5.1.
+@item
+This function has problems when the first argument is minus zero on some
+platforms:
+MSVC 9.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize

diff --git a/m4/fmodl-ieee.m4 b/m4/fmodl-ieee.m4
new file mode 100644 (file)
index 0000000..f5c3d7b
--- /dev/null
+++ b/m4/fmodl-ieee.m4
@@ -0,0 +1,15 @@
+# fmodl-ieee.m4 serial 1
+dnl Copyright (C) 2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in fmodl.m4 and not inlined in the
+dnl module description), so that gl_FUNC_FMODL can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_FMODL_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_fmodl_required=ieee])
+  AC_REQUIRE([gl_FUNC_FMODL])
+])

diff --git a/m4/fmodl.m4 b/m4/fmodl.m4
index 3207215..ae5f233 100644 (file)
--- a/m4/fmodl.m4
+++ b/m4/fmodl.m4
@@ -1,4 +1,4 @@
-# fmodl.m4 serial 1
+# fmodl.m4 serial 2
 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_FMODL],
 [
+  m4_divert_text([DEFAULTS], [gl_fmodl_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
   AC_REQUIRE([gl_FUNC_FMOD])
@@ -24,15 +25,61 @@ AC_DEFUN([gl_FUNC_FMODL],
   AC_CHECK_FUNCS([fmodl])
   LIBS="$save_LIBS"
   if test $ac_cv_func_fmodl = yes; then
-    if test $ac_cv_have_decl_fmodl = yes; then
-      FMODL_LIBM="$FMOD_LIBM"
-    else
+    FMODL_LIBM="$FMOD_LIBM"
+    if test $ac_cv_have_decl_fmodl = no; then
       REPLACE_FMODL=1
     fi
+    m4_ifdef([gl_FUNC_FMODL_IEEE], [
+      if test $gl_fmodl_required = ieee && test $REPLACE_FMODL = 0; then
+        AC_CACHE_CHECK([whether fmodl works according to ISO C 99 with IEC 60559],
+          [gl_cv_func_fmodl_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $FMODL_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (long double x, long double y)
+{
+  return x == y;
+}
+static long double dummy (long double x, long double y) { return 0; }
+int main (int argc, char *argv[])
+{
+  long double (*my_fmodl) (long double, long double) = argc ? fmodl : dummy;
+  long double i;
+  long double f;
+  /* Test fmodl(...,0.0L).
+     This test fails on OSF/1 5.1.  */
+  f = my_fmodl (2.0L, 0.0L);
+  if (numeric_equal (f, f))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_fmodl_ieee=yes],
+              [gl_cv_func_fmodl_ieee=no],
+              [gl_cv_func_fmodl_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_fmodl_ieee" in
+          *yes) ;;
+          *) REPLACE_FMODL=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_FMODL=0
   fi
   if test $HAVE_FMODL = 0 || test $REPLACE_FMODL = 1; then
+    dnl Find libraries needed to link lib/fmodl.c.
     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
       FMODL_LIBM="$FMOD_LIBM"
     else

diff --git a/modules/fmodl-ieee b/modules/fmodl-ieee
index 3dcddde..4363f31 100644 (file)
--- a/modules/fmodl-ieee
+++ b/modules/fmodl-ieee
@@ -2,12 +2,15 @@ Description:
 fmodl() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/fmodl-ieee.m4
 
 Depends-on:
 fmodl
 fpieee
+fmod-ieee       [{ test $HAVE_FMODL = 0 || test $REPLACE_FMODL = 1; } && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1]
 
 configure.ac:
+gl_FUNC_FMODL_IEEE
 
 Makefile.am: