m4/mathfunc.m4

   1 # mathfunc.m4 serial 6
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_MATHFUNC(FUNC, RETTYPE, PARAMTYPES)
   8 # --------------------------------------------------
   9 # tests whether the function FUNC is available in libc or libm.
  10 # RETTYPE is the return type. PARAMTYPES is a parameter list, with parentheses.
  11 # It sets FUNC_LIBM to empty or "-lm" accordingly.
  12
  13 AC_DEFUN([gl_MATHFUNC],
  14 [
  15   dnl We need the RETTYPE and PARAMTYPES in order to force linking with the
  16   dnl function. With gcc >= 4.3 on glibc/x86_64, calls to the 'fabs' function
  17   dnl are inlined by the compiler, therefore linking of these calls does not
  18   dnl require -lm, but taking the function pointer of 'fabs' does.
  19   m4_pushdef([func], [$1])
  20   m4_pushdef([FUNC], [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
  21                                        [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
  22   FUNC[]_LIBM=
  23   AC_CACHE_CHECK([whether func() can be used without linking with libm],
  24     [gl_cv_func_]func[_no_libm],
  25     [
  26       AC_LINK_IFELSE(
  27         [AC_LANG_PROGRAM(
  28            [[#ifndef __NO_MATH_INLINES
  29              # define __NO_MATH_INLINES 1 /* for glibc */
  30              #endif
  31              #include <math.h>
  32              $2 (*funcptr) $3 = ]func[;]],
  33            [[$2 y = funcptr ]m4_bpatsubst([m4_bpatsubst([$3], [int], [2])], [double], [1.6180339887])[;
  34              return y < 0.3 || y > 1.7;
  35            ]])],
  36         [gl_cv_func_]func[_no_libm=yes],
  37         [gl_cv_func_]func[_no_libm=no])
  38     ])
  39   if test $gl_cv_func_[]func[]_no_libm = no; then
  40     AC_CACHE_CHECK([whether func() can be used with libm],
  41       [gl_cv_func_]func[_in_libm],
  42       [
  43         save_LIBS="$LIBS"
  44         LIBS="$LIBS -lm"
  45         AC_LINK_IFELSE(
  46           [AC_LANG_PROGRAM(
  47              [[#ifndef __NO_MATH_INLINES
  48                # define __NO_MATH_INLINES 1 /* for glibc */
  49                #endif
  50                #include <math.h>
  51                $2 (*funcptr) $3 = ]func[;]],
  52              [[$2 y = funcptr ]m4_bpatsubst([m4_bpatsubst([$3], [int], [2])], [double], [1.6180339887])[;
  53                return y < 0.3 || y > 1.7;
  54              ]])],
  55           [gl_cv_func_]func[_in_libm=yes],
  56           [gl_cv_func_]func[_in_libm=no])
  57         LIBS="$save_LIBS"
  58       ])
  59     if test $gl_cv_func_[]func[]_in_libm = yes; then
  60       FUNC[]_LIBM=-lm
  61     fi
  62   fi
  63   AC_SUBST(FUNC[_LIBM])
  64   m4_popdef([FUNC])
  65   m4_popdef([func])
  66 ])
  67
  68 # gl_COMMON_DOUBLE_MATHFUNC(FUNC)
  69 # -------------------------------
  70 # tests whether the function FUNC is available in libc or libm.
  71 # It sets FUNC_LIBM to empty or "-lm" accordingly.
  72 # FUNC must be one of the following functions, that are present on all systems
  73 # and provided by libm on all systems except MacOS X, BeOS, Haiku:
  74 #   acos asin atan atan2 cbrt cos cosh erf erfc exp fmod hypot j0 j1 jn lgamma
  75 #   log log10 log1p pow remainder sin sinh sqrt tan tanh y0 y1 yn
  76
  77 AC_DEFUN([gl_COMMON_DOUBLE_MATHFUNC],
  78 [
  79   AC_REQUIRE([gl_COMMON_DOUBLE_MATHFUNC_TEST])
  80   m4_pushdef([FUNC], [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
  81                                        [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
  82   FUNC[]_LIBM="$POW_LIBM"
  83   AC_SUBST(FUNC[_LIBM])
  84   m4_popdef([FUNC])
  85 ])
  86
  87 AC_DEFUN([gl_COMMON_DOUBLE_MATHFUNC_TEST],
  88 [
  89   dnl We could use any of the following:
  90   dnl gl_MATHFUNC([acos], [double], [(double)])
  91   dnl gl_MATHFUNC([asin], [double], [(double)])
  92   dnl gl_MATHFUNC([atan], [double], [(double)])
  93   dnl gl_MATHFUNC([atan2], [double], [(double, double)])
  94   dnl gl_MATHFUNC([cbrt], [double], [(double)])
  95   dnl gl_MATHFUNC([cos], [double], [(double)])
  96   dnl gl_MATHFUNC([cosh], [double], [(double)])
  97   dnl gl_MATHFUNC([erf], [double], [(double)])
  98   dnl gl_MATHFUNC([erfc], [double], [(double)])
  99   dnl gl_MATHFUNC([exp], [double], [(double)])
 100   dnl gl_MATHFUNC([fmod], [double], [(double, double)])
 101   dnl gl_MATHFUNC([hypot], [double], [(double, double)])
 102   dnl gl_MATHFUNC([j0], [double], [(double)])
 103   dnl gl_MATHFUNC([j1], [double], [(double)])
 104   dnl gl_MATHFUNC([jn], [double], [(int, double)])
 105   dnl gl_MATHFUNC([lgamma], [double], [(double)])
 106   dnl gl_MATHFUNC([log], [double], [(double)])
 107   dnl gl_MATHFUNC([log10], [double], [(double)])
 108   dnl gl_MATHFUNC([log1p], [double], [(double)])
 109   dnl gl_MATHFUNC([pow], [double], [(double, double)])
 110   dnl gl_MATHFUNC([remainder], [double], [(double, double)])
 111   dnl gl_MATHFUNC([sin], [double], [(double)])
 112   dnl gl_MATHFUNC([sinh], [double], [(double)])
 113   dnl gl_MATHFUNC([sqrt], [double], [(double)])
 114   dnl gl_MATHFUNC([tan], [double], [(double)])
 115   dnl gl_MATHFUNC([tanh], [double], [(double)])
 116   dnl gl_MATHFUNC([y0], [double], [(double)])
 117   dnl gl_MATHFUNC([y1], [double], [(double)])
 118   dnl gl_MATHFUNC([yn], [double], [(int, double)])
 119   gl_MATHFUNC([pow], [double], [(double, double)])
 120 ])