lib/ID3FS/DB.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::DB;
  18
  19 use strict;
  20 use warnings;
  21 use DBI;
  22 use ID3FS::AudioFile;
  23 use Cwd;
  24
  25 our $SCHEMA_VERSION=1;
  26 my $dbfile=".id3fs"; # default
  27
  28 sub new
  29 {
  30     my $proto=shift;
  31     my $class=ref($proto) || $proto;
  32     my $self={};
  33     bless($self,$class);
  34
  35     $self->{me}=shift;
  36     $self->{verbose}=shift;
  37     my $init=shift;
  38     $self->{base}=shift;
  39     $self->{dbpath}=shift || ($self->{base} . "/" . $dbfile);
  40     $self->{dbpath}=Cwd::abs_path($self->{dbpath});
  41     $self->{absbase}=Cwd::abs_path($self->{base});
  42
  43     my $connectstr="dbi:SQLite:dbname=$self->{dbpath}";
  44     my $exists=-f $self->{dbpath};
  45     $self->{dbh}=DBI->connect($connectstr, undef, undef,
  46                               { AutoCommit=>1 } );
  47     unless(defined($self->{dbh}))
  48     {
  49         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  50     }
  51
  52     if($exists)
  53     {
  54         $self->checkschema();
  55     }
  56     else
  57     {
  58         $self->create();
  59     }
  60     $self->enable_foreign_keys();
  61     return $self;
  62 }
  63
  64 # search parent directories for db
  65 sub find_db
  66 {
  67     # class method
  68     shift if(ref($_[0]) eq "ID3FS::DB");
  69
  70     my($me, $init, @dirs)=@_;
  71     my $base=undef;
  72     for my $dir (@dirs)
  73     {
  74         my $path=Cwd::abs_path($dir);
  75         do
  76         {
  77             $base=$path;
  78             $path=~s/(.*)\/.*/$1/;
  79         }
  80         while(! -f "$base/$dbfile" && length($path) && -d $path);
  81         if(-f "$base/$dbfile")
  82         {
  83             return $base;
  84         }
  85     }
  86     if(!-f "$base/$dbfile")
  87     {
  88         unless($init)
  89         {
  90             print "$me: db not found at $base/$dbfile\n";
  91             return undef;
  92         }
  93         $base=$dirs[0];
  94
  95     }
  96     return $base;
  97 }
  98
  99 sub base_dir { return shift->{base}; }
 100
 101 sub create
 102 {
 103     my($self,$name)=@_;
 104     my @schema=split(/\n\n/,join("", <DATA>));
 105     close(DATA);
 106     for my $cmd (@schema)
 107     {
 108         $self->{dbh}->do($cmd);
 109     }
 110     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 111                $SCHEMA_VERSION, time());
 112 }
 113
 114 sub checkschema
 115 {
 116     my $self=shift;
 117     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 118     if(!defined($version) || $version != $SCHEMA_VERSION)
 119     {
 120         die("$self->{me}: id3fs database version " .
 121             defined($version) ? $version : '""' .
 122             "not known, current version is $SCHEMA_VERSION.\n");
 123     }
 124 }
 125
 126 sub analyze
 127 {
 128     my $self=shift;
 129     $self->cmd("ANALYZE");
 130 }
 131
 132 sub enable_foreign_keys
 133 {
 134     my $self=shift;
 135     $self->cmd("PRAGMA foreign_keys = ON");
 136 }
 137
 138 sub last_update
 139 {
 140     my($self, $newval)=@_;
 141     if(defined($newval))
 142     {
 143         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 144     }
 145     else
 146     {
 147         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 148     }
 149     return $newval;
 150 }
 151
 152 sub bare_tags
 153 {
 154     my($self)=@_;
 155     my $sql=("SELECT tags.name FROM tags\n" .
 156              "WHERE tags.parents_id=''\n" .
 157              "GROUP BY tags.name\n");
 158     my @names=$self->cmd_firstcol($sql);
 159     return (@names);
 160 }
 161
 162 sub tags_with_values
 163 {
 164     my($self)=@_;
 165     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 166              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 167              "GROUP BY p.name, t.name\n");
 168     my $result=$self->cmd_rows($sql);
 169     my $tags={};
 170     for my $pair (@$result)
 171     {
 172         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 173     }
 174     return $tags;
 175 }
 176
 177 sub tag_has_values
 178 {
 179     my($self, $id)=@_;
 180     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 181              "WHERE tags.parents_id=?\n");
 182     my ($rows)=$self->cmd_onerow($sql, $id);
 183     return $rows;
 184 }
 185
 186 sub relativise
 187 {
 188     my($self, $path, $name, $mountpoint, $querypath)=@_;
 189     my $rpath="$self->{absbase}/$path";
 190     my $vpath=$mountpoint . $querypath;
 191     my @path=split(/\//,$rpath);
 192     my @rel=split(/\//,$vpath);
 193     # drop filename from rel
 194     pop @rel;
 195     # absolute paths have empty first element due to leading /
 196     shift(@path) if($path[0] eq "");
 197     shift(@rel)  if($rel[0]  eq "");
 198     # f: /home/foo/bar/baz.mp3
 199     # r: /home/ianb/music/albums
 200     while(@path && @rel && ($path[0] eq $rel[0]))
 201     {
 202         shift(@path);
 203         shift(@rel);
 204     }
 205     my $upcount=scalar(@rel);
 206     my $result="../" x $upcount;
 207     $result .= join("/",@path);
 208     $result .= "/$name";
 209     return $result;
 210 }
 211
 212 sub add
 213 {
 214     my($self,$path)=@_;
 215     my $relpath=Cwd::abs_path($path);
 216     $relpath =~ s/^\Q$self->{absbase}\E\/?//;
 217     my($filepart,$pathpart);
 218     if($relpath !~ /\//)
 219     {
 220         $pathpart='';
 221         $filepart=$relpath;
 222     }
 223     else
 224     {
 225         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 226     }
 227     my $file=ID3FS::AudioFile->new($path, $self->{me});
 228     return unless(defined($file));
 229     my $artist=$file->artist();
 230     my $album=$file->album();
 231     my $v1genre=$file->v1genre();
 232     my $year=$file->year();
 233     my $audiotype=$file->audiotype();
 234     my @tags=$file->tags();
 235     my $haspic=$file->haspic();
 236     my $channels=$file->channels();
 237     my $bitrate=$file->bitrate();
 238     my $samplerate=$file->samplerate();
 239
 240     $artist=undef unless($self->ok($artist));
 241     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 242     my $artist_id=$self->add_to_table("artists",  $artist);
 243     my $path_id=$self->add_to_table("paths", $pathpart);
 244     $album=undef unless($self->ok($album));
 245 #    if($self->{verbose} && !defined($album)) FIXME
 246     if(!defined($album))
 247     {
 248         print "$self->{me}: $path: no album tag defined\n";
 249     }
 250
 251     my $albums_id=$self->add_to_table("albums", $album);
 252     my $file_id=$self->add_to_table("files", $filepart,
 253                                     { "artists_id" => $artist_id,
 254                                       "albums_id"  => $albums_id,
 255                                       "paths_id"   => $path_id });
 256     if(@tags)
 257     {
 258         for my $tag (@tags)
 259         {
 260             $self->add_tag($file_id, @$tag);
 261         }
 262     }
 263     else
 264     {
 265         $self->add_tag($file_id, "UNTAGGED");
 266     }
 267
 268     $year="UNKNOWN" if(!$self->ok($year) || $year =~ /^0+$/);
 269     $year+=1900 if($year=~/^\d\d$/);
 270     $self->add_tag($file_id, "year", $year);
 271     if($year=~/^(\d\d\d)\d$/)
 272     {
 273         $self->add_tag($file_id, "decade", "${1}0s");
 274     }
 275     else
 276     {
 277         $self->add_tag($file_id, "decade", "UNKNOWN");
 278     }
 279
 280     if($self->ok($v1genre))
 281     {
 282         $self->add_tag($file_id, "v1genre", $v1genre);
 283     }
 284
 285     if($haspic)
 286     {
 287         $self->add_tag($file_id, "haspic", undef);
 288     }
 289
 290     if($self->ok($audiotype))
 291     {
 292         $self->add_tag($file_id, "audiotype", $audiotype);
 293     }
 294     else
 295     {
 296         # should never happen
 297         $self->add_tag($file_id, "audiotype", "UNKNOWN");
 298     }
 299
 300     if($self->ok($channels))
 301     {
 302         if    ($channels eq "2") { $channels="stereo";  }
 303         elsif ($channels eq "1") { $channels="mono";    }
 304         elsif ($channels eq "0") { $channels="UNKNOWN"; }
 305         $self->add_tag($file_id, "channels", $channels);
 306     }
 307
 308     if($self->ok($bitrate))
 309     {
 310         $bitrate="UNKNOWN" if($bitrate=~/^0+$/);
 311         $self->add_tag($file_id, "bitrate", $bitrate);
 312     }
 313
 314     if($self->ok($samplerate))
 315     {
 316         $samplerate="UNKNOWN" if($samplerate=~/^0+$/);
 317         $self->add_tag($file_id, "samplerate", $samplerate);
 318     }
 319
 320 }
 321
 322 sub add_tag
 323 {
 324     my($self, $file_id, $tag, $value)=@_;
 325     my $tag_id=$self->add_to_table("tags",  $tag,
 326                                    { "parents_id" => undef });
 327     $self->add_relation("files_x_tags",
 328                         { "files_id" => $file_id,
 329                           "tags_id"  => $tag_id });
 330     if(defined($value) && length($value))
 331     {
 332         my $val_id=$self->add_to_table("tags",  $value,
 333                                        { "parents_id" => $tag_id });
 334         $self->add_relation("files_x_tags",
 335                             { "files_id" => $file_id,
 336                               "tags_id"  => $val_id });
 337     }
 338 }
 339
 340 sub add_to_table
 341 {
 342     my($self, $table, $name, $extradata)=@_;
 343     my $parent=undef;
 344     if($extradata && $extradata->{parents_id})
 345     {
 346         $parent=$extradata->{parents_id};
 347     }
 348     my $id=$self->lookup_id($table, $name, $parent);
 349     unless(defined($id))
 350     {
 351         my $sql="INSERT INTO $table (";
 352         my @fields=qw(name);
 353         if(defined($extradata))
 354         {
 355             push(@fields, sort keys(%$extradata));
 356         }
 357         $sql .= join(", ", @fields);
 358         $sql .=") VALUES (";
 359         $sql .= join(", ", map { "?"; } @fields);
 360         $sql .= ");";
 361         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 362     }
 363     return $id;
 364 }
 365
 366 sub add_relation
 367 {
 368     my ($self, $relname, $fields)=@_;
 369     return if($self->relation_exists($relname, $fields));
 370     my $sql="INSERT INTO $relname (";
 371     $sql .= join(", ", sort keys(%$fields));
 372     $sql .= ") VALUES (";
 373     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 374     $sql .= ");";
 375     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 376 }
 377
 378 sub files_in
 379 {
 380     my ($self, $dir)=@_;
 381     my $sql=("SELECT files.name FROM files\n" .
 382              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 383              "WHERE paths.name=?\n");
 384     return($self->cmd_firstcol($sql, $dir));
 385 }
 386
 387 sub unindex
 388 {
 389     my($self, $path, $file)=@_;
 390     my $sql=("DELETE FROM files WHERE id IN (" .
 391              "\tSELECT files.id FROM files\n" .
 392              "\tINNER JOIN paths ON paths.id=files.paths_id\n" .
 393              "\tWHERE paths.name=? and files.name=? )\n");
 394     $self->cmd_rows($sql, $path, $file);
 395 }
 396
 397
 398 sub prune_directories
 399 {
 400     my($self)=@_;
 401     my $sql=("SELECT name, id FROM paths\n");
 402     my $pathsref=$self->cmd_rows($sql);
 403     my @ids=();
 404     for my $pathpair (@$pathsref)
 405     {
 406         my($path, $id)=@$pathpair;
 407         my $fullpath="$self->{absbase}/$path";
 408         unless(-d $fullpath)
 409         {
 410             push(@ids, $id)
 411         }
 412     }
 413     $self->prune_paths(@ids);
 414     return scalar(@ids);
 415 }
 416
 417 sub prune_paths
 418 {
 419     my($self, @ids)=@_;
 420     return unless(@ids);
 421     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 422              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 423     $self->cmd($sql);
 424 }
 425
 426 sub remove_unused
 427 {
 428     my($self)=@_;
 429     my $sql=<<'EOT';
 430    DELETE FROM artists WHERE id IN (
 431        SELECT artists.id FROM artists
 432        LEFT JOIN files ON files.artists_id=artists.id
 433        WHERE files.id IS NULL);
 434
 435    DELETE FROM albums WHERE id IN (
 436        SELECT albums.id FROM albums
 437        LEFT JOIN files ON files.albums_id=albums.id
 438        WHERE files.id IS NULL);
 439
 440    DELETE FROM paths WHERE id IN (
 441        SELECT paths.id FROM paths
 442        LEFT JOIN files ON files.paths_id=paths.id
 443        WHERE files.id IS NULL);
 444
 445    DELETE FROM files_x_tags WHERE files_id IN (
 446        SELECT files_x_tags.files_id FROM files_x_tags
 447        LEFT JOIN files ON files.id=files_x_tags.files_id
 448        WHERE files.id IS NULL);
 449
 450    DELETE FROM tags WHERE id IN (
 451        SELECT tags.id FROM tags
 452        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 453        WHERE files_x_tags.files_id IS NULL);
 454
 455     VACUUM
 456 EOT
 457 #    print "SQL: $sql\n";
 458     my @sql=split(/\n\n/, $sql);
 459     $self->cmd($_) for (@sql);
 460 }
 461
 462 sub relation_exists
 463 {
 464     my ($self, $relname, $fields)=@_;
 465     my $sql="SELECT count(1) FROM $relname WHERE ";
 466     my @exprs=();
 467     my @vals=();
 468     for my $field (keys %$fields)
 469     {
 470         push(@exprs,$field);
 471         push(@vals,$fields->{$field});
 472     }
 473     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 474     my ($ret)=$self->cmd_onerow($sql, @vals);
 475     return $ret;
 476 }
 477
 478 sub ok
 479 {
 480     my($self, $thing)=@_;
 481     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 482 }
 483
 484 # actually call the database
 485 sub cmd_sth
 486 {
 487     my($self, $sql, @params)=@_;
 488     my $sth=$self->{dbh}->prepare($sql);
 489     my $idx=1;
 490     for my $param (@params)
 491     {
 492         $param="" unless(defined($param));
 493         $sth->bind_param($idx++, $param);
 494     }
 495     $sth->execute();
 496     return $sth;
 497 }
 498
 499 # pass cmd to db, ignore response
 500 sub cmd
 501 {
 502     my ($self, @args)=@_;
 503     # don't care about retcode
 504     $self->cmd_sth(@args);
 505 }
 506
 507 # return one row
 508 sub cmd_onerow
 509 {
 510     my ($self, @args)=@_;
 511     my $sth=$self->cmd_sth(@args);
 512     return($sth->fetchrow_array());
 513 }
 514
 515 # returns all rows
 516 sub cmd_rows
 517 {
 518     my ($self, @args)=@_;
 519     my $sth=$self->cmd_sth(@args);
 520     return $sth->fetchall_arrayref();
 521 }
 522
 523 # returns just the first column
 524 sub cmd_firstcol
 525 {
 526     my ($self, @args)=@_;
 527     return(map { $_->[0] } @{$self->cmd_rows(@args)});
 528 }
 529
 530 # runs cmd, returns id of last insert
 531 sub cmd_id
 532 {
 533     my ($self, @args)=@_;
 534     $self->cmd_sth(@args);
 535     return($self->last_insert_id());
 536 }
 537
 538 sub last_insert_id
 539 {
 540     my $self=shift;
 541     return $self->{dbh}->last_insert_id("","","","");
 542 }
 543
 544 # lookup id of $name in $table, also matching on $parent if needed
 545 sub lookup_id
 546 {
 547     my($self, $table, $name, $parent)=@_;
 548     my $sql="SELECT id FROM $table where name=?";
 549     my @args=($name);
 550     if($parent)
 551     {
 552         $sql .= " AND parents_id=?";
 553         push(@args, $parent);
 554     }
 555     my($id)=$self->cmd_onerow($sql, @args);
 556     return $id;
 557 }
 558
 559 __DATA__
 560
 561 CREATE TABLE id3fs (
 562     schema_version INTEGER,
 563     last_update
 564 );
 565
 566 CREATE TABLE paths (
 567     id INTEGER,
 568     name text,
 569     PRIMARY KEY(id ASC)
 570 );
 571
 572 CREATE TABLE artists (
 573     id INTEGER,
 574     name text,
 575     PRIMARY KEY(id ASC)
 576 );
 577
 578 CREATE TABLE albums (
 579     id INTEGER,
 580     name text,
 581     PRIMARY KEY(id ASC)
 582 );
 583
 584 CREATE TABLE files (
 585     id INTEGER,
 586     name text,
 587     artists_id,
 588     albums_id,
 589     paths_id,
 590     PRIMARY KEY(id ASC),
 591     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 592     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 593     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 594 );
 595
 596 CREATE TABLE tags (
 597     id INTEGER,
 598     parents_id INTEGER,
 599     name text,
 600     PRIMARY KEY(id ASC)
 601 );
 602
 603 CREATE TABLE files_x_tags (
 604     files_id INTEGER,
 605     tags_id INTEGER,
 606     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 607     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 608 );
 609
 610 CREATE INDEX idx_fxt_both ON files_x_tags (files_id, tags_id)
 611
 612 CREATE INDEX idx_fxt_tags ON files_x_tags (tags_id)
 613
 614 CREATE INDEX idx_files_id_name ON files (id, name)
 615
 616 CREATE INDEX idx_files_name_id ON files (name, id)
 617
 618 CREATE INDEX idx_tags_id_parent_name ON tags (id, parents_id, name)
 619
 620 CREATE INDEX idx_tags_parent_id_name ON tags (parents_id, id, name)
 621
 622 CREATE INDEX idx_tags_name ON tags (name)