lib/ID3FS/DB.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::DB;
  18
  19 use strict;
  20 use warnings;
  21 use DBI;
  22 use ID3FS::AudioFile;
  23 use Cwd;
  24
  25 our $SCHEMA_VERSION=1;
  26 my $dbfile=".id3fs"; # default
  27
  28 sub new
  29 {
  30     my $proto=shift;
  31     my $class=ref($proto) || $proto;
  32     my $self={};
  33     bless($self,$class);
  34
  35     $self->{me}=shift;
  36     $self->{verbose}=shift;
  37     my $init=shift;
  38     $self->{base}=shift;
  39     $self->{dbpath}=shift || ($self->{base} . "/" . $dbfile);
  40     $self->{dbpath}=Cwd::abs_path($self->{dbpath});
  41     $self->{absbase}=Cwd::abs_path($self->{base});
  42
  43     my $connectstr="dbi:SQLite:dbname=$self->{dbpath}";
  44     my $exists=-f $self->{dbpath};
  45     $self->{dbh}=DBI->connect($connectstr, undef, undef,
  46                               { AutoCommit=>1 } );
  47     unless(defined($self->{dbh}))
  48     {
  49         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  50     }
  51
  52     if($exists)
  53     {
  54         $self->checkschema();
  55     }
  56     else
  57     {
  58         $self->create();
  59     }
  60     $self->enable_foreign_keys();
  61     return $self;
  62 }
  63
  64 # search parent directories for db
  65 sub find_db
  66 {
  67     # class method
  68     shift if(ref($_[0]) eq "ID3FS::DB");
  69
  70     my($me, $init, @dirs)=@_;
  71     my $base=undef;
  72     for my $dir (@dirs)
  73     {
  74         my $path=Cwd::abs_path($dir);
  75         do
  76         {
  77             $base=$path;
  78             $path=~s/(.*)\/.*/$1/;
  79         }
  80         while(! -f "$base/$dbfile" && length($path) && -d $path);
  81         if(-f "$base/$dbfile")
  82         {
  83             return $base;
  84         }
  85     }
  86     if(!-f "$base/$dbfile")
  87     {
  88         unless($init)
  89         {
  90             print "$me: db not found at $base/$dbfile\n";
  91             return undef;
  92         }
  93         $base=$dirs[0];
  94
  95     }
  96     return $base;
  97 }
  98
  99 sub base_dir { return shift->{base}; }
 100
 101 sub create
 102 {
 103     my($self,$name)=@_;
 104     my @schema=split(/\n\n/,join("", <DATA>));
 105     close(DATA);
 106     for my $cmd (@schema)
 107     {
 108         $self->{dbh}->do($cmd);
 109     }
 110     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 111                $SCHEMA_VERSION, time());
 112 }
 113
 114 sub checkschema
 115 {
 116     my $self=shift;
 117     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 118     if(!defined($version) || $version != $SCHEMA_VERSION)
 119     {
 120         die("$self->{me}: id3fs database version " .
 121             defined($version) ? $version : '""' .
 122             "not known, current version is $SCHEMA_VERSION.\n");
 123     }
 124 }
 125
 126 sub analyze
 127 {
 128     my $self=shift;
 129     $self->cmd("ANALYZE");
 130 }
 131
 132 sub enable_foreign_keys
 133 {
 134     my $self=shift;
 135     $self->cmd("PRAGMA foreign_keys = ON");
 136 }
 137
 138 sub last_update
 139 {
 140     my($self, $newval)=@_;
 141     if(defined($newval))
 142     {
 143         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 144     }
 145     else
 146     {
 147         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 148     }
 149     return $newval;
 150 }
 151
 152 sub bare_tags
 153 {
 154     my($self)=@_;
 155     my $sql=("SELECT tags.name FROM tags\n" .
 156              "WHERE tags.parents_id=''\n" .
 157              "GROUP BY tags.name\n");
 158     my @names=$self->cmd_firstcol($sql);
 159     return (@names);
 160 }
 161
 162 sub tags_with_values
 163 {
 164     my($self)=@_;
 165     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 166              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 167              "GROUP BY p.name, t.name\n");
 168     my $result=$self->cmd_rows($sql);
 169     my $tags={};
 170     for my $pair (@$result)
 171     {
 172         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 173     }
 174     return $tags;
 175 }
 176
 177 sub tag_has_values
 178 {
 179     my($self, $id)=@_;
 180     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 181              "WHERE tags.parents_id=?\n");
 182     my ($rows)=$self->cmd_onerow($sql, $id);
 183     return $rows;
 184 }
 185
 186 sub relativise
 187 {
 188     my($self, $path, $name, $mountpoint, $querypath)=@_;
 189     my $rpath="$self->{absbase}/$path";
 190     my $vpath=$mountpoint . $querypath;
 191     my @path=split(/\//,$rpath);
 192     my @rel=split(/\//,$vpath);
 193     # drop filename from rel
 194     pop @rel;
 195     # absolute paths have empty first element due to leading /
 196     shift(@path) if($path[0] eq "");
 197     shift(@rel)  if($rel[0]  eq "");
 198     # f: /home/foo/bar/baz.mp3
 199     # r: /home/ianb/music/albums
 200     while(@path && @rel && ($path[0] eq $rel[0]))
 201     {
 202         shift(@path);
 203         shift(@rel);
 204     }
 205     my $upcount=scalar(@rel);
 206     my $result="../" x $upcount;
 207     $result .= join("/",@path);
 208     $result .= "/$name";
 209     return $result;
 210 }
 211
 212 sub add
 213 {
 214     my($self,$path)=@_;
 215     my $relpath=Cwd::abs_path($path);
 216     $relpath =~ s/^\Q$self->{absbase}\E\/?//;
 217     my($filepart,$pathpart);
 218     if($relpath !~ /\//)
 219     {
 220         $pathpart='';
 221         $filepart=$relpath;
 222     }
 223     else
 224     {
 225         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 226     }
 227     my $file=ID3FS::AudioFile->new($path, $self->{me});
 228     return unless(defined($file));
 229     my $artist=$file->artist();
 230     my $album=$file->album();
 231     my $v1genre=$file->v1genre();
 232     my $year=$file->year();
 233     my $audiotype=$file->audiotype();
 234     my @tags=$file->tags();
 235     my $haspic=$file->haspic();
 236
 237     $artist=undef unless($self->ok($artist));
 238     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 239     my $artist_id=$self->add_to_table("artists",  $artist);
 240     my $path_id=$self->add_to_table("paths", $pathpart);
 241     $album=undef unless($self->ok($album));
 242     if($self->{verbose} && !defined($album))
 243     {
 244         print "$self->{me}: $path: no album tag defined\n";
 245     }
 246
 247     my $albums_id=$self->add_to_table("albums", $album);
 248     my $file_id=$self->add_to_table("files", $filepart,
 249                                     { "artists_id" => $artist_id,
 250                                       "albums_id"  => $albums_id,
 251                                       "paths_id"   => $path_id });
 252     if(@tags)
 253     {
 254         for my $tag (@tags)
 255         {
 256             $self->add_tag($file_id, @$tag);
 257         }
 258     }
 259     else
 260     {
 261         $self->add_tag($file_id, "UNTAGGED");
 262     }
 263
 264     $year="UNKNOWN" unless($self->ok($year));
 265     $self->add_tag($file_id, "year", $year);
 266     if($year=~/^(\d\d\d)\d$/)
 267     {
 268         $self->add_tag($file_id, "decade", "${1}0s");
 269     }
 270     else
 271     {
 272         $self->add_tag($file_id, "decade", "UNKNOWN");
 273     }
 274
 275     if($self->ok($v1genre))
 276     {
 277         $self->add_tag($file_id, "v1genre", $v1genre);
 278     }
 279
 280     if($haspic)
 281     {
 282         $self->add_tag($file_id, "haspic", undef);
 283     }
 284
 285     if($self->ok($audiotype))
 286     {
 287         $self->add_tag($file_id, "audiotype", $audiotype);
 288     }
 289 }
 290
 291 sub add_tag
 292 {
 293     my($self, $file_id, $tag, $value)=@_;
 294     my $tag_id=$self->add_to_table("tags",  $tag,
 295                                    { "parents_id" => undef });
 296     $self->add_relation("files_x_tags",
 297                         { "files_id" => $file_id,
 298                           "tags_id"  => $tag_id });
 299     if(defined($value) && length($value))
 300     {
 301         my $val_id=$self->add_to_table("tags",  $value,
 302                                        { "parents_id" => $tag_id });
 303         $self->add_relation("files_x_tags",
 304                             { "files_id" => $file_id,
 305                               "tags_id"  => $val_id });
 306     }
 307 }
 308
 309 sub add_to_table
 310 {
 311     my($self, $table, $name, $extradata)=@_;
 312     my $parent=undef;
 313     if($extradata && $extradata->{parents_id})
 314     {
 315         $parent=$extradata->{parents_id};
 316     }
 317     my $id=$self->lookup_id($table, $name, $parent);
 318     unless(defined($id))
 319     {
 320         my $sql="INSERT INTO $table (";
 321         my @fields=qw(name);
 322         if(defined($extradata))
 323         {
 324             push(@fields, sort keys(%$extradata));
 325         }
 326         $sql .= join(", ", @fields);
 327         $sql .=") VALUES (";
 328         $sql .= join(", ", map { "?"; } @fields);
 329         $sql .= ");";
 330         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 331     }
 332     return $id;
 333 }
 334
 335 sub add_relation
 336 {
 337     my ($self, $relname, $fields)=@_;
 338     return if($self->relation_exists($relname, $fields));
 339     my $sql="INSERT INTO $relname (";
 340     $sql .= join(", ", sort keys(%$fields));
 341     $sql .= ") VALUES (";
 342     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 343     $sql .= ");";
 344     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 345 }
 346
 347 sub files_in
 348 {
 349     my ($self, $dir)=@_;
 350     my $sql=("SELECT files.name FROM files\n" .
 351              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 352              "WHERE paths.name=?\n");
 353     return($self->cmd_firstcol($sql, $dir));
 354 }
 355
 356 sub unindex
 357 {
 358     my($self, $path, $file)=@_;
 359     my $sql=("DELETE FROM files WHERE id IN (" .
 360              "\tSELECT files.id FROM files\n" .
 361              "\tINNER JOIN paths ON paths.id=files.paths_id\n" .
 362              "\tWHERE paths.name=? and files.name=? )\n");
 363     $self->cmd_rows($sql, $path, $file);
 364 }
 365
 366
 367 sub prune_directories
 368 {
 369     my($self)=@_;
 370     my $sql=("SELECT name, id FROM paths\n");
 371     my $pathsref=$self->cmd_rows($sql);
 372     my @ids=();
 373     for my $pathpair (@$pathsref)
 374     {
 375         my($path, $id)=@$pathpair;
 376         my $fullpath="$self->{absbase}/$path";
 377         unless(-d $fullpath)
 378         {
 379             push(@ids, $id)
 380         }
 381     }
 382     $self->prune_paths(@ids);
 383     return scalar(@ids);
 384 }
 385
 386 sub prune_paths
 387 {
 388     my($self, @ids)=@_;
 389     return unless(@ids);
 390     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 391              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 392     $self->cmd($sql);
 393 }
 394
 395 sub remove_unused
 396 {
 397     my($self)=@_;
 398     my $sql=<<'EOT';
 399    DELETE FROM artists WHERE id IN (
 400        SELECT artists.id FROM artists
 401        LEFT JOIN files ON files.artists_id=artists.id
 402        WHERE files.id IS NULL);
 403
 404    DELETE FROM albums WHERE id IN (
 405        SELECT albums.id FROM albums
 406        LEFT JOIN files ON files.albums_id=albums.id
 407        WHERE files.id IS NULL);
 408
 409    DELETE FROM paths WHERE id IN (
 410        SELECT paths.id FROM paths
 411        LEFT JOIN files ON files.paths_id=paths.id
 412        WHERE files.id IS NULL);
 413
 414    DELETE FROM files_x_tags WHERE files_id IN (
 415        SELECT files_x_tags.files_id FROM files_x_tags
 416        LEFT JOIN files ON files.id=files_x_tags.files_id
 417        WHERE files.id IS NULL);
 418
 419    DELETE FROM tags WHERE id IN (
 420        SELECT tags.id FROM tags
 421        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 422        WHERE files_x_tags.files_id IS NULL);
 423
 424     VACUUM
 425 EOT
 426 #    print "SQL: $sql\n";
 427     my @sql=split(/\n\n/, $sql);
 428     $self->cmd($_) for (@sql);
 429 }
 430
 431 sub relation_exists
 432 {
 433     my ($self, $relname, $fields)=@_;
 434     my $sql="SELECT count(1) FROM $relname WHERE ";
 435     my @exprs=();
 436     my @vals=();
 437     for my $field (keys %$fields)
 438     {
 439         push(@exprs,$field);
 440         push(@vals,$fields->{$field});
 441     }
 442     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 443     my ($ret)=$self->cmd_onerow($sql, @vals);
 444     return $ret;
 445 }
 446
 447 sub ok
 448 {
 449     my($self, $thing)=@_;
 450     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 451 }
 452
 453 # actually call the database
 454 sub cmd_sth
 455 {
 456     my($self, $sql, @params)=@_;
 457     my $sth=$self->{dbh}->prepare($sql);
 458     my $idx=1;
 459     for my $param (@params)
 460     {
 461         $param="" unless(defined($param));
 462         $sth->bind_param($idx++, $param);
 463     }
 464     $sth->execute();
 465     return $sth;
 466 }
 467
 468 # pass cmd to db, ignore response
 469 sub cmd
 470 {
 471     my ($self, @args)=@_;
 472     # don't care about retcode
 473     $self->cmd_sth(@args);
 474 }
 475
 476 # return one row
 477 sub cmd_onerow
 478 {
 479     my ($self, @args)=@_;
 480     my $sth=$self->cmd_sth(@args);
 481     return($sth->fetchrow_array());
 482 }
 483
 484 # returns all rows
 485 sub cmd_rows
 486 {
 487     my ($self, @args)=@_;
 488     my $sth=$self->cmd_sth(@args);
 489     return $sth->fetchall_arrayref();
 490 }
 491
 492 # returns just the first column
 493 sub cmd_firstcol
 494 {
 495     my ($self, @args)=@_;
 496     return(map { $_->[0] } @{$self->cmd_rows(@args)});
 497 }
 498
 499 # runs cmd, returns id of last insert
 500 sub cmd_id
 501 {
 502     my ($self, @args)=@_;
 503     $self->cmd_sth(@args);
 504     return($self->last_insert_id());
 505 }
 506
 507 sub last_insert_id
 508 {
 509     my $self=shift;
 510     return $self->{dbh}->last_insert_id("","","","");
 511 }
 512
 513 # lookup id of $name in $table, also matching on $parent if needed
 514 sub lookup_id
 515 {
 516     my($self, $table, $name, $parent)=@_;
 517     my $sql="SELECT id FROM $table where name=?";
 518     my @args=($name);
 519     if($parent)
 520     {
 521         $sql .= " AND parents_id=?";
 522         push(@args, $parent);
 523     }
 524     my($id)=$self->cmd_onerow($sql, @args);
 525     return $id;
 526 }
 527
 528 __DATA__
 529
 530 CREATE TABLE id3fs (
 531     schema_version INTEGER,
 532     last_update
 533 );
 534
 535 CREATE TABLE paths (
 536     id INTEGER,
 537     name text,
 538     PRIMARY KEY(id ASC)
 539 );
 540
 541 CREATE TABLE artists (
 542     id INTEGER,
 543     name text,
 544     PRIMARY KEY(id ASC)
 545 );
 546
 547 CREATE TABLE albums (
 548     id INTEGER,
 549     name text,
 550     PRIMARY KEY(id ASC)
 551 );
 552
 553 CREATE TABLE files (
 554     id INTEGER,
 555     name text,
 556     artists_id,
 557     albums_id,
 558     paths_id,
 559     PRIMARY KEY(id ASC),
 560     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 561     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 562     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 563 );
 564
 565 CREATE TABLE tags (
 566     id INTEGER,
 567     parents_id INTEGER,
 568     name text,
 569     PRIMARY KEY(id ASC)
 570 );
 571
 572 CREATE TABLE files_x_tags (
 573     files_id INTEGER,
 574     tags_id INTEGER,
 575     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 576     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 577 );
 578
 579 CREATE INDEX idx_fxt_both ON files_x_tags (files_id, tags_id)
 580
 581 CREATE INDEX idx_fxt_tags ON files_x_tags (tags_id)
 582
 583 CREATE INDEX idx_files_id_name ON files (id, name)
 584
 585 CREATE INDEX idx_files_name_id ON files (name, id)
 586
 587 CREATE INDEX idx_tags_id_parent_name ON tags (id, parents_id, name)
 588
 589 CREATE INDEX idx_tags_parent_id_name ON tags (parents_id, id, name)
 590
 591 CREATE INDEX idx_tags_name ON tags (name)