lib/ID3FS/AudioFile.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::AudioFile;
  18
  19 use strict;
  20 use warnings;
  21 use ID3FS::AudioFile::Mp3;
  22 use ID3FS::AudioFile::Ogg;
  23 use ID3FS::AudioFile::Flac;
  24
  25 sub new
  26 {
  27     my $proto=shift;
  28     my $class=ref($proto) || $proto;
  29     my $self={};
  30     bless($self,$class);
  31
  32     $self->{path}=shift;
  33     my $ext=($self->{path}=~/.*\.(.*)/)[0];
  34     return undef unless($ext);
  35     my $me=shift;
  36     $ext=lc($ext);
  37     if($ext eq "mp3")
  38     {
  39         $self->{audiofile}=ID3FS::AudioFile::Mp3->new($self->{path});
  40     }
  41     elsif($ext eq "ogg")
  42     {
  43         $self->{audiofile}=ID3FS::AudioFile::Ogg->new($self->{path});
  44     }
  45     elsif($ext eq "flac")
  46     {
  47         $self->{audiofile}=ID3FS::AudioFile::Flac->new($self->{path});
  48     }
  49     else
  50     {
  51         print("$me: $self->{path}: Unknown extension: $ext\n");
  52         return undef;
  53     }
  54     return $self;
  55 }
  56
  57 sub set
  58 {
  59     my ($self, $thing, $value)=@_;
  60     if($value)
  61     {
  62         $value=$self->sanitise($self->stripslashes($value));
  63         $self->{audiofile}->$thing($value);
  64     }
  65     else
  66     {
  67         $value=$self->sanitise($self->stripslashes($self->{audiofile}->$thing()));
  68     }
  69     return $value;
  70 }
  71
  72 sub artist    { return(shift->set("artist", @_));   }
  73 sub album     { return(shift->set("album", @_));    }
  74 sub track     { return(shift->set("track", @_));    }
  75 sub tracknum  { return(shift->set("tracknum", @_)); }
  76 sub v1genre   { return(shift->set("v1genre", @_));  }
  77 sub genre     { return(shift->set("genre", @_));    }
  78 sub comment   { return(shift->set("comment", @_));  }
  79 sub audiotype { return(shift->set("audiotype"));    }
  80 sub haspic    { return(shift->set("haspic"));       }
  81 sub path      { return(shift->{path});              }
  82
  83 sub delete_artist   { shift->{audiofile}->delete_artist();   }
  84 sub delete_album    { shift->{audiofile}->delete_album();    }
  85 sub delete_track    { shift->{audiofile}->delete_track();    }
  86 sub delete_tracknum { shift->{audiofile}->delete_tracknum(); }
  87 sub delete_year     { shift->{audiofile}->delete_year();     }
  88 sub delete_v1genre  { shift->{audiofile}->delete_v1genre();  }
  89 sub delete_comment  { shift->{audiofile}->delete_comment();  }
  90 sub delete_all      { shift->{audiofile}->delete_all();      }
  91 sub delete_genre    { shift->{audiofile}->delete_genre();    }
  92 sub delete_tags     { shift->{audiofile}->delete_tags(@_);   }
  93 sub channels        { shift->{audiofile}->channels();        }
  94 sub bitrate         { shift->{audiofile}->bitrate();         }
  95 sub samplerate      { shift->{audiofile}->samplerate(@_);    }
  96
  97 sub year
  98 {
  99     my ($self, $year)=@_;
 100     if($year)
 101     {
 102         $year=$self->format_year($year);
 103         $self->{audiofile}->year($year);
 104     }
 105     else
 106     {
 107         $year=$self->{audiofile}->year();
 108     }
 109     return $year;
 110 }
 111
 112 sub format_year
 113 {
 114     my ($self, $year)=@_;
 115     if($year)
 116     {
 117         $year=$self->sanitise($self->stripslashes($year));
 118         if(defined($year) && $year =~/(\d{4})/)
 119         {
 120             $year=$1;
 121         }
 122     }
 123     return $year;
 124 }
 125
 126 sub add_tags
 127 {
 128     my($self, $tags)=@_;
 129     my @tags=split(/\s*,\s*/, $tags);
 130     $self->{audiofile}->add_tags(@tags);
 131 }
 132
 133 sub tags
 134 {
 135     my $self=shift;
 136     my @intags=$self->{audiofile}->tags();
 137     my @outtags=();
 138     return() unless(@intags);
 139     @intags = grep { defined($_); } @intags;
 140     # combine then split on commas
 141     # so multiple comma-delimited tags will work
 142     @intags=split(/\s*,\s*/, join(', ', @intags));
 143     for my $tag (@intags)
 144     {
 145         next unless(length($tag));
 146         next unless($tag =~ /\S+/);
 147         $tag=$self->sanitise($tag);
 148         my ($tagname, $tagval)=($tag, undef);
 149         if($tag=~/^([^\/]+)\/(.*)/)
 150         {
 151             ($tagname, $tagval)=($1, $2);
 152         }
 153         push(@outtags, [ $tagname, $tagval ]);
 154     }
 155     return @outtags;
 156 }
 157
 158 sub write
 159 {
 160     shift->{audiofile}->write();
 161 }
 162
 163 sub sanitise
 164 {
 165     my ($self, $text)=@_;
 166     $text =~ s/[^[:print:]]//g if(defined($text));
 167     return $text;
 168 }
 169
 170 sub stripslashes
 171 {
 172     my ($self, $text)=@_;
 173     $text =~ s/\//-/g if(defined($text));
 174     return $text;
 175 }
 176
 177 1;