m4/cosl.m4

   1 # cosl.m4 serial 2
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_COSL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare cosl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   COSL_LIBM=
  14   AC_CACHE_CHECK([whether cosl() can be used without linking with libm],
  15     [gl_cv_func_cosl_no_libm],
  16     [
  17       AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  18                    # define __NO_MATH_INLINES 1 /* for glibc */
  19                    #endif
  20                    #include <math.h>
  21                    long double x;],
  22                   [return cosl (x) > 0.4;],
  23         [gl_cv_func_cosl_no_libm=yes],
  24         [gl_cv_func_cosl_no_libm=no])
  25     ])
  26   if test $gl_cv_func_cosl_no_libm = no; then
  27     AC_CACHE_CHECK([whether cosl() can be used with libm],
  28       [gl_cv_func_cosl_in_libm],
  29       [
  30         save_LIBS="$LIBS"
  31         LIBS="$LIBS -lm"
  32         AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  33                      # define __NO_MATH_INLINES 1 /* for glibc */
  34                      #endif
  35                      #include <math.h>
  36                      long double x;],
  37                     [return cosl (x) > 0.4;],
  38           [gl_cv_func_cosl_in_libm=yes],
  39           [gl_cv_func_cosl_in_libm=no])
  40         LIBS="$save_LIBS"
  41       ])
  42     if test $gl_cv_func_cosl_in_libm = yes; then
  43       COSL_LIBM=-lm
  44     fi
  45   fi
  46   if test $gl_cv_func_cosl_no_libm = yes \
  47      || test $gl_cv_func_cosl_in_libm = yes; then
  48     dnl Also check whether it's declared.
  49     dnl MacOS X 10.3 has cosl() in libc but doesn't declare it in <math.h>.
  50     AC_CHECK_DECL([cosl], , [HAVE_DECL_COSL=0], [#include <math.h>])
  51   else
  52     HAVE_DECL_COSL=0
  53     HAVE_COSL=0
  54     AC_LIBOBJ([cosl])
  55     AC_LIBOBJ([sincosl])
  56     AC_LIBOBJ([trigl])
  57     AC_REQUIRE([gl_FUNC_ISNANL])
  58     AC_REQUIRE([gl_FUNC_FLOOR])
  59     AC_REQUIRE([gl_FUNC_FLOORL])
  60     dnl Append $ISNANL_LIBM to COSL_LIBM, avoiding gratuitous duplicates.
  61     case " $COSL_LIBM " in
  62       *" $ISNANL_LIBM "*) ;;
  63       *) COSL_LIBM="$COSL_LIBM $ISNANL_LIBM" ;;
  64     esac
  65     dnl Append $FLOOR_LIBM to COSL_LIBM, avoiding gratuitous duplicates.
  66     case " $COSL_LIBM " in
  67       *" $FLOOR_LIBM "*) ;;
  68       *) COSL_LIBM="$COSL_LIBM $FLOOR_LIBM" ;;
  69     esac
  70     dnl Append $FLOORL_LIBM to COSL_LIBM, avoiding gratuitous duplicates.
  71     case " $COSL_LIBM " in
  72       *" $FLOORL_LIBM "*) ;;
  73       *) COSL_LIBM="$COSL_LIBM $FLOORL_LIBM" ;;
  74     esac
  75   fi
  76   AC_SUBST([COSL_LIBM])
  77 ])