lib/ID3FS/Path.pm

   1 package ID3FS::Path;
   2
   3 use strict;
   4 use warnings;
   5 use ID3FS::PathElement::Artist;
   6 use ID3FS::PathElement::Album;
   7 use ID3FS::PathElement::Boolean;
   8 use ID3FS::PathElement::File;
   9 use ID3FS::PathElement::Tag;
  10 use ID3FS::PathElement::Tagval;
  11 use ID3FS::Path::Node;
  12
  13 our ($STATE_INVALID, $STATE_ROOT, $STATE_TAG, $STATE_TAGVAL,
  14      $STATE_BOOLEAN, $STATE_ALBUMS, $STATE_TRACKLIST,
  15      $STATE_FILE, $STATE_ALL)=(0..8);
  16
  17 our %priorities=( "OR" => 0, "AND" => 1, "NOT" => 2 );
  18
  19 our $PATH_ALLTRACKS="TRACKS";
  20 our $PATH_NOARTIST="NOARTIST";
  21 our $PATH_NOALBUM="NOALBUM";
  22
  23 sub new
  24 {
  25     my $proto=shift;
  26     my $class=ref($proto) || $proto;
  27     my $self={};
  28     bless($self,$class);
  29
  30     $self->{elements}=[];
  31     $self->{db}=shift;
  32     $self->{path}=shift;
  33     $self->{verbose}=shift;
  34     $self->{path} =~ s/\/\//\//g; # drop doubled slashes
  35
  36     $self->parse();
  37 #    print "STATE: ", $self->state(), "\n";
  38     return $self;
  39 }
  40
  41 sub isdir
  42 {
  43     my($self)=@_;
  44     if(($self->state() == $STATE_FILE) ||
  45        ($self->state() == $STATE_INVALID))
  46     {
  47         return 0;
  48     }
  49     return 1;
  50 }
  51
  52 sub isfile
  53 {
  54     my($self)=@_;
  55     return 1 if($self->state() == $STATE_FILE);
  56     return 0;
  57 }
  58
  59 sub isvalid
  60 {
  61     my($self)=@_;
  62     return($self->state() != $STATE_INVALID);
  63 }
  64
  65 sub dest
  66 {
  67     my($self, $mountpoint)=@_;
  68     if($self->state() == $STATE_FILE)
  69     {
  70         return $self->filename($mountpoint, $self);
  71     }
  72     return "ERROR"; #should never happen?
  73 }
  74
  75 sub dirents
  76 {
  77     my($self)=@_;
  78     my @dents=();
  79     my @fents=();
  80     my $state=$self->state();
  81 #    print "DIRENTS: STATE: $state\n";
  82 #    print "DIRENTS: FILE: $self->{path}\n";
  83     if($state==$STATE_ALL)
  84     {
  85         @dents=($self->artists(), $PATH_ALLTRACKS, $PATH_NOARTIST);
  86     }
  87     elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
  88     {
  89         my $tag=$self->tail();
  90         if($state==$STATE_TAG &&
  91            defined($tag) &&
  92            ref($tag) eq "ID3FS::PathElement::Tag" &&
  93            $self->{db}->tag_has_values($tag->{id}))
  94         {
  95             @dents=$self->tags();
  96         }
  97         else
  98         {
  99             @dents=($self->artists(), qw(AND OR), $PATH_ALLTRACKS, $PATH_NOARTIST);
 100         }
 101     }
 102     elsif($state==$STATE_BOOLEAN)
 103     {
 104         @dents=$self->tags();
 105         my $parent=$self->tail();
 106         unless(defined($parent) &&
 107                ref($parent) eq "ID3FS::PathElement::Boolean" &&
 108                $parent->{name} eq "NOT")
 109         {
 110             push(@dents, "NOT");
 111         }
 112     }
 113     elsif($state==$STATE_ROOT)
 114     {
 115         @dents=($self->tags(), qw(ALL NOT));
 116     }
 117     elsif($state==$STATE_ALBUMS)
 118     {
 119         @dents=($self->albums(), $PATH_ALLTRACKS, $PATH_NOALBUM);
 120     }
 121     elsif($state==$STATE_TRACKLIST)
 122     {
 123         @fents=$self->tracks();
 124     }
 125     else
 126     {
 127         print "DIRENTS: UNHANDLED STATE: $state\n";
 128     }
 129     return(\@dents, \@fents);
 130 }
 131
 132 sub parse
 133 {
 134     my($self)=@_;
 135     @{$self->{components}}=split(/\//, $self->{path});
 136     shift @{$self->{components}}; # drop empty field before leading /
 137 #    print "PATH: $self->{path}\n";
 138     $self->state($STATE_ROOT);
 139     return if($self->{path} eq "/");
 140     my @parts=@{$self->{components}};
 141     my($tag, $tagval);
 142     $self->{elements}=[];
 143     $self->{bare_not}=0;
 144     $self->{in_all}=0;
 145     my $root_not=0;
 146     my $tags_seen=0;
 147     while(defined(my $name=shift @parts))
 148     {
 149 #       print "NAME: $name\n";
 150         my $state=$self->state();
 151         if($state==$STATE_INVALID)
 152         {
 153 #           print "SM: INVALID: $name\n";
 154             return;
 155         }
 156         elsif($state==$STATE_ROOT)
 157         {
 158 #           print "SM: ROOT: $name\n";
 159             if($name eq "ALL")
 160             {
 161                 $self->{in_all}=1;
 162                 $self->state($STATE_ALL);
 163             }
 164             elsif($name eq "NOT")
 165             {
 166                 $root_not=1;
 167                 push(@{$self->{elements}}, ID3FS::PathElement::Boolean->new($self->{db}, $name));
 168                 $self->state($STATE_BOOLEAN);
 169             }
 170             else
 171             {
 172                 $tag=ID3FS::PathElement::Tag->new($self->{db}, $name);
 173                 if($tag)
 174                 {
 175                     push(@{$self->{elements}}, $tag);
 176                     $tags_seen++;
 177                     $self->state($STATE_TAG);
 178                 }
 179                 else
 180                 {
 181                     $self->state($STATE_INVALID);
 182                 }
 183             }
 184         }
 185         elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
 186         {
 187 #           print "SM: TAG/TAGVAL($state): $name\n";
 188             my $tag=$self->tail();
 189             if($state==$STATE_TAG &&
 190                defined($tag) &&
 191                ref($tag) eq "ID3FS::PathElement::Tag" &&
 192                $self->{db}->tag_has_values($tag->{id}))
 193             {
 194 #               print "Parsing: parent: $tag->{id}\n";
 195                 my $tagval=ID3FS::PathElement::Tag->new($self->{db}, $name, $tag->{id});
 196                 if(defined($tagval))
 197                 {
 198                     $self->state($STATE_TAGVAL);
 199                     # stay in tag state
 200                     push(@{$self->{elements}}, $tagval);
 201                 }
 202                 else
 203                 {
 204                     $self->state($STATE_INVALID);
 205                 }
 206             }
 207             elsif($name eq $PATH_ALLTRACKS)
 208             {
 209                 $self->state($STATE_TRACKLIST);
 210             }
 211             elsif($name eq $PATH_NOARTIST)
 212             {
 213                 $self->state($STATE_TRACKLIST);
 214             }
 215             elsif($name eq "AND")
 216             {
 217                 $self->state($STATE_BOOLEAN);
 218                 push(@{$self->{elements}}, ID3FS::PathElement::Boolean->new($self->{db}, $name));
 219             }
 220             elsif($name eq "OR")
 221             {
 222                 $self->state($STATE_BOOLEAN);
 223                 push(@{$self->{elements}}, ID3FS::PathElement::Boolean->new($self->{db}, $name));
 224             }
 225             else
 226             {
 227                 my $artist=ID3FS::PathElement::Artist->new($self->{db}, $name);
 228                 if($artist)
 229                 {
 230                     push(@{$self->{elements}}, $artist);
 231                     $self->state($STATE_ALBUMS);
 232                 }
 233                 else
 234                 {
 235                     $self->state($STATE_INVALID);
 236                 }
 237             }
 238         }
 239         elsif($state==$STATE_BOOLEAN)
 240         {
 241 #           print "SM: BOOLEAN: $name\n";
 242             my $parent=$self->tail();
 243             my $allownot=1;
 244             if(defined($parent) &&
 245                ref($parent) eq "ID3FS::PathElement::Boolean" &&
 246                $parent->{name} eq "NOT")
 247             {
 248                 $allownot=0;
 249             }
 250             if($allownot && $name eq "NOT")
 251             {
 252                 $self->state($STATE_BOOLEAN);
 253                 push(@{$self->{elements}}, ID3FS::PathElement::Boolean->new($self->{db}, $name));
 254             }
 255             else
 256             {
 257                 my $tag=ID3FS::PathElement::Tag->new($self->{db}, $name);
 258                 if($tag)
 259                 {
 260                     push(@{$self->{elements}}, $tag);
 261                     $tags_seen++;
 262                     $self->state($STATE_TAG);
 263                 }
 264                 else
 265                 {
 266                     $self->state($STATE_INVALID);
 267                 }
 268             }
 269         }
 270         elsif($state==$STATE_ALBUMS)
 271         {
 272 #           print "SM: ALBUM: $name\n";
 273             if($name eq $PATH_ALLTRACKS)
 274             {
 275                 $self->state($STATE_TRACKLIST);
 276             }
 277             elsif($name eq $PATH_NOALBUM)
 278             {
 279                 $self->state($STATE_TRACKLIST);
 280             }
 281             else
 282             {
 283                 my $album=ID3FS::PathElement::Album->new($self->{db}, $name);
 284                 if($album)
 285                 {
 286                     push(@{$self->{elements}}, $album);
 287                     $self->state($STATE_TRACKLIST);
 288                 }
 289                 else
 290                 {
 291                     $self->state($STATE_INVALID);
 292                 }
 293             }
 294         }
 295         elsif($state==$STATE_TRACKLIST)
 296         {
 297 #           print "SM: TRACKLIST: $name\n";
 298             my $track=ID3FS::PathElement::File->new($self->{db}, $name);
 299             if($track)
 300             {
 301                 push(@{$self->{elements}}, $track);
 302                 $self->state($STATE_FILE);
 303             }
 304             else
 305             {
 306                 $self->state($STATE_INVALID);
 307             }
 308         }
 309         elsif($state==$STATE_FILE)
 310         {
 311 #           print "SM: FILE: $name\n";
 312             # Can't have anything after a filename
 313             $self->state($STATE_INVALID);
 314         }
 315         elsif($state==$STATE_ALL)
 316         {
 317             if($name eq $PATH_ALLTRACKS)
 318             {
 319                 $self->state($STATE_TRACKLIST);
 320             }
 321             elsif($name eq $PATH_NOARTIST)
 322             {
 323                 # FIXME
 324                 $self->state($STATE_TRACKLIST);
 325             }
 326             else
 327             {
 328                 my $artist=ID3FS::PathElement::Artist->new($self->{db}, $name);
 329                 if($artist)
 330                 {
 331                     push(@{$self->{elements}}, $artist);
 332                     $self->state($STATE_ALBUMS);
 333                 }
 334                 else
 335                 {
 336                     $self->state($STATE_INVALID);
 337                 }
 338             }
 339         }
 340         else
 341         {
 342             print "SM: ERROR: UNKNOWN STATE: $self->{state}\n";
 343             $self->state($STATE_INVALID);
 344         }
 345     }
 346
 347     if($root_not && ($tags_seen < 2))
 348     {
 349         $self->{bare_not}=1;
 350     }
 351
 352     # remove trailing boolean
 353     my @elements=@{$self->{elements}};
 354     while(@elements && ref($elements[$#elements]) eq "ID3FS::PathElement::Boolean")
 355     {
 356         pop @elements;
 357     }
 358     # sort elements by precedence
 359     @elements=$self->sort_elements(@elements);
 360     $self->{tagtree}=$self->elements_to_tree(\@elements);
 361     if($self->{tagtree})
 362     {
 363         ($self->{sqlconditions},
 364          $self->{joins}) = $self->{tagtree}->to_sql();
 365 #       print "TREE: ",  $self->{tagtree}->print(), "\n";
 366 #       print("SQL CONDITION(", scalar(@{$self->{joins}}), "): ",
 367 #             $self->{sqlconditions}, "\n");
 368 #       use Data::Dumper;
 369 #       print Dumper $self->{tagtree};
 370     }
 371 }
 372
 373 sub state
 374 {
 375     my($self, $newstate)=@_;
 376     $self->{state}=$newstate if(defined($newstate));
 377     return $self->{state};
 378 }
 379
 380 sub elements_to_tree
 381 {
 382     my($self, $elements)=@_;
 383     return undef unless(@$elements);
 384     my ($left, $right, $op)=(undef, undef, undef);
 385     my $thing=pop @$elements;
 386     if(ref($thing) eq "ID3FS::PathElement::Boolean")
 387     {
 388         my $op=$thing;
 389         $right=$self->elements_to_tree($elements);
 390         if($op->{name} ne "NOT")
 391         {
 392             $left=$self->elements_to_tree($elements);
 393         }
 394         return ID3FS::Path::Node->new($left, $op, $right);
 395     }
 396     else
 397     {
 398         return ID3FS::Path::Node->new($thing);
 399     }
 400 }
 401
 402 # Dijkstra's shunting-yard algorithm
 403 sub sort_elements
 404 {
 405     my ($self, @input)=@_;
 406     my @opstack=();
 407     my @output=();
 408 #    print "INPUT: ", join(', ', map { $_->{name}; } @input), "\n";
 409     while(my $thing = shift @input)
 410     {
 411         if(ref($thing) eq "ID3FS::PathElement::Tag")
 412         {
 413             # Handle tag values by dropping parent
 414             if(@input && ref($input[0]) eq "ID3FS::PathElement::Tag")
 415             {
 416                 $thing=shift @input;
 417             }
 418             push(@output, $thing);
 419         }
 420         elsif(ref($thing) eq "ID3FS::PathElement::Boolean")
 421         {
 422             # bool
 423             while(@opstack &&
 424                   ($priorities{$thing->{name}} <= $priorities{$opstack[$#opstack]->{name}}))
 425             {
 426                 push(@output, pop(@opstack));
 427             }
 428             push(@opstack, $thing);
 429         }
 430     }
 431     while(@opstack)
 432     {
 433         push(@output, pop(@opstack));
 434     }
 435 #    print "STACK: ", join(', ', map { $_->{name}; } @output), "\n";
 436     return @output;
 437 }
 438
 439 sub used_tags
 440 {
 441     my($self)=@_;
 442     return() unless(defined($self->{tagtree}));
 443     return($self->{tagtree}->used_tags());
 444 }
 445
 446 sub tag_has_values
 447 {
 448     my($self)=@_;
 449     my $tail=$self->tail();
 450     if($tail && ref($tail) eq "ID3FS::PathElement::Tag")
 451     {
 452         return($self->{db}->tag_has_values($tail->{id}));
 453     }
 454 }
 455
 456 sub trailing_tag_id
 457 {
 458     my($self)=@_;
 459     my $tail=$self->tail();
 460     if($tail && ref($tail) eq "ID3FS::PathElement::Tag")
 461     {
 462         return($tail->{id});
 463     }
 464     return undef;
 465 }
 466
 467 sub trailing_tag_parent
 468 {
 469     my($self)=@_;
 470     my $tail=$self->tail();
 471     if($tail && ref($tail) eq "ID3FS::PathElement::Tag")
 472     {
 473         return($tail->{parents_id});
 474     }
 475     return undef;
 476 }
 477
 478 sub tail
 479 {
 480     my($self)=@_;
 481     return($self->{elements}->[$#{$self->{elements}}]);
 482 }
 483
 484 # the one before last
 485 sub tail_parent
 486 {
 487     my($self)=@_;
 488     return($self->{elements}->[($#{$self->{elements}}) - 1]);
 489 }
 490
 491 ######################################################################
 492
 493 sub tags
 494 {
 495     my($self)=@_;
 496     if(!$self->{tagtree}) # / or /NOT  # FIXME: /ALL too?
 497     {
 498         my $sql="SELECT DISTINCT name FROM tags WHERE parents_id='';";
 499         return($self->{db}->cmd_firstcol($sql));
 500     }
 501     my $hasvals=$self->tag_has_values();
 502     my $parent=$self->trailing_tag_parent();
 503 #    print "THASVALS: $hasvals\n";
 504 #    print "TPARENT: ", (defined($parent)? $parent : "NO"), "\n";
 505     my @ids=();
 506     my $sql=("SELECT tags.name FROM (\n" .
 507              $self->tags_subselect() .
 508              ") AS subselect\n" .
 509              "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n" .
 510              "INNER JOIN tags ON files_x_tags.tags_id=tags.id\n");
 511     my @allused=$self->used_tags();
 512     my @used=grep { ref($_) ne "ARRAY"; } @allused;
 513     my @used_with_vals=grep { ref($_) eq "ARRAY"; } @allused;
 514 #    print "tags(): USED: ", join(", ", @used), "\n";
 515 #    print "tags(): USED_WITH_VALS: ", join(", ", map { "[".$_->[0]. ", ".$_->[1]."]";} @used_with_vals), "\n";
 516     my @orclauses=();
 517     my @andclauses=();
 518     my $id=$self->trailing_tag_id();
 519     if($hasvals)
 520     {
 521 #       print "HAS_VALUES\n";
 522         my @values=map { "'".$_->[1]."'"; } grep { $_->[0] == $id; } @used_with_vals;
 523         my $clause="(tags.parents_id='$id'";
 524         if(@values)
 525         {
 526             $clause .= " AND tags.id NOT IN (" . join(', ', @values) . ")";
 527         }
 528         $clause .= ")";
 529         push(@andclauses, $clause);
 530     }
 531     else
 532     {
 533 #       print "HASNT VALUES\n";;
 534         if(@used)
 535         {
 536             push(@andclauses, "(NOT (tags.parents_id='' AND tags.id IN (" . join(', ', @used) . ")))");
 537         }
 538         for my $pair (@used_with_vals)
 539         {
 540             push(@andclauses, "(NOT (tags.parents_id='" . $pair->[0] . "' AND tags.id='" . $pair->[1] . "'))");
 541         }
 542     }
 543
 544     my $parentclause= "(tags.parents_id='";
 545     if($hasvals)
 546     {
 547         $parentclause .= $id;
 548     }
 549     elsif($parent)
 550     {
 551         $parentclause .= $parent;
 552     }
 553     $parentclause .= "')";
 554     push(@andclauses, $parentclause);
 555
 556     if(@orclauses)
 557     {
 558         push(@andclauses, '( ' . join(' OR ', @orclauses) . ' )');
 559     }
 560     if(@andclauses)
 561     {
 562         $sql .= "WHERE " . join(' AND ', @andclauses) . "\n";
 563     }
 564     $sql .= "GROUP BY tags.name;";
 565     print "SQL(TAGS): $sql\n" if($self->{verbose});
 566     my @tagnames=$self->{db}->cmd_firstcol($sql);
 567     print("SUBNAMES: ", join(', ', @tagnames), "\n") if($self->{verbose});
 568     return(@tagnames);
 569 }
 570
 571 sub tag_values
 572 {
 573     my($self, $tagid)=@_;
 574     my $sql=("SELECT DISTINCT name FROM tags\n" .
 575              "WHERE parents_id=?");
 576     my @tags=$self->{db}->cmd_firstcol($sql, $tagid);
 577     @tags=map { length($_) ? $_ : "NOVALUE"; } @tags;
 578     return @tags;
 579 }
 580
 581 sub artists
 582 {
 583     my($self)=@_;
 584     if(!@{$self->{elements}}) # /ALL
 585     {
 586         my $sql="SELECT DISTINCT name FROM artists WHERE name!='';";
 587         return($self->{db}->cmd_firstcol($sql));
 588     }
 589     my @ids=();
 590     my $sql=("SELECT artists.name FROM (\n" .
 591              $self->tags_subselect() .
 592              ") AS subselect\n" .
 593              "INNER JOIN files ON subselect.files_id=files.id\n" .
 594              "INNER JOIN artists ON files.artists_id=artists.id\n" .
 595              "WHERE artists.name != ''\n" .
 596              "GROUP BY artists.name;");
 597     print "SQL(ARTISTS): $sql\n" if($self->{verbose});
 598     my @tagnames=$self->{db}->cmd_firstcol($sql);
 599     print("ARTISTS: ", join(', ', @tagnames), "\n") if($self->{verbose});
 600     return(@tagnames);
 601 }
 602
 603 sub albums
 604 {
 605     my($self)=@_;
 606     my @ids=();
 607     my $tail=$self->tail();
 608     # FIXME: rework PathElements
 609     if(ref($tail) eq "ID3FS::PathElement::Artist")
 610     {
 611         return $self->artist_albums($tail->{id});
 612     }
 613     my $sql;
 614     if($self->{in_all})
 615     {
 616         $sql="SELECT name FROM albums";
 617     }
 618     else
 619     {
 620         $sql=("SELECT albums.name\n" .
 621               "\tFROM (\n" .
 622               $self->tags_subselect() .
 623               "\t) AS subselect\n" .
 624               "INNER JOIN files ON subselect.files_id=files.id\n" .
 625               "INNER JOIN albums ON files.albums_id=albums.id\n" .
 626               "WHERE albums.name != ''\n" .
 627               "GROUP BY albums.name;");
 628     }
 629     print "SQL(ALBUMS): \n$sql\n" if($self->{verbose});
 630     my @names=$self->{db}->cmd_firstcol($sql);
 631     print("ALBUMS: ", join(', ', @names), "\n") if($self->{verbose});
 632     return(@names);
 633 }
 634
 635 sub artist_albums
 636 {
 637     my($self, $artist_id)=@_;
 638     my $sql="SELECT albums.name FROM ";
 639     if($self->{in_all})
 640     {
 641         $sql .= "files\n";
 642     }
 643     else
 644     {
 645         $sql .= ("(\n" .
 646                  $self->tags_subselect() .
 647                  ") AS subselect\n" .
 648                  "INNER JOIN files ON subselect.files_id=files.id\n");
 649     }
 650     $sql .= ("INNER JOIN albums ON albums.id=files.albums_id\n" .
 651              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 652              "WHERE artists.id=? and albums.name <> ''\n" .
 653              "GROUP BY albums.name\n");
 654     print "ARTIST_ALBUMS SQL: $sql\n" if($self->{verbose});
 655     my @albums=$self->{db}->cmd_firstcol($sql, $artist_id);
 656     print("ALBUMS: ", join(', ', @albums), "\n") if($self->{verbose});
 657     return(@albums);
 658 }
 659
 660 sub artist_tracks
 661 {
 662     my($self, $artist_id)=@_;
 663     my $sql="SELECT files.name FROM ";
 664     if($self->{in_all})
 665     {
 666         $sql .= "files\n";
 667     }
 668     else
 669     {
 670         $sql .= ("(\n" .
 671                  $self->tags_subselect() .
 672                  "\t) AS subselect\n" .
 673                  "INNER JOIN files ON subselect.files_id=files.id\n");
 674     }
 675     $sql .= ("INNER JOIN artists ON artists.id=files.artists_id\n" .
 676              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 677              "WHERE artists.id=? AND albums.name=''\n" .
 678              "GROUP BY files.name\n");
 679     print "ARTIST_TRACKS SQL: $sql\n" if($self->{verbose});
 680     my @names=$self->{db}->cmd_firstcol($sql, $artist_id);
 681     print("ARTISTTRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 682     return(@names);
 683 }
 684
 685 sub album_tracks
 686 {
 687     my($self, $artist_id, $album_id)=@_;
 688     my $sql=("SELECT files.name FROM files\n" .
 689              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 690              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 691              "WHERE artists.id=? AND albums.id=?\n" .
 692              "GROUP BY files.name\n");
 693     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n" if($self->{verbose});
 694     my @names=$self->{db}->cmd_firstcol($sql, $artist_id, $album_id);
 695     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 696     return(@names);
 697 }
 698
 699 sub tracks
 700 {
 701     my($self)=@_;
 702     # FIXME: rework PathElements
 703     my $tail=$self->tail();
 704     if(ref($tail) eq "ID3FS::PathElement::Artist")
 705     {
 706         return $self->artist_tracks($tail->{id});
 707     }
 708     elsif(ref($tail) eq "ID3FS::PathElement::Album")
 709     {
 710         my $artist_id=0;
 711         my $artist=$self->tail_parent();
 712         if(defined($artist) && (ref($artist) eq "ID3FS::PathElement::Artist"))
 713         {
 714             # should always happen
 715             $artist_id=$artist->{id};
 716         }
 717         return $self->album_tracks($artist_id, $tail->{id});
 718     }
 719     my $sql="SELECT files.name FROM ";
 720     if($self->{in_all})
 721     {
 722         $sql .= "files\n";
 723     }
 724     else
 725     {
 726         $sql .= ("(\n" .
 727                  $self->tags_subselect() .
 728                  ") AS subselect\n" .
 729                  "INNER JOIN files ON files.id=subselect.files_id\n");
 730     }
 731     $sql .= "INNER JOIN artists ON files.artists_id=artists.id\n";
 732     if($self->{components}->[$#{$self->{components}}] eq $PATH_NOARTIST)
 733     {
 734         $sql .= "WHERE artists.name =''\n";
 735     }
 736     $sql .= "GROUP BY files.name;";
 737     print "TRACKS SQL($self->{path}): $sql\n" if($self->{verbose});
 738     my @names=$self->{db}->cmd_firstcol($sql);
 739     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 740     return(@names);
 741 }
 742
 743 sub filename
 744 {
 745     my($self, $mountpoint)=@_;
 746     my $tail=$self->tail();
 747     if(ref($tail) eq "ID3FS::PathElement::File")
 748     {
 749         my $id=$tail->{id};
 750         my $sql=("SELECT paths.name, files.name FROM files\n" .
 751                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 752                  "WHERE files.id=?\n" .
 753                  "GROUP BY paths.name, files.name");
 754         print "FILENAME SQL: $sql\n" if($self->{verbose});
 755         my ($path, $name)=$self->{db}->cmd_onerow($sql, $id);
 756         my $id3fs_path=join('/', map { $_->{name}; }  @{$self->{elements}});
 757         return($self->{db}->relativise($path, $name, $mountpoint, $id3fs_path));
 758     }
 759     die("DB::filename: unhandled case\n"); #FIXME
 760 }
 761
 762 sub tags_subselect
 763 {
 764     my($self)=@_;
 765     my $hasvals=$self->tag_has_values();
 766     # we need to specially handle a bare /NOT/tag with no other clauses,
 767     # using a simple WHERE id !='tagid' instead of a LEFT JOIN
 768     if($self->{bare_not})
 769     {
 770         return $self->bare_not_subselect();
 771     }
 772     if($self->{in_all})
 773     {
 774         return "\tSELECT id FROM files AS files_id\n";
 775     }
 776     my $tree=$self->{tagtree};
 777     my $parent=$self->trailing_tag_parent();
 778
 779 #    print "ELEMENTS: ", join('/', map { $_->{name}; } @{$self->{elements}}), "\n";
 780 #    print "TREE: ", $tree->print(), "\n";
 781     my $tag=undef;
 782     if($hasvals)
 783     {
 784         $tag=$self->trailing_tag_id();
 785 #       print "Trailing id: $tag\n";
 786     }
 787     my ($sqlclause, @joins)=(undef, ());
 788     ($sqlclause, @joins) = $tree->to_sql($hasvals) if($tree);
 789 #    print "SQL(" . scalar(@joins) .": $sqlclause\n";
 790     my $sql="\tSELECT fxt1.files_id FROM tags t1";
 791     my @crosses=();
 792     my @inners=();
 793 #    $joinsneeded++ if($tag);
 794     for(my $i=0; $i <= $#joins; $i++)
 795     {
 796         my $cnt=$i+1;
 797         my $join=$joins[$i];
 798         my $inner=("\t$join JOIN files_x_tags fxt$cnt ON " .
 799                    "t${cnt}.id=fxt${cnt}.tags_id");
 800         if($i > 0)
 801         {
 802             push(@crosses, "CROSS JOIN tags t$cnt");
 803             $inner .= " AND fxt1.files_id=fxt${cnt}.files_id";
 804         }
 805         push(@inners, $inner);
 806     }
 807     $sql .= ("\n\t" . join(" ", @crosses)) if(@crosses);
 808     $sql .= ("\n" . join("\n", @inners)) if(@inners);
 809     $sql .= "\n\tWHERE $sqlclause" if($sqlclause);
 810 #    if($tag)
 811 #    {
 812 #       $sql .= " AND t${joinsneeded}.parents_id='$tag'";
 813 #    }
 814     $sql .= "\n\tGROUP BY fxt1.files_id\n";
 815     return $sql;
 816 }
 817
 818 sub bare_not_subselect
 819 {
 820     my($self)=@_;
 821     my @tags=grep { ref($_) eq "ID3FS::PathElement::Tag"; } @{$self->{elements}};
 822     my $sql=("\tSELECT f1.id AS files_id FROM files f1 WHERE f1.id NOT IN (\n" .
 823              "\t\tSELECT fxt1.files_id FROM tags t1\n" .
 824              "\t\tINNER JOIN files_x_tags fxt1 ON t1.id=fxt1.tags_id\n" .
 825              "\t\tWHERE ");
 826     if(scalar(@tags) > 1)
 827     {
 828         $sql .= ("(t1.parents_id='" . $tags[0]->{id} . "' AND t1.id='" .
 829                  $tags[1]->{id} . "')");
 830     }
 831     else
 832     {
 833         $sql .= ("(t1.parents_id='' AND t1.id='" . $tags[0]->{id} . "')");
 834     }
 835     $sql .= "\n\t\tGROUP BY fxt1.files_id\n\t)\n";
 836     return($sql);
 837 }
 838
 839 sub constraints_tag_list
 840 {
 841     my($self, @constraints)=@_;
 842     my $lasttag=undef;
 843     my @tags=();
 844     my @tags_vals=();
 845     for my $constraint (@constraints)
 846     {
 847 #       print ref($constraint), ": ", $constraint->{name}, "\n";
 848         if(ref($constraint) eq "ID3FS::PathElement::Tag")
 849         {
 850             if(defined($lasttag))
 851             {
 852 #               print "TAGVAL\n";
 853                 push(@tags_vals, [$lasttag, $constraint->{id}]) if defined($constraint->{id});
 854                 $lasttag=undef;
 855             }
 856             elsif($self->tag_has_values($constraint->{id}))
 857             {
 858 #               print "HASVALUES\n";
 859                 $lasttag=$constraint->{id} if defined($constraint->{id});
 860             }
 861             else
 862             {
 863 #               print "NOVALUES\n";
 864                 push(@tags, $constraint->{id}) if(defined($constraint->{id}));
 865             }
 866         }
 867     }
 868     unless($self->{db}->{postgres})
 869     {
 870         @tags=map{ "\"$_\""; } @tags;
 871         @tags_vals=map( { [ map({ "\"$_\""; } @$_ ) ] } @tags_vals);
 872         $lasttag="\"$lasttag\"" if defined($lasttag);
 873     }
 874     return(\@tags, \@tags_vals, $lasttag);
 875 }
 876
 877
 878 sub bare_tags
 879 {
 880     my($self)=@_;
 881     my $sql=("SELECT tags.name FROM tags\n" .
 882              "WHERE tags.parents_id=''\n" .
 883              "GROUP BY tags.name\n");
 884     my @names=$self->{db}->cmd_firstcol($sql);
 885     return (@names);
 886 }
 887
 888 sub tags_with_values
 889 {
 890     # FIXME: only shows one level of tag depth
 891     my($self)=@_;
 892     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 893              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 894              "GROUP BY p.name, t.name\n");
 895 #    print "SQL: $sql\n";
 896     my $result=$self->{db}->cmd_rows($sql);
 897     my $tags={};
 898     for my $pair (@$result)
 899     {
 900         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 901     }
 902     return $tags;
 903 }
 904
 905
 906 sub filter
 907 {
 908     my($self, @dirs)=@_;
 909     my $base=$self->{path};
 910     my @outdirs=();
 911     # depth 4 to allow for tag/tagval/AND/NOT
 912     my $maxdepth=4;
 913     for my $dir (@dirs)
 914     {
 915 #       print "\nFILTER (",$self->state(), "): $base / $dir\n";
 916         if($self->empty("$base/$dir", $maxdepth))
 917         {
 918 #           print "empty: $base / $dir\n";
 919         }
 920         else
 921         {
 922 #           print "non-empty, accepting: $base / $dir\n";
 923             push(@outdirs, $dir);
 924         }
 925     }
 926     return(@outdirs);
 927 }
 928
 929 sub empty
 930 {
 931     my($self, $dir, $maxdepth)=@_;
 932     return 0 unless($maxdepth);
 933 #    print "testing($maxdepth): $dir\n";
 934     my $path=ID3FS::Path->new($self->{db}, $dir, $self->{verbose});
 935 #    print "PATH INVALID\n" unless($path->isvalid());
 936     return 1 unless($path->isvalid());
 937     my($subdirs,$subfiles)=$path->dirents();
 938 #    print "SUBDENTS: ", join(", ", @$subdirs, @$subfiles), "\n";
 939 #    print("SUBFILES: ", join(', ', @$subfiles), "\n") if(@$subfiles);
 940     return 0 if(@$subfiles);
 941     for my $subdir (@$subdirs)
 942     {
 943 #       print "SUBSUB $dir/$subdir\n";
 944         if(1) #$self->dir_is_special($subdir))
 945         {
 946             if($self->empty("$dir/$subdir", ($maxdepth-1)))
 947             {
 948 #               print "EMPTY: $dir / $subdir\n";
 949             }
 950             else
 951             {
 952 #               print "NONEMPTY: $dir / $subdir\n";
 953                 return 0;
 954             }
 955         }
 956         else
 957         {
 958             return 0;
 959         }
 960 #       return 0 if($self->nonempty("$dir/$subdir", ($maxdepth-1)));
 961     }
 962     return 1;
 963 }
 964
 965 sub tagname_has_values
 966 {
 967     my($self, $name)=@_;
 968     my $id=$self->{db}->lookup_id("tags", $name);
 969     return 0 unless($id);
 970     return $self->{db}->tag_has_values($id);
 971
 972 }
 973
 974 sub dir_is_special
 975 {
 976     my($self, $dir)=@_;
 977     if((grep { $_ eq $dir; }
 978         qw(AND OR NOT), $PATH_ALLTRACKS, $PATH_NOARTIST, $PATH_NOALBUM) ||
 979        ($self->tagname_has_values($dir)))
 980     {
 981         return 1;
 982     }
 983     return 0;
 984 }
 985
 986 1;