lib/ID3FS/Path.pm

   1 package ID3FS::Path;
   2
   3 use strict;
   4 use warnings;
   5 use ID3FS::Path::Node;
   6
   7 our ($STATE_INVALID, $STATE_ROOT, $STATE_TAG, $STATE_TAGVAL,
   8      $STATE_BOOLEAN, $STATE_ALBUMS, $STATE_TRACKLIST,
   9      $STATE_FILE, $STATE_ALL)=(0..8);
  10
  11 our %priorities=( "OR" => 0, "AND" => 1, "NOT" => 2 );
  12
  13 our $PATH_ALLTRACKS= "TRACKS";
  14 our $PATH_NOARTIST = "NOARTIST";
  15 our $PATH_NOALBUM  = "NOALBUM";
  16
  17 our $ENABLE_FILTER = 1;
  18
  19 sub new
  20 {
  21     my $proto=shift;
  22     my $class=ref($proto) || $proto;
  23     my $self={};
  24     bless($self,$class);
  25
  26     $self->{elements}=[];
  27     $self->{db}=shift;
  28     $self->{path}=shift;
  29     $self->{verbose}=shift;
  30     $self->{maxtagdepth}=shift;
  31     $self->{curtagdepth}=0;
  32     $self->{path} =~ s/\/\//\//g; # drop doubled slashes
  33
  34     $self->parse();
  35 #    print "STATE: ", $self->state(), "\n";
  36     return $self;
  37 }
  38
  39 sub isdir
  40 {
  41     my($self)=@_;
  42     if(($self->state() == $STATE_FILE) ||
  43        ($self->state() == $STATE_INVALID))
  44     {
  45         return 0;
  46     }
  47     return 1;
  48 }
  49
  50 sub isfile
  51 {
  52     my($self)=@_;
  53     return($self->state() == $STATE_FILE);
  54 }
  55
  56 sub isvalid
  57 {
  58     my($self)=@_;
  59     return($self->state() != $STATE_INVALID);
  60 }
  61
  62 sub dest
  63 {
  64     my($self, $mountpoint)=@_;
  65     if($self->state() == $STATE_FILE)
  66     {
  67         return $self->filename($mountpoint);
  68     }
  69     return "ERROR"; #should never happen?
  70 }
  71
  72 sub dirents
  73 {
  74     my($self)=@_;
  75     my @dents=();
  76     my @fents=();
  77     my $state=$self->state();
  78 #    print "DIRENTS: STATE: $state\n";
  79 #    print "DIRENTS: FILE: $self->{path}\n";
  80     if($state==$STATE_ALL)
  81     {
  82         @dents=($self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
  83     }
  84     elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
  85     {
  86         if($state==$STATE_TAG && $self->at("tag") &&
  87            $self->{db}->tag_has_values($self->tail()->id()))
  88         {
  89             @dents=$self->tags();
  90         }
  91         else
  92         {
  93             if($self->{maxtagdepth} && ($self->{curtagdepth} < $self->{maxtagdepth}))
  94             {
  95                 @dents=qw(AND OR);
  96             }
  97             push(@dents, $self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
  98         }
  99     }
 100     elsif($state==$STATE_BOOLEAN)
 101     {
 102         my $parent=$self->tail();
 103         unless($self->is("boolean", $parent) &&
 104                $parent->{name} eq "NOT")
 105         {
 106             @dents=("NOT");
 107         }
 108         push(@dents,$self->tags());
 109     }
 110     elsif($state==$STATE_ROOT)
 111     {
 112         @dents=(qw(ALL NOT), $self->tags());
 113     }
 114     elsif($state==$STATE_ALBUMS)
 115     {
 116         @dents=$self->filter($PATH_ALLTRACKS, $PATH_NOALBUM, $self->albums());
 117     }
 118     elsif($state==$STATE_TRACKLIST)
 119     {
 120         @fents=$self->tracks();
 121     }
 122     else
 123     {
 124         print "DIRENTS: UNHANDLED STATE: $state\n";
 125     }
 126     return(\@dents, \@fents);
 127 }
 128
 129 sub parse
 130 {
 131     my($self)=@_;
 132     @{$self->{components}}=split(/\//, $self->{path});
 133     shift @{$self->{components}}; # drop empty field before leading /
 134 #    print "PATH: $self->{path}\n";
 135     $self->state($STATE_ROOT);
 136     return if($self->{path} eq "/");
 137     my @parts=@{$self->{components}};
 138     my($tag, $tagval);
 139     $self->{elements}=[];
 140     $self->{in_all}=0;
 141     my $root_not=0;
 142     my $tags_seen=0;
 143     while(defined(my $name=shift @parts))
 144     {
 145 #       print "NAME: $name\n";
 146         my $state=$self->state();
 147         if($state==$STATE_INVALID)
 148         {
 149 #           print "SM: INVALID: $name\n";
 150             return;
 151         }
 152         elsif($state==$STATE_ROOT)
 153         {
 154 #           print "SM: ROOT: $name\n";
 155             if($name eq "ALL")
 156             {
 157                 $self->{in_all}=1;
 158                 $self->state($STATE_ALL);
 159             }
 160             elsif($name eq "NOT")
 161             {
 162                 $root_not=1;
 163                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 164                 $self->state($STATE_BOOLEAN);
 165             }
 166             else
 167             {
 168                 $tag=ID3FS::Path::Node->new($self->{db},"tag", $name);
 169                 if($tag)
 170                 {
 171                     push(@{$self->{elements}}, $tag);
 172                     $tags_seen++;
 173                     $self->state($STATE_TAG);
 174                 }
 175                 else
 176                 {
 177                     $self->state($STATE_INVALID);
 178                 }
 179             }
 180         }
 181         elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
 182         {
 183             my $tag=$self->tail();
 184 #           print "SM: TAG/TAGVAL($state): $name\n";
 185             if($state==$STATE_TAG && $self->is("tag", $tag) &&
 186                $self->{db}->tag_has_values($tag->id()))
 187             {
 188 #               print "Parsing: parent: $tag->id()\n";
 189                 my $tagval=ID3FS::Path::Node->new($self->{db}, "tag", $name, $tag->id());
 190                 if(defined($tagval))
 191                 {
 192                     $self->state($STATE_TAGVAL);
 193                     # stay in tag state
 194                     push(@{$self->{elements}}, $tagval);
 195                 }
 196                 else
 197                 {
 198                     $self->state($STATE_INVALID);
 199                 }
 200             }
 201             elsif($name eq $PATH_ALLTRACKS)
 202             {
 203                 $self->state($STATE_TRACKLIST);
 204             }
 205             elsif($name eq $PATH_NOARTIST)
 206             {
 207                 $self->state($STATE_TRACKLIST);
 208             }
 209             elsif($name eq "AND")
 210             {
 211                 $self->state($STATE_BOOLEAN);
 212                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 213             }
 214             elsif($name eq "OR")
 215             {
 216                 $self->state($STATE_BOOLEAN);
 217                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 218             }
 219             else
 220             {
 221                 my $artist=ID3FS::Path::Node->new($self->{db}, "artist", $name);
 222                 if($artist)
 223                 {
 224                     push(@{$self->{elements}}, $artist);
 225                     $self->state($STATE_ALBUMS);
 226                 }
 227                 else
 228                 {
 229                     $self->state($STATE_INVALID);
 230                 }
 231             }
 232         }
 233         elsif($state==$STATE_BOOLEAN)
 234         {
 235 #           print "SM: BOOLEAN: $name\n";
 236             my $parent=$self->tail();
 237             my $allownot=1;
 238             if($self->is("boolean", $parent) &&
 239                $parent->{name} eq "NOT")
 240             {
 241                 $allownot=0;
 242             }
 243             if($allownot && $name eq "NOT")
 244             {
 245                 $self->state($STATE_BOOLEAN);
 246                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 247             }
 248             else
 249             {
 250                 my $tag=ID3FS::Path::Node->new($self->{db}, "tag", $name);
 251                 if($tag)
 252                 {
 253                     push(@{$self->{elements}}, $tag);
 254                     $tags_seen++;
 255                     $self->state($STATE_TAG);
 256                 }
 257                 else
 258                 {
 259                     $self->state($STATE_INVALID);
 260                 }
 261             }
 262         }
 263         elsif($state==$STATE_ALBUMS)
 264         {
 265 #           print "SM: ALBUM: $name\n";
 266             if($name eq $PATH_ALLTRACKS)
 267             {
 268                 $self->state($STATE_TRACKLIST);
 269             }
 270             elsif($name eq $PATH_NOALBUM)
 271             {
 272                 $self->state($STATE_TRACKLIST);
 273             }
 274             else
 275             {
 276                 my $album=ID3FS::Path::Node->new($self->{db}, "album", $name);
 277                 if($album)
 278                 {
 279                     push(@{$self->{elements}}, $album);
 280                     $self->state($STATE_TRACKLIST);
 281                 }
 282                 else
 283                 {
 284                     $self->state($STATE_INVALID);
 285                 }
 286             }
 287         }
 288         elsif($state==$STATE_TRACKLIST)
 289         {
 290 #           print "SM: TRACKLIST: $name\n";
 291             my $track=ID3FS::Path::Node->new($self->{db}, "file", $name);
 292             if($track)
 293             {
 294                 push(@{$self->{elements}}, $track);
 295                 $self->state($STATE_FILE);
 296             }
 297             else
 298             {
 299                 $self->state($STATE_INVALID);
 300             }
 301         }
 302         elsif($state==$STATE_FILE)
 303         {
 304 #           print "SM: FILE: $name\n";
 305             # Can't have anything after a filename
 306             $self->state($STATE_INVALID);
 307         }
 308         elsif($state==$STATE_ALL)
 309         {
 310             if($name eq $PATH_ALLTRACKS)
 311             {
 312                 $self->state($STATE_TRACKLIST);
 313             }
 314             elsif($name eq $PATH_NOARTIST)
 315             {
 316                 $self->state($STATE_TRACKLIST);
 317             }
 318             else
 319             {
 320                 my $artist=ID3FS::Path::Node->new($self->{db}, "artist", $name);
 321                 if($artist)
 322                 {
 323                     push(@{$self->{elements}}, $artist);
 324                     $self->state($STATE_ALBUMS);
 325                 }
 326                 else
 327                 {
 328                     $self->state($STATE_INVALID);
 329                 }
 330             }
 331         }
 332         else
 333         {
 334             print "SM: ERROR: UNKNOWN STATE: $self->{state}\n";
 335             $self->state($STATE_INVALID);
 336         }
 337     }
 338
 339     # remove trailing boolean
 340     my @elements=@{$self->{elements}};
 341     while(@elements && $self->is("boolean", $elements[$#elements]))
 342     {
 343         pop @elements;
 344     }
 345     # sort elements by precedence
 346     @elements=$self->sort_elements(@elements);
 347     $self->{tagtree}=$self->elements_to_tree(\@elements);
 348     if($self->{tagtree})
 349     {
 350 #       my ($conditions, @joins)=$self->{tagtree}->to_sql();
 351 #       print "CONDITIONS(", scalar(@joins), "): ", $conditions, "\n";
 352     }
 353 }
 354
 355 sub state
 356 {
 357     my($self, $newstate)=@_;
 358     if(defined($newstate))
 359     {
 360         $self->{state}=$newstate;
 361         $self->{curtagdepth}++ if($newstate == $STATE_TAG);
 362     }
 363     return $self->{state};
 364 }
 365
 366 sub elements_to_tree
 367 {
 368     my($self, $elements)=@_;
 369     return undef unless(@$elements);
 370     my ($left, $right, $op)=(undef, undef, undef);
 371     my $thing=pop @$elements;
 372     if($self->is("boolean", $thing))
 373     {
 374         $right=$self->elements_to_tree($elements);
 375         if($thing->{name} ne "NOT")
 376         {
 377             $left=$self->elements_to_tree($elements);
 378         }
 379         $thing->left($left);
 380         $thing->right($right);
 381     }
 382     return $thing;
 383 }
 384
 385 # Dijkstra's shunting-yard algorithm
 386 sub sort_elements
 387 {
 388     my ($self, @input)=@_;
 389     my @opstack=();
 390     my @output=();
 391 #    print "INPUT: ", join(', ', map { $_->{name}; } @input), "\n";
 392     while(my $thing = shift @input)
 393     {
 394         if($self->is("tag", $thing))
 395         {
 396             # Handle tag values by dropping parent
 397             if(@input && $self->is("tag", $input[0]))
 398             {
 399                 $thing=shift @input;
 400             }
 401             push(@output, $thing);
 402         }
 403         elsif($self->is("boolean", $thing))
 404         {
 405             # bool
 406             while(@opstack &&
 407                   ($priorities{$thing->{name}} <= $priorities{$opstack[$#opstack]->{name}}))
 408             {
 409                 push(@output, pop(@opstack));
 410             }
 411             push(@opstack, $thing);
 412         }
 413     }
 414     while(@opstack)
 415     {
 416         push(@output, pop(@opstack));
 417     }
 418 #    print "STACK: ", join(', ', map { $_->{name}; } @output), "\n";
 419     return @output;
 420 }
 421
 422 sub used_tags
 423 {
 424     my($self)=@_;
 425     return() unless(defined($self->{tagtree}));
 426     return($self->{tagtree}->used_tags());
 427 }
 428
 429 sub expecting_values
 430 {
 431     my($self)=@_;
 432     my $tail=$self->tail();
 433     if($self->is("tag", $tail))
 434     {
 435         return($self->{db}->tag_has_values($tail->id()));
 436     }
 437 }
 438
 439 sub trailing_tag_id
 440 {
 441     my($self)=@_;
 442     my $tail=$self->tail();
 443     if($self->is("tag", $tail))
 444     {
 445         return($tail->id());
 446     }
 447     return undef;
 448 }
 449
 450 sub trailing_tag_parent
 451 {
 452     my($self)=@_;
 453     my $tail=$self->tail();
 454     if($self->is("tag", $tail))
 455     {
 456         return($tail->{parents_id});
 457     }
 458     return undef;
 459 }
 460
 461 sub tail
 462 {
 463     my($self)=@_;
 464     return($self->{elements}->[$#{$self->{elements}}]);
 465 }
 466
 467 sub at
 468 {
 469     my($self, $type)=@_;
 470     return($self->is($type, $self->tail()));
 471 }
 472
 473 sub is
 474 {
 475     my($self, $type, $thing)=@_;
 476     return 0 unless($thing);
 477     return 0 unless($thing->type());
 478     return 1 if($type eq $thing->type());
 479     return 0;
 480 }
 481
 482 # the one before last
 483 sub tail_parent
 484 {
 485     my($self)=@_;
 486     return($self->{elements}->[($#{$self->{elements}}) - 1]);
 487 }
 488
 489 ######################################################################
 490
 491 sub tags
 492 {
 493     my($self)=@_;
 494     if(!$self->{tagtree}) # / or /NOT
 495     {
 496         my $sql="SELECT DISTINCT name FROM tags WHERE parents_id='';";
 497         return($self->{db}->cmd_firstcol($sql));
 498     }
 499     my $hasvals=$self->expecting_values();
 500     my $parent=$self->trailing_tag_parent();
 501 #    print "THASVALS: $hasvals\n";
 502 #    print "TPARENT: ", (defined($parent)? $parent : "NO"), "\n";
 503     my @ids=();
 504     my $sql="SELECT tags.name FROM ";
 505     if($self->in_or())
 506     {
 507         $sql .= "files_x_tags\n";
 508     }
 509     else
 510     {
 511         $sql .= ("(\n" .
 512                  $self->tags_subselect() .
 513                  ") AS subselect\n" .
 514                  "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n");
 515     }
 516     $sql .= "INNER JOIN tags ON files_x_tags.tags_id=tags.id\n";
 517     my @andclauses=();
 518     my $id=$self->trailing_tag_id();
 519
 520     my $parentclause= "tags.parents_id='";
 521     if($hasvals)
 522     {
 523         $parentclause .= $id;
 524     }
 525     elsif($parent)
 526     {
 527         $parentclause .= $parent;
 528     }
 529     $parentclause .= "'";
 530     push(@andclauses, $parentclause);
 531
 532     my @used=$self->used_tags();
 533     if(@used)
 534     {
 535         push(@andclauses, "tags.id NOT IN (" . join(', ', @used) . ")");
 536     }
 537     if(@andclauses)
 538     {
 539         $sql .= "WHERE " . join(' AND ', @andclauses) . "\n";
 540     }
 541
 542     $sql .= "GROUP BY tags.name;";
 543     print "SQL(TAGS): $sql\n" if($self->{verbose});
 544     my @tagnames=$self->{db}->cmd_firstcol($sql);
 545     print("SUBNAMES: ", join(', ', @tagnames), "\n") if($self->{verbose});
 546     return(@tagnames);
 547 }
 548
 549 sub artists
 550 {
 551     my($self)=@_;
 552     if(!@{$self->{elements}}) # /ALL
 553     {
 554         my $sql="SELECT DISTINCT name FROM artists WHERE name!='';";
 555         return($self->{db}->cmd_firstcol($sql));
 556     }
 557     my @ids=();
 558     my $sql=$self->sql_start("artists.name");
 559     $sql .= ("INNER JOIN artists ON files.artists_id=artists.id\n" .
 560              "WHERE artists.name != ''\n" .
 561              "GROUP BY artists.name;");
 562     print "SQL(ARTISTS): $sql\n" if($self->{verbose});
 563     my @tagnames=$self->{db}->cmd_firstcol($sql);
 564     print("ARTISTS: ", join(', ', @tagnames), "\n") if($self->{verbose});
 565     return(@tagnames);
 566 }
 567
 568 sub albums
 569 {
 570     my($self)=@_;
 571     my @ids=();
 572     my $tail=$self->tail();
 573     if($self->is("artist", $tail))
 574     {
 575         return $self->artist_albums($tail->id());
 576     }
 577     my $sql=$self->sql_start("albums.name");
 578     $sql .= ("INNER JOIN albums ON files.albums_id=albums.id\n" .
 579              "WHERE albums.name != ''\n" .
 580              "GROUP BY albums.name;");
 581     print "SQL(ALBUMS): \n$sql\n" if($self->{verbose});
 582     my @names=$self->{db}->cmd_firstcol($sql);
 583     print("ALBUMS: ", join(', ', @names), "\n") if($self->{verbose});
 584     return(@names);
 585 }
 586
 587 sub artist_albums
 588 {
 589     my($self, $artist_id)=@_;
 590     my $sql=$self->sql_start("albums.name");
 591     $sql .= ("INNER JOIN albums ON albums.id=files.albums_id\n" .
 592              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 593              "WHERE artists.id=? and albums.name <> ''\n" .
 594              "GROUP BY albums.name\n");
 595     print "ARTIST_ALBUMS SQL: $sql\n" if($self->{verbose});
 596     my @albums=$self->{db}->cmd_firstcol($sql, $artist_id);
 597     print("ALBUMS: ", join(', ', @albums), "\n") if($self->{verbose});
 598     return(@albums);
 599 }
 600
 601 sub artist_tracks
 602 {
 603     my($self, $artist_id)=@_;
 604     my $sql=$self->sql_start("files.name");
 605     $sql .= ("INNER JOIN artists ON artists.id=files.artists_id\n" .
 606              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 607              "WHERE artists.id=? AND albums.name=''\n" .
 608              "GROUP BY files.name\n");
 609     print "ARTIST_TRACKS SQL: $sql\n" if($self->{verbose});
 610     my @names=$self->{db}->cmd_firstcol($sql, $artist_id);
 611     print("ARTISTTRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 612     return(@names);
 613 }
 614
 615 sub album_tracks
 616 {
 617     my($self, $artist_id, $album_id)=@_;
 618     my $sql=("SELECT files.name FROM files\n" .
 619              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 620              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 621              "WHERE artists.id=? AND albums.id=?\n" .
 622              "GROUP BY files.name\n");
 623     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n" if($self->{verbose});
 624     my @names=$self->{db}->cmd_firstcol($sql, $artist_id, $album_id);
 625     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 626     return(@names);
 627 }
 628
 629 sub tracks
 630 {
 631     my($self)=@_;
 632     my $tail=$self->tail();
 633     if($self->is("artist", $tail))
 634     {
 635         return $self->artist_tracks($tail->id());
 636     }
 637     elsif($self->is("album", $tail))
 638     {
 639         my $artist_id=0;
 640         my $artist=$self->tail_parent();
 641         if($self->is("artist", $artist))
 642         {
 643             # should always happen
 644             $artist_id=$artist->id();
 645         }
 646         return $self->album_tracks($artist_id, $tail->id());
 647     }
 648     my $sql=$self->sql_start("files.name");
 649     $sql .= "INNER JOIN artists ON files.artists_id=artists.id\n";
 650     if($self->{components}->[$#{$self->{components}}] eq $PATH_NOARTIST)
 651     {
 652         $sql .= "WHERE artists.name =''\n";
 653     }
 654     $sql .= "GROUP BY files.name;";
 655     print "TRACKS SQL($self->{path}): $sql\n" if($self->{verbose});
 656     my @names=$self->{db}->cmd_firstcol($sql);
 657     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 658     return(@names);
 659 }
 660
 661 sub filename
 662 {
 663     my($self, $mountpoint)=@_;
 664     my $tail=$self->tail();
 665     if($self->is("file", $tail))
 666     {
 667         my $id=$tail->id();
 668         my $sql=("SELECT paths.name, files.name FROM files\n" .
 669                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 670                  "WHERE files.id=?\n" .
 671                  "GROUP BY paths.name, files.name");
 672         print "FILENAME SQL: $sql\n" if($self->{verbose});
 673         my ($path, $name)=$self->{db}->cmd_onerow($sql, $id);
 674         my $id3fs_path=join('/', map { $_->{name}; }  @{$self->{elements}});
 675         return($self->{db}->relativise($path, $name, $mountpoint));
 676     }
 677     # should never happen
 678     return "ERROR";
 679 }
 680
 681 sub tags_subselect
 682 {
 683     my($self)=@_;
 684     my $hasvals=$self->expecting_values();
 685     if($self->{in_all})
 686     {
 687         # FIXME: is this used?
 688         die "IN_ALL CALLED!!\n";
 689         return "\tSELECT id FROM files AS files_id\n";
 690     }
 691     my $tree=$self->{tagtree};
 692     # FIXME
 693     print "UNDEF!!\n" unless($self->{tagtree});
 694     my $parent=$self->trailing_tag_parent();
 695
 696 #    print "ELEMENTS: ", join('/', map { $_->{name}; } @{$self->{elements}}), "\n";
 697 #    print "TREE: ", $tree->print(), "\n";
 698     my $tag=undef;
 699     if($hasvals)
 700     {
 701         $tag=$self->trailing_tag_id();
 702 #       print "Trailing id: $tag\n";
 703     }
 704     my ($sqlclause, @joins)=(undef, ());
 705     ($sqlclause, @joins) = $tree->to_sql($hasvals) if($tree);
 706 #    print "SQL(" . scalar(@joins) ."): $sqlclause\n";
 707     my $sql="\tSELECT fxt1.files_id FROM tags t1";
 708     my @crosses=();
 709     my @inners=();
 710 #    $joinsneeded++ if($tag);
 711     for(my $i=0; $i <= $#joins; $i++)
 712     {
 713         my $cnt=$i+1;
 714         my $join=$joins[$i];
 715         my $inner=("\t$join JOIN files_x_tags fxt$cnt ON " .
 716                    "t${cnt}.id=fxt${cnt}.tags_id");
 717         if($i > 0)
 718         {
 719             push(@crosses, "CROSS JOIN tags t$cnt");
 720             $inner .= " AND fxt1.files_id=fxt${cnt}.files_id";
 721         }
 722         push(@inners, $inner);
 723     }
 724     $sql .= ("\n\t" . join(" ", @crosses)) if(@crosses);
 725     $sql .= ("\n" . join("\n", @inners)) if(@inners);
 726     $sql .= "\n\tWHERE $sqlclause" if($sqlclause);
 727 #    if($tag)
 728 #    {
 729 #       $sql .= " AND t${joinsneeded}.parents_id='$tag'";
 730 #    }
 731     $sql .= "\n\tGROUP BY fxt1.files_id\n";
 732     return $sql;
 733 }
 734
 735 sub sql_start
 736 {
 737     my($self, $tables)=@_;
 738     my $sql="SELECT $tables FROM ";
 739     if($self->{in_all})
 740     {
 741         $sql .= "files\n";
 742     }
 743     else
 744     {
 745         $sql .= ("(\n" .
 746                  $self->tags_subselect() .
 747                  ") AS subselect\n" .
 748                  "INNER JOIN files ON subselect.files_id=files.id\n");
 749     }
 750     return $sql;
 751 }
 752
 753 # FIXME: remove
 754 sub constraints_tag_list
 755 {
 756     my($self, @constraints)=@_;
 757     my $lasttag=undef;
 758     my @tags=();
 759     my @tags_vals=();
 760     for my $constraint (@constraints)
 761     {
 762 #       print ref($constraint), ": ", $constraint->{name}, "\n";
 763         if($self->is("tag", $constraint))
 764         {
 765             if(defined($lasttag))
 766             {
 767 #               print "TAGVAL\n";
 768                 push(@tags_vals, [$lasttag, $constraint->id()]) if defined($constraint->id());
 769                 $lasttag=undef;
 770             }
 771             elsif($self->tag_has_values($constraint->id()))
 772             {
 773 #               print "HASVALUES\n";
 774                 $lasttag=$constraint->id() if defined($constraint->id());
 775             }
 776             else
 777             {
 778 #               print "NOVALUES\n";
 779                 push(@tags, $constraint->id()) if(defined($constraint->id()));
 780             }
 781         }
 782     }
 783     @tags=map{ "\"$_\""; } @tags;
 784     @tags_vals=map( { [ map({ "\"$_\""; } @$_ ) ] } @tags_vals);
 785     $lasttag="\"$lasttag\"" if defined($lasttag);
 786     return(\@tags, \@tags_vals, $lasttag);
 787 }
 788
 789 # we just filter $ALLTRACKS, $NOARTIST and $NOALBUM
 790 # filtering tags properly requires up to four levels of recursion
 791 # (tag/tagval/AND/NOT) and is too slow
 792 sub filter
 793 {
 794     my($self, @dirs)=@_;
 795     return(@dirs) unless($ENABLE_FILTER);
 796     my $base=$self->{path};
 797     my @outdirs=();
 798     for my $dir (@dirs)
 799     {
 800 #       print "\nFILTER (",$self->state(), "): $base / $dir\n";
 801         if($self->empty("$base/$dir"))
 802         {
 803 #           print "empty: $base / $dir\n";
 804         }
 805         else
 806         {
 807 #           print "non-empty, accepting: $base / $dir\n";
 808             push(@outdirs, $dir);
 809         }
 810     }
 811     return(@outdirs);
 812 }
 813
 814 sub empty
 815 {
 816     my($self, $dir)=@_;
 817     my $path=ID3FS::Path->new($self->{db}, $dir, $self->{verbose},
 818                               ($self->{maxtagdepth} - $self->{curtagdepth}));
 819     return 1 unless($path->isvalid());
 820     my($subdirs,$subfiles)=$path->dirents();
 821     return 0 if(@$subfiles || @$subdirs);
 822     return 1;
 823 }
 824
 825 # if path is .../OR/ or .../OR/NOT
 826 sub in_or
 827 {
 828     my($self)=@_;
 829     my $tail=$self->tail();
 830     return 0 unless($tail);
 831     return 0 unless($tail->type() eq "boolean");
 832     return 1 if($tail->name() eq "OR");
 833     return 0 unless($tail->name() eq "NOT");
 834     my $parent=$self->tail_parent();
 835     return 0 unless($parent);
 836     return 0 unless($parent->type() eq "boolean");
 837     return 1 if($parent->name() eq "OR");
 838     return 0;
 839 }
 840
 841 1;