lib/ID3FS/Path.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::Path;
  18
  19 use strict;
  20 use warnings;
  21 use ID3FS::Path::Node;
  22
  23 our ($STATE_INVALID, $STATE_ROOT, $STATE_TAG, $STATE_TAGVAL,
  24      $STATE_BOOLEAN, $STATE_ALBUMS, $STATE_TRACKLIST,
  25      $STATE_FILE, $STATE_ALL)=(0..8);
  26
  27 our %priorities=( "OR" => 0, "AND" => 1, "NOT" => 2 );
  28
  29 our $PATH_ALLTRACKS= "TRACKS";
  30 our $PATH_NOARTIST = "NOARTIST";
  31 our $PATH_NOALBUM  = "NOALBUM";
  32
  33 our $ENABLE_FILTER = 1;
  34
  35 sub new
  36 {
  37     my $proto=shift;
  38     my $class=ref($proto) || $proto;
  39     my $self={};
  40     bless($self,$class);
  41
  42     $self->{elements}=[];
  43     $self->{db}=shift;
  44     $self->{path}=shift;
  45     $self->{verbose}=shift;
  46     $self->{maxtagdepth}=shift;
  47     $self->{curtagdepth}=0;
  48     $self->{path} =~ s/\/\//\//g; # drop doubled slashes
  49
  50     $self->parse();
  51 #    print "STATE: ", $self->state(), "\n";
  52     return $self;
  53 }
  54
  55 sub isdir
  56 {
  57     my($self)=@_;
  58     if(($self->state() == $STATE_FILE) ||
  59        ($self->state() == $STATE_INVALID))
  60     {
  61         return 0;
  62     }
  63     return 1;
  64 }
  65
  66 sub isfile
  67 {
  68     my($self)=@_;
  69     return($self->state() == $STATE_FILE);
  70 }
  71
  72 sub isvalid
  73 {
  74     my($self)=@_;
  75     return($self->state() != $STATE_INVALID);
  76 }
  77
  78 sub dest
  79 {
  80     my($self, $mountpoint)=@_;
  81     if($self->state() == $STATE_FILE)
  82     {
  83         return $self->filename($mountpoint);
  84     }
  85     return "ERROR"; #should never happen?
  86 }
  87
  88 sub dirents
  89 {
  90     my($self)=@_;
  91     my @dents=();
  92     my @fents=();
  93     my $state=$self->state();
  94 #    print "DIRENTS: STATE: $state\n";
  95 #    print "DIRENTS: FILE: $self->{path}\n";
  96     if($state==$STATE_ALL)
  97     {
  98         @dents=($self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
  99     }
 100     elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
 101     {
 102         if($state==$STATE_TAG && $self->at("tag") &&
 103            $self->{db}->tag_has_values($self->tail()->id()))
 104         {
 105             @dents=$self->tags();
 106         }
 107         else
 108         {
 109             if($self->{maxtagdepth} && ($self->{curtagdepth} < $self->{maxtagdepth}))
 110             {
 111                 @dents=qw(AND OR);
 112             }
 113             push(@dents, $self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
 114         }
 115     }
 116     elsif($state==$STATE_BOOLEAN)
 117     {
 118         my $parent=$self->tail();
 119         unless($self->is("boolean", $parent) &&
 120                $parent->{name} eq "NOT")
 121         {
 122             @dents=("NOT");
 123         }
 124         push(@dents,$self->tags());
 125     }
 126     elsif($state==$STATE_ROOT)
 127     {
 128         @dents=(qw(ALL NOT), $self->tags());
 129     }
 130     elsif($state==$STATE_ALBUMS)
 131     {
 132         @dents=$self->filter($PATH_ALLTRACKS, $PATH_NOALBUM, $self->albums());
 133     }
 134     elsif($state==$STATE_TRACKLIST)
 135     {
 136         @fents=$self->tracks();
 137     }
 138     else
 139     {
 140         print "DIRENTS: UNHANDLED STATE: $state\n";
 141     }
 142     return(\@dents, \@fents);
 143 }
 144
 145 sub parse
 146 {
 147     my($self)=@_;
 148     @{$self->{components}}=split(/\//, $self->{path});
 149     shift @{$self->{components}}; # drop empty field before leading /
 150 #    print "PATH: $self->{path}\n";
 151     $self->state($STATE_ROOT);
 152     return if($self->{path} eq "/");
 153     my @parts=@{$self->{components}};
 154     my($tag, $tagval);
 155     $self->{elements}=[];
 156     $self->{in_all}=0;
 157     my $root_not=0;
 158     my $tags_seen=0;
 159     while(defined(my $name=shift @parts))
 160     {
 161 #       print "NAME: $name\n";
 162         my $state=$self->state();
 163         if($state==$STATE_INVALID)
 164         {
 165 #           print "SM: INVALID: $name\n";
 166             return;
 167         }
 168         elsif($state==$STATE_ROOT)
 169         {
 170 #           print "SM: ROOT: $name\n";
 171             if($name eq "ALL")
 172             {
 173                 $self->{in_all}=1;
 174                 $self->state($STATE_ALL);
 175             }
 176             elsif($name eq "NOT")
 177             {
 178                 $root_not=1;
 179                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 180                 $self->state($STATE_BOOLEAN);
 181             }
 182             else
 183             {
 184                 $tag=ID3FS::Path::Node->new($self->{db},"tag", $name);
 185                 if($tag)
 186                 {
 187                     push(@{$self->{elements}}, $tag);
 188                     $tags_seen++;
 189                     $self->state($STATE_TAG);
 190                 }
 191                 else
 192                 {
 193                     $self->state($STATE_INVALID);
 194                 }
 195             }
 196         }
 197         elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
 198         {
 199             my $tag=$self->tail();
 200 #           print "SM: TAG/TAGVAL($state): $name\n";
 201             if($state==$STATE_TAG && $self->is("tag", $tag) &&
 202                $self->{db}->tag_has_values($tag->id()))
 203             {
 204 #               print "Parsing: parent: $tag->id()\n";
 205                 my $tagval=ID3FS::Path::Node->new($self->{db}, "tag", $name, $tag->id());
 206                 if(defined($tagval))
 207                 {
 208                     $self->state($STATE_TAGVAL);
 209                     # stay in tag state
 210                     push(@{$self->{elements}}, $tagval);
 211                 }
 212                 else
 213                 {
 214                     $self->state($STATE_INVALID);
 215                 }
 216             }
 217             elsif($name eq $PATH_ALLTRACKS)
 218             {
 219                 $self->state($STATE_TRACKLIST);
 220             }
 221             elsif($name eq $PATH_NOARTIST)
 222             {
 223                 $self->state($STATE_TRACKLIST);
 224             }
 225             elsif($name eq "AND")
 226             {
 227                 $self->state($STATE_BOOLEAN);
 228                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 229             }
 230             elsif($name eq "OR")
 231             {
 232                 $self->state($STATE_BOOLEAN);
 233                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 234             }
 235             else
 236             {
 237                 my $artist=ID3FS::Path::Node->new($self->{db}, "artist", $name);
 238                 if($artist)
 239                 {
 240                     push(@{$self->{elements}}, $artist);
 241                     $self->state($STATE_ALBUMS);
 242                 }
 243                 else
 244                 {
 245                     $self->state($STATE_INVALID);
 246                 }
 247             }
 248         }
 249         elsif($state==$STATE_BOOLEAN)
 250         {
 251 #           print "SM: BOOLEAN: $name\n";
 252             my $parent=$self->tail();
 253             my $allownot=1;
 254             if($self->is("boolean", $parent) &&
 255                $parent->{name} eq "NOT")
 256             {
 257                 $allownot=0;
 258             }
 259             if($allownot && $name eq "NOT")
 260             {
 261                 $self->state($STATE_BOOLEAN);
 262                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 263             }
 264             else
 265             {
 266                 my $tag=ID3FS::Path::Node->new($self->{db}, "tag", $name);
 267                 if($tag)
 268                 {
 269                     push(@{$self->{elements}}, $tag);
 270                     $tags_seen++;
 271                     $self->state($STATE_TAG);
 272                 }
 273                 else
 274                 {
 275                     $self->state($STATE_INVALID);
 276                 }
 277             }
 278         }
 279         elsif($state==$STATE_ALBUMS)
 280         {
 281 #           print "SM: ALBUM: $name\n";
 282             if($name eq $PATH_ALLTRACKS)
 283             {
 284                 $self->state($STATE_TRACKLIST);
 285             }
 286             elsif($name eq $PATH_NOALBUM)
 287             {
 288                 $self->state($STATE_TRACKLIST);
 289             }
 290             else
 291             {
 292                 my $album=ID3FS::Path::Node->new($self->{db}, "album", $name);
 293                 if($album)
 294                 {
 295                     push(@{$self->{elements}}, $album);
 296                     $self->state($STATE_TRACKLIST);
 297                 }
 298                 else
 299                 {
 300                     $self->state($STATE_INVALID);
 301                 }
 302             }
 303         }
 304         elsif($state==$STATE_TRACKLIST)
 305         {
 306 #           print "SM: TRACKLIST: $name\n";
 307             my $track=ID3FS::Path::Node->new($self->{db}, "file", $name);
 308             if($track)
 309             {
 310                 push(@{$self->{elements}}, $track);
 311                 $self->state($STATE_FILE);
 312             }
 313             else
 314             {
 315                 $self->state($STATE_INVALID);
 316             }
 317         }
 318         elsif($state==$STATE_FILE)
 319         {
 320 #           print "SM: FILE: $name\n";
 321             # Can't have anything after a filename
 322             $self->state($STATE_INVALID);
 323         }
 324         elsif($state==$STATE_ALL)
 325         {
 326             if($name eq $PATH_ALLTRACKS)
 327             {
 328                 $self->state($STATE_TRACKLIST);
 329             }
 330             elsif($name eq $PATH_NOARTIST)
 331             {
 332                 $self->state($STATE_TRACKLIST);
 333             }
 334             else
 335             {
 336                 my $artist=ID3FS::Path::Node->new($self->{db}, "artist", $name);
 337                 if($artist)
 338                 {
 339                     push(@{$self->{elements}}, $artist);
 340                     $self->state($STATE_ALBUMS);
 341                 }
 342                 else
 343                 {
 344                     $self->state($STATE_INVALID);
 345                 }
 346             }
 347         }
 348         else
 349         {
 350             print "SM: ERROR: UNKNOWN STATE: $self->{state}\n";
 351             $self->state($STATE_INVALID);
 352         }
 353     }
 354
 355     # remove trailing boolean
 356     my @elements=@{$self->{elements}};
 357     while(@elements && $self->is("boolean", $elements[$#elements]))
 358     {
 359         pop @elements;
 360     }
 361     # sort elements by precedence
 362     @elements=$self->sort_elements(@elements);
 363     $self->{tagtree}=$self->elements_to_tree(\@elements);
 364     if($self->{tagtree})
 365     {
 366 #       my ($conditions, @joins)=$self->{tagtree}->to_sql();
 367 #       print "CONDITIONS(", scalar(@joins), "): ", $conditions, "\n";
 368     }
 369 }
 370
 371 sub state
 372 {
 373     my($self, $newstate)=@_;
 374     if(defined($newstate))
 375     {
 376         $self->{state}=$newstate;
 377         $self->{curtagdepth}++ if($newstate == $STATE_TAG);
 378     }
 379     return $self->{state};
 380 }
 381
 382 sub elements_to_tree
 383 {
 384     my($self, $elements)=@_;
 385     return undef unless(@$elements);
 386     my ($left, $right, $op)=(undef, undef, undef);
 387     my $thing=pop @$elements;
 388     if($self->is("boolean", $thing))
 389     {
 390         $right=$self->elements_to_tree($elements);
 391         if($thing->{name} ne "NOT")
 392         {
 393             $left=$self->elements_to_tree($elements);
 394         }
 395         $thing->left($left);
 396         $thing->right($right);
 397     }
 398     return $thing;
 399 }
 400
 401 # Dijkstra's shunting-yard algorithm
 402 sub sort_elements
 403 {
 404     my ($self, @input)=@_;
 405     my @opstack=();
 406     my @output=();
 407 #    print "INPUT: ", join(', ', map { $_->{name}; } @input), "\n";
 408     while(my $thing = shift @input)
 409     {
 410         if($self->is("tag", $thing))
 411         {
 412             # Handle tag values by dropping parent
 413             if(@input && $self->is("tag", $input[0]))
 414             {
 415                 $thing=shift @input;
 416             }
 417             push(@output, $thing);
 418         }
 419         elsif($self->is("boolean", $thing))
 420         {
 421             # bool
 422             while(@opstack &&
 423                   ($priorities{$thing->{name}} <= $priorities{$opstack[$#opstack]->{name}}))
 424             {
 425                 push(@output, pop(@opstack));
 426             }
 427             push(@opstack, $thing);
 428         }
 429     }
 430     while(@opstack)
 431     {
 432         push(@output, pop(@opstack));
 433     }
 434 #    print "STACK: ", join(', ', map { $_->{name}; } @output), "\n";
 435     return @output;
 436 }
 437
 438 sub used_tags
 439 {
 440     my($self)=@_;
 441     return() unless(defined($self->{tagtree}));
 442     return($self->{tagtree}->used_tags());
 443 }
 444
 445 sub expecting_values
 446 {
 447     my($self)=@_;
 448     my $tail=$self->tail();
 449     if($self->is("tag", $tail))
 450     {
 451         return($self->{db}->tag_has_values($tail->id()));
 452     }
 453 }
 454
 455 sub trailing_tag_id
 456 {
 457     my($self)=@_;
 458     my $tail=$self->tail();
 459     if($self->is("tag", $tail))
 460     {
 461         return($tail->id());
 462     }
 463     return undef;
 464 }
 465
 466 sub trailing_tag_parent
 467 {
 468     my($self)=@_;
 469     my $tail=$self->tail();
 470     if($self->is("tag", $tail))
 471     {
 472         return($tail->{parents_id});
 473     }
 474     return undef;
 475 }
 476
 477 sub tail
 478 {
 479     my($self)=@_;
 480     return($self->{elements}->[$#{$self->{elements}}]);
 481 }
 482
 483 sub at
 484 {
 485     my($self, $type)=@_;
 486     return($self->is($type, $self->tail()));
 487 }
 488
 489 sub is
 490 {
 491     my($self, $type, $thing)=@_;
 492     return 0 unless($thing);
 493     return 0 unless($thing->type());
 494     return 1 if($type eq $thing->type());
 495     return 0;
 496 }
 497
 498 # the one before last
 499 sub tail_parent
 500 {
 501     my($self)=@_;
 502     return($self->{elements}->[($#{$self->{elements}}) - 1]);
 503 }
 504
 505 ######################################################################
 506
 507 sub tags
 508 {
 509     my($self)=@_;
 510     if(!$self->{tagtree}) # / or /NOT
 511     {
 512         my $sql="SELECT DISTINCT name FROM tags WHERE parents_id='';";
 513         return($self->{db}->cmd_firstcol($sql));
 514     }
 515     my $hasvals=$self->expecting_values();
 516     my $parent=$self->trailing_tag_parent();
 517 #    print "THASVALS: $hasvals\n";
 518 #    print "TPARENT: ", (defined($parent)? $parent : "NO"), "\n";
 519     my @ids=();
 520     my $sql="SELECT tags.name FROM ";
 521     if($self->in_or())
 522     {
 523         $sql .= "files_x_tags\n";
 524     }
 525     else
 526     {
 527         $sql .= ("(\n" .
 528                  $self->tags_subselect() .
 529                  ") AS subselect\n" .
 530                  "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n");
 531     }
 532     $sql .= "INNER JOIN tags ON files_x_tags.tags_id=tags.id\n";
 533     my @andclauses=();
 534     my $id=$self->trailing_tag_id();
 535
 536     my $parentclause= "tags.parents_id='";
 537     if($hasvals)
 538     {
 539         $parentclause .= $id;
 540     }
 541     elsif($parent)
 542     {
 543         $parentclause .= $parent;
 544     }
 545     $parentclause .= "'";
 546     push(@andclauses, $parentclause);
 547
 548     my @used=$self->used_tags();
 549     if(@used)
 550     {
 551         push(@andclauses, "tags.id NOT IN (" . join(', ', @used) . ")");
 552     }
 553     if(@andclauses)
 554     {
 555         $sql .= "WHERE " . join(' AND ', @andclauses) . "\n";
 556     }
 557
 558     $sql .= "GROUP BY tags.name;";
 559     print "SQL(TAGS): $sql\n" if($self->{verbose});
 560     my @tagnames=$self->{db}->cmd_firstcol($sql);
 561     print("SUBNAMES: ", join(', ', @tagnames), "\n") if($self->{verbose});
 562     return(@tagnames);
 563 }
 564
 565 sub artists
 566 {
 567     my($self)=@_;
 568     if(!@{$self->{elements}}) # /ALL
 569     {
 570         my $sql="SELECT DISTINCT name FROM artists WHERE name!='';";
 571         return($self->{db}->cmd_firstcol($sql));
 572     }
 573     my @ids=();
 574     my $sql=$self->sql_start("artists.name");
 575     $sql .= ("INNER JOIN artists ON files.artists_id=artists.id\n" .
 576              "WHERE artists.name != ''\n" .
 577              "GROUP BY artists.name;");
 578     print "SQL(ARTISTS): $sql\n" if($self->{verbose});
 579     my @tagnames=$self->{db}->cmd_firstcol($sql);
 580     print("ARTISTS: ", join(', ', @tagnames), "\n") if($self->{verbose});
 581     return(@tagnames);
 582 }
 583
 584 sub albums
 585 {
 586     my($self)=@_;
 587     my @ids=();
 588     my $tail=$self->tail();
 589     if($self->is("artist", $tail))
 590     {
 591         return $self->artist_albums($tail->id());
 592     }
 593     my $sql=$self->sql_start("albums.name");
 594     $sql .= ("INNER JOIN albums ON files.albums_id=albums.id\n" .
 595              "WHERE albums.name != ''\n" .
 596              "GROUP BY albums.name;");
 597     print "SQL(ALBUMS): \n$sql\n" if($self->{verbose});
 598     my @names=$self->{db}->cmd_firstcol($sql);
 599     print("ALBUMS: ", join(', ', @names), "\n") if($self->{verbose});
 600     return(@names);
 601 }
 602
 603 sub artist_albums
 604 {
 605     my($self, $artist_id)=@_;
 606     my $sql=$self->sql_start("albums.name");
 607     $sql .= ("INNER JOIN albums ON albums.id=files.albums_id\n" .
 608              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 609              "WHERE artists.id=? and albums.name <> ''\n" .
 610              "GROUP BY albums.name\n");
 611     print "ARTIST_ALBUMS SQL: $sql\n" if($self->{verbose});
 612     my @albums=$self->{db}->cmd_firstcol($sql, $artist_id);
 613     print("ALBUMS: ", join(', ', @albums), "\n") if($self->{verbose});
 614     return(@albums);
 615 }
 616
 617 sub artist_tracks
 618 {
 619     my($self, $artist_id)=@_;
 620     my $sql=$self->sql_start("files.name");
 621     $sql .= ("INNER JOIN artists ON artists.id=files.artists_id\n" .
 622              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 623              "WHERE artists.id=? AND albums.name=''\n" .
 624              "GROUP BY files.name\n");
 625     print "ARTIST_TRACKS SQL: $sql\n" if($self->{verbose});
 626     my @names=$self->{db}->cmd_firstcol($sql, $artist_id);
 627     print("ARTISTTRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 628     return(@names);
 629 }
 630
 631 sub album_tracks
 632 {
 633     my($self, $artist_id, $album_id)=@_;
 634     my $sql=("SELECT files.name FROM files\n" .
 635              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 636              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 637              "WHERE artists.id=? AND albums.id=?\n" .
 638              "GROUP BY files.name\n");
 639     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n" if($self->{verbose});
 640     my @names=$self->{db}->cmd_firstcol($sql, $artist_id, $album_id);
 641     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 642     return(@names);
 643 }
 644
 645 sub tracks
 646 {
 647     my($self)=@_;
 648     my $tail=$self->tail();
 649     if($self->is("artist", $tail))
 650     {
 651         return $self->artist_tracks($tail->id());
 652     }
 653     elsif($self->is("album", $tail))
 654     {
 655         my $artist_id=0;
 656         my $artist=$self->tail_parent();
 657         if($self->is("artist", $artist))
 658         {
 659             # should always happen
 660             $artist_id=$artist->id();
 661         }
 662         return $self->album_tracks($artist_id, $tail->id());
 663     }
 664     my $sql=$self->sql_start("files.name");
 665     $sql .= "INNER JOIN artists ON files.artists_id=artists.id\n";
 666     if($self->{components}->[$#{$self->{components}}] eq $PATH_NOARTIST)
 667     {
 668         $sql .= "WHERE artists.name =''\n";
 669     }
 670     $sql .= "GROUP BY files.name;";
 671     print "TRACKS SQL($self->{path}): $sql\n" if($self->{verbose});
 672     my @names=$self->{db}->cmd_firstcol($sql);
 673     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 674     return(@names);
 675 }
 676
 677 sub filename
 678 {
 679     my($self, $mountpoint)=@_;
 680     my $tail=$self->tail();
 681     if($self->is("file", $tail))
 682     {
 683         my $id=$tail->id();
 684         my $sql=("SELECT paths.name, files.name FROM files\n" .
 685                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 686                  "WHERE files.id=?\n" .
 687                  "GROUP BY paths.name, files.name");
 688         print "FILENAME SQL: $sql\n" if($self->{verbose});
 689         my ($path, $name)=$self->{db}->cmd_onerow($sql, $id);
 690         my $id3fs_path=join('/', map { $_->{name}; }  @{$self->{elements}});
 691         return($self->{db}->relativise($path, $name, $mountpoint));
 692     }
 693     # should never happen
 694     return "ERROR";
 695 }
 696
 697 sub tags_subselect
 698 {
 699     my($self)=@_;
 700     my $hasvals=$self->expecting_values();
 701     if($self->{in_all})
 702     {
 703         # FIXME: is this used?
 704         die "IN_ALL CALLED!!\n";
 705         return "\tSELECT id FROM files AS files_id\n";
 706     }
 707     my $tree=$self->{tagtree};
 708     # FIXME
 709     print "UNDEF!!\n" unless($self->{tagtree});
 710     my $parent=$self->trailing_tag_parent();
 711
 712 #    print "ELEMENTS: ", join('/', map { $_->{name}; } @{$self->{elements}}), "\n";
 713 #    print "TREE: ", $tree->print(), "\n";
 714     my $tag=undef;
 715     if($hasvals)
 716     {
 717         $tag=$self->trailing_tag_id();
 718 #       print "Trailing id: $tag\n";
 719     }
 720     my ($sqlclause, @joins)=(undef, ());
 721     ($sqlclause, @joins) = $tree->to_sql($hasvals) if($tree);
 722 #    print "SQL(" . scalar(@joins) ."): $sqlclause\n";
 723     my $sql="\tSELECT fxt1.files_id FROM tags t1";
 724     my @crosses=();
 725     my @inners=();
 726 #    $joinsneeded++ if($tag);
 727     for(my $i=0; $i <= $#joins; $i++)
 728     {
 729         my $cnt=$i+1;
 730         my $join=$joins[$i];
 731         my $inner=("\t$join JOIN files_x_tags fxt$cnt ON " .
 732                    "t${cnt}.id=fxt${cnt}.tags_id");
 733         if($i > 0)
 734         {
 735             push(@crosses, "CROSS JOIN tags t$cnt");
 736             $inner .= " AND fxt1.files_id=fxt${cnt}.files_id";
 737         }
 738         push(@inners, $inner);
 739     }
 740     $sql .= ("\n\t" . join(" ", @crosses)) if(@crosses);
 741     $sql .= ("\n" . join("\n", @inners)) if(@inners);
 742     $sql .= "\n\tWHERE $sqlclause" if($sqlclause);
 743 #    if($tag)
 744 #    {
 745 #       $sql .= " AND t${joinsneeded}.parents_id='$tag'";
 746 #    }
 747     $sql .= "\n\tGROUP BY fxt1.files_id\n";
 748     return $sql;
 749 }
 750
 751 sub sql_start
 752 {
 753     my($self, $tables)=@_;
 754     my $sql="SELECT $tables FROM ";
 755     if($self->{in_all})
 756     {
 757         $sql .= "files\n";
 758     }
 759     else
 760     {
 761         $sql .= ("(\n" .
 762                  $self->tags_subselect() .
 763                  ") AS subselect\n" .
 764                  "INNER JOIN files ON subselect.files_id=files.id\n");
 765     }
 766     return $sql;
 767 }
 768
 769 # FIXME: remove
 770 sub constraints_tag_list
 771 {
 772     my($self, @constraints)=@_;
 773     my $lasttag=undef;
 774     my @tags=();
 775     my @tags_vals=();
 776     for my $constraint (@constraints)
 777     {
 778 #       print ref($constraint), ": ", $constraint->{name}, "\n";
 779         if($self->is("tag", $constraint))
 780         {
 781             if(defined($lasttag))
 782             {
 783 #               print "TAGVAL\n";
 784                 push(@tags_vals, [$lasttag, $constraint->id()]) if defined($constraint->id());
 785                 $lasttag=undef;
 786             }
 787             elsif($self->tag_has_values($constraint->id()))
 788             {
 789 #               print "HASVALUES\n";
 790                 $lasttag=$constraint->id() if defined($constraint->id());
 791             }
 792             else
 793             {
 794 #               print "NOVALUES\n";
 795                 push(@tags, $constraint->id()) if(defined($constraint->id()));
 796             }
 797         }
 798     }
 799     @tags=map{ "\"$_\""; } @tags;
 800     @tags_vals=map( { [ map({ "\"$_\""; } @$_ ) ] } @tags_vals);
 801     $lasttag="\"$lasttag\"" if defined($lasttag);
 802     return(\@tags, \@tags_vals, $lasttag);
 803 }
 804
 805 # we just filter $ALLTRACKS, $NOARTIST and $NOALBUM
 806 # filtering tags properly requires up to four levels of recursion
 807 # (tag/tagval/AND/NOT) and is too slow
 808 sub filter
 809 {
 810     my($self, @dirs)=@_;
 811     return(@dirs) unless($ENABLE_FILTER);
 812     my $base=$self->{path};
 813     my @outdirs=();
 814     for my $dir (@dirs)
 815     {
 816 #       print "\nFILTER (",$self->state(), "): $base / $dir\n";
 817         if($self->empty("$base/$dir"))
 818         {
 819 #           print "empty: $base / $dir\n";
 820         }
 821         else
 822         {
 823 #           print "non-empty, accepting: $base / $dir\n";
 824             push(@outdirs, $dir);
 825         }
 826     }
 827     return(@outdirs);
 828 }
 829
 830 sub empty
 831 {
 832     my($self, $dir)=@_;
 833     my $path=ID3FS::Path->new($self->{db}, $dir, $self->{verbose},
 834                               ($self->{maxtagdepth} - $self->{curtagdepth}));
 835     return 1 unless($path->isvalid());
 836     my($subdirs,$subfiles)=$path->dirents();
 837     return 0 if(@$subfiles || @$subdirs);
 838     return 1;
 839 }
 840
 841 # if path is .../OR/ or .../OR/NOT
 842 sub in_or
 843 {
 844     my($self)=@_;
 845     my $tail=$self->tail();
 846     return 0 unless($tail);
 847     return 0 unless($tail->type() eq "boolean");
 848     return 1 if($tail->name() eq "OR");
 849     return 0 unless($tail->name() eq "NOT");
 850     my $parent=$self->tail_parent();
 851     return 0 unless($parent);
 852     return 0 unless($parent->type() eq "boolean");
 853     return 1 if($parent->name() eq "OR");
 854     return 0;
 855 }
 856
 857 1;