lib/ID3FS/AudioFile.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::AudioFile;
  18
  19 use strict;
  20 use warnings;
  21 use ID3FS::AudioFile::Mp3;
  22 use ID3FS::AudioFile::Ogg;
  23 use ID3FS::AudioFile::Flac;
  24
  25 sub new
  26 {
  27     my $proto=shift;
  28     my $class=ref($proto) || $proto;
  29     my $self={};
  30     bless($self,$class);
  31
  32     $self->{path}=shift;
  33     my $ext=($self->{path}=~/.*\.(.*)/)[0];
  34     return undef unless($ext);
  35     my $me=shift;
  36     $ext=lc($ext);
  37     if($ext eq "mp3")
  38     {
  39         $self->{audiofile}=ID3FS::AudioFile::Mp3->new($self->{path});
  40     }
  41     elsif($ext eq "ogg")
  42     {
  43         $self->{audiofile}=ID3FS::AudioFile::Ogg->new($self->{path});
  44     }
  45     elsif($ext eq "flac")
  46     {
  47         $self->{audiofile}=ID3FS::AudioFile::Flac->new($self->{path});
  48     }
  49     else
  50     {
  51         print("$me: $self->{path}: Unknown extension: $ext\n");
  52         return undef;
  53     }
  54     return $self;
  55 }
  56
  57 sub set
  58 {
  59     my ($self, $thing, $value)=@_;
  60     if($value)
  61     {
  62         $value=$self->sanitise($self->stripslashes($value));
  63         $self->{audiofile}->$thing($value);
  64     }
  65     else
  66     {
  67         $value=$self->sanitise($self->stripslashes($self->{audiofile}->$thing()));
  68     }
  69     return $value;
  70 }
  71
  72 sub artist    { return(shift->set("artist", @_));   }
  73 sub album     { return(shift->set("album", @_));    }
  74 sub track     { return(shift->set("track", @_));    }
  75 sub tracknum  { return(shift->set("tracknum", @_)); }
  76 sub v1genre   { return(shift->set("v1genre", @_));  }
  77 sub comment   { return(shift->set("comment", @_));  }
  78 sub audiotype { return(shift->set("audiotype"));    }
  79 sub haspic    { return(shift->set("haspic"));       }
  80 sub path      { return(shift->{path});              }
  81
  82 sub delete_artist   { shift->{audiofile}->delete_artist();   }
  83 sub delete_album    { shift->{audiofile}->delete_album();    }
  84 sub delete_track    { shift->{audiofile}->delete_track();    }
  85 sub delete_tracknum { shift->{audiofile}->delete_tracknum(); }
  86 sub delete_year     { shift->{audiofile}->delete_year();     }
  87 sub delete_v1genre  { shift->{audiofile}->delete_v1genre();  }
  88 sub delete_comment  { shift->{audiofile}->delete_comment();  }
  89 sub delete_all      { shift->{audiofile}->delete_all();      }
  90 sub delete_genre    { shift->{audiofile}->delete_genre();    }
  91 sub delete_tags     { shift->{audiofile}->delete_tags();     }
  92
  93 sub year
  94 {
  95     my ($self, $year)=@_;
  96     if($year)
  97     {
  98         $year=$self->format_year($year);
  99         $self->{audiofile}->year($year);
 100     }
 101     else
 102     {
 103         $year=$self->{audiofile}->year();
 104     }
 105     return $year;
 106 }
 107
 108 sub format_year
 109 {
 110     my ($self, $year)=@_;
 111     if($year)
 112     {
 113         $year=$self->sanitise($self->stripslashes($year));
 114         if(defined($year) && $year =~/(\d{4})/)
 115         {
 116             $year=$1;
 117         }
 118     }
 119     return $year;
 120 }
 121
 122 sub add_tags
 123 {
 124     my($self, $tags)=@_;
 125     die("FIXME: implement add_tags()\n");
 126 }
 127
 128 sub tags
 129 {
 130     my $self=shift;
 131     my @intags=$self->{audiofile}->tags();
 132     my @outtags=();
 133     return() unless(@intags);
 134     @intags = grep { defined($_); } @intags;
 135     # combine then split on commas
 136     # so multiple comma-delimited tags will work
 137     @intags=split(/\s*,\s*/, join(', ', @intags));
 138     for my $tag (@intags)
 139     {
 140         next unless(length($tag));
 141         next unless($tag =~ /\S+/);
 142         $tag=$self->sanitise($tag);
 143         my ($tagname, $tagval)=($tag, undef);
 144         if($tag=~/^([^\/]+)\/(.*)/)
 145         {
 146             ($tagname, $tagval)=($1, $2);
 147         }
 148         push(@outtags, [ $tagname, $tagval ]);
 149     }
 150     return @outtags;
 151 }
 152
 153 sub write
 154 {
 155     shift->{audiofile}->write();
 156 }
 157
 158 sub sanitise
 159 {
 160     my ($self, $text)=@_;
 161     $text =~ s/[^[:print:]]//g if(defined($text));
 162     return $text;
 163 }
 164
 165 sub stripslashes
 166 {
 167     my ($self, $text)=@_;
 168     $text =~ s/\//-/g if(defined($text));
 169     return $text;
 170 }
 171
 172 1;