lib/ID3FS/DB.pm

   1 package ID3FS::DB;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use ID3FS::AudioFile;
   7 use Cwd;
   8
   9 our $SCHEMA_VERSION=1;
  10 my $dbfile=".id3fs";
  11
  12 sub new
  13 {
  14     my $proto=shift;
  15     my $class=ref($proto) || $proto;
  16     my $self={};
  17     bless($self,$class);
  18
  19     $self->{me}=shift;
  20     $self->{verbose}=shift;
  21     my $init=shift;
  22     my $dbpath=shift;
  23     $self->{base}=shift;
  24     my $fallbackdir=shift;
  25
  26     $self->{dbpath}=$self->find_db($init, $dbpath, $fallbackdir);
  27     return undef unless($self->{dbpath});
  28     $self->{absbase}=Cwd::abs_path($self->{base});
  29
  30     my $connectstr="dbi:SQLite:dbname=$self->{dbpath}";
  31     my $exists=-f $self->{dbpath};
  32     $self->{dbh}=DBI->connect($connectstr, undef, undef,
  33                               { AutoCommit=>1 } );
  34     unless(defined($self->{dbh}))
  35     {
  36         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  37     }
  38
  39     if($exists)
  40     {
  41         $self->checkschema();
  42     }
  43     else
  44     {
  45         $self->create();
  46     }
  47     $self->enable_foreign_keys();
  48     return $self;
  49 }
  50
  51 sub find_db
  52 {
  53     my($self, $init, $dbpath, $fallbackdir)=@_;
  54     my $file=undef;
  55     my $base=undef;
  56     if(defined($dbpath))
  57     {
  58         $file=$dbpath;
  59     }
  60     if(defined ($self->{base}))
  61     {
  62         $file="$self->{base}/$dbfile" unless defined($file);
  63         $base=$self->{base};
  64     }
  65     elsif(defined($fallbackdir) && -d $fallbackdir)
  66     {
  67         my $path=Cwd::abs_path($fallbackdir);
  68         do
  69         {
  70             $file="$path/$dbfile";
  71             $base=$path;
  72             $path=~s/(.*)\/.*/$1/;
  73         }
  74         while(! -f $file && length($path) && -d $path);
  75         if(! -f $file)
  76         {
  77             $file="$fallbackdir/$dbfile";
  78             $base=$fallbackdir;
  79         }
  80     }
  81     else
  82     {
  83         print "$self->{me}: $fallbackdir: not a directory\n";
  84         return undef;
  85     }
  86     if(!-f $file && !$init)
  87     {
  88         print "$self->{me}: db not found at $file\n";
  89         return undef;
  90     }
  91     $self->{base}=$base;
  92     return $file;
  93 }
  94
  95 sub base_dir { return shift->{base}; }
  96
  97 sub create
  98 {
  99     my($self,$name)=@_;
 100     my @schema=split(/\n\n/,join("", <DATA>));
 101     close(DATA);
 102     for my $cmd (@schema)
 103     {
 104         $self->{dbh}->do($cmd);
 105     }
 106     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 107                $SCHEMA_VERSION, time());
 108 }
 109
 110 sub checkschema
 111 {
 112     my $self=shift;
 113     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 114     if(!defined($version) || $version != $SCHEMA_VERSION)
 115     {
 116         die("$self->{me}: id3fs database version " .
 117             defined($version) ? $version : '""' .
 118             "not known, current version is $SCHEMA_VERSION.\n");
 119     }
 120 }
 121
 122 sub analyze
 123 {
 124     my $self=shift;
 125     $self->cmd("ANALYZE");
 126 }
 127
 128 sub enable_foreign_keys
 129 {
 130     my $self=shift;
 131     $self->cmd("PRAGMA foreign_keys = ON");
 132 }
 133
 134 sub last_update
 135 {
 136     my($self, $newval)=@_;
 137     if(defined($newval))
 138     {
 139         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 140     }
 141     else
 142     {
 143         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 144     }
 145     return $newval;
 146 }
 147
 148 sub bare_tags
 149 {
 150     my($self)=@_;
 151     my $sql=("SELECT tags.name FROM tags\n" .
 152              "WHERE tags.parents_id=''\n" .
 153              "GROUP BY tags.name\n");
 154     my @names=$self->cmd_firstcol($sql);
 155     return (@names);
 156 }
 157
 158 sub tags_with_values
 159 {
 160     # FIXME: only shows one level of tag depth
 161     my($self)=@_;
 162     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 163              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 164              "GROUP BY p.name, t.name\n");
 165 #    print "SQL: $sql\n";
 166     my $result=$self->cmd_rows($sql);
 167     my $tags={};
 168     for my $pair (@$result)
 169     {
 170         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 171     }
 172     return $tags;
 173 }
 174
 175 sub tag_has_values
 176 {
 177     my($self, $id)=@_;
 178     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 179              "WHERE tags.parents_id=?\n");
 180     my ($rows)=$self->cmd_onerow($sql, $id);
 181     return $rows;
 182 }
 183
 184 sub relativise
 185 {
 186     my($self, $path, $name, $mountpoint)=@_;
 187     my $id3fs_path=$self->{dbpath};
 188     $id3fs_path=~s/(.*)\/.*/$1/;
 189     my $rpath="$self->{absbase}/$path";
 190     my $vpath="$mountpoint/$id3fs_path";
 191     my @path=split(/\//,$rpath);
 192     my @rel=split(/\//,$vpath);
 193     #absolute paths have empty first element due to leading /
 194     shift(@path) if($path[0] eq "");
 195     shift(@rel)  if($rel[0]  eq "");
 196     if($path[0] ne $rel[0])
 197     {
 198         #no path in common, return absolute
 199         print "FAIL: NO PATHS IN COMMON\n";
 200         return $name;
 201     }
 202     # f: /home/foo/bar/baz.mp3
 203     # r: /home/ianb/music/albums
 204     while(@path && @rel && ($path[0] eq $rel[0]))
 205     {
 206         shift(@path);
 207         shift(@rel);
 208 #       print "POP ";
 209     }
 210 #    print "\n";
 211     my $upcount=scalar(@rel);
 212     my $result="../" x $upcount;
 213     $result .= join("/",@path);
 214     $result .= "/$name";
 215     return $result;
 216 }
 217
 218 sub add
 219 {
 220     my($self,$path)=@_;
 221     my $relpath=Cwd::abs_path($path);
 222     $relpath =~ s/^\Q$self->{absbase}\E\/?//;
 223     my($filepart,$pathpart);
 224     if($relpath !~ /\//)
 225     {
 226         $pathpart='';
 227         $filepart=$relpath;
 228     }
 229     else
 230     {
 231         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 232     }
 233     my $file=ID3FS::AudioFile->new($path, $self->{me});
 234     return unless(defined($file));
 235     my $artist=$file->artist();
 236     my $album=$file->album();
 237     my $v1genre=$file->v1genre();
 238     my $year=$file->year();
 239     my $audiotype=$file->audiotype();
 240     my @tags=$file->tags();
 241     my $haspic=$file->haspic();
 242
 243     $artist=undef unless($self->ok($artist));
 244     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 245     my $artist_id=$self->add_to_table("artists",  $artist);
 246     my $path_id=$self->add_to_table("paths", $pathpart);
 247     $album=undef unless($self->ok($album));
 248     if($self->{verbose} && !defined($album))
 249     {
 250         print "$self->{me}: $path: no album tag defined\n";
 251     }
 252
 253     my $albums_id=$self->add_to_table("albums", $album);
 254     my $file_id=$self->add_to_table("files", $filepart,
 255                                     { "artists_id" => $artist_id,
 256                                       "albums_id"  => $albums_id,
 257                                       "paths_id"   => $path_id });
 258     for my $tag (@tags)
 259     {
 260         $self->add_tag($file_id, @$tag);
 261     }
 262
 263     $year="UNKNOWN" unless($self->ok($year));
 264     $self->add_tag($file_id, "year", $year);
 265     if($year=~/^(\d\d\d)\d$/)
 266     {
 267         $self->add_tag($file_id, "decade", "${1}0s");
 268     }
 269     else
 270     {
 271         $self->add_tag($file_id, "decade", "UNKNOWN");
 272     }
 273
 274     if($self->ok($v1genre))
 275     {
 276         $self->add_tag($file_id, "v1genre", $v1genre);
 277     }
 278
 279     if($haspic)
 280     {
 281         $self->add_tag($file_id, "haspic", undef);
 282     }
 283 }
 284
 285 sub add_tag
 286 {
 287     my($self, $file_id, $tag, $value)=@_;
 288     my $tag_id=$self->add_to_table("tags",  $tag,
 289                                    { "parents_id" => undef });
 290     $self->add_relation("files_x_tags",
 291                         { "files_id" => $file_id,
 292                           "tags_id"  => $tag_id });
 293     if(defined($value) && length($value))
 294     {
 295         my $val_id=$self->add_to_table("tags",  $value,
 296                                        { "parents_id" => $tag_id });
 297         $self->add_relation("files_x_tags",
 298                             { "files_id" => $file_id,
 299                               "tags_id"  => $val_id });
 300     }
 301 }
 302
 303 sub add_to_table
 304 {
 305     my($self, $table, $name, $extradata)=@_;
 306     my $parent=undef;
 307     if($extradata && $extradata->{parents_id})
 308     {
 309         $parent=$extradata->{parents_id};
 310     }
 311     my $id=$self->lookup_id($table, $name, $parent);
 312     unless(defined($id))
 313     {
 314         my $sql="INSERT INTO $table (";
 315         my @fields=qw(name);
 316         if(defined($extradata))
 317         {
 318             push(@fields, sort keys(%$extradata));
 319         }
 320         $sql .= join(", ", @fields);
 321         $sql .=") VALUES (";
 322         $sql .= join(", ", map { "?"; } @fields);
 323         $sql .= ");";
 324         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 325     }
 326     return $id;
 327 }
 328
 329 sub add_relation
 330 {
 331     my ($self, $relname, $fields)=@_;
 332     return if($self->relation_exists($relname, $fields));
 333     my $sql="INSERT INTO $relname (";
 334     $sql .= join(", ", sort keys(%$fields));
 335     $sql .= ") VALUES (";
 336     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 337     $sql .= ");";
 338     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 339 }
 340
 341 sub files_in
 342 {
 343     my ($self, $dir)=@_;
 344     my $sql=("SELECT files.name FROM files\n" .
 345              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 346              "WHERE paths.name=?\n");
 347 #    print "files_in: SQL: $sql\n";
 348     return($self->cmd_firstcol($sql, $dir));
 349 }
 350
 351 sub unindex
 352 {
 353     my($self, $path, $file)=@_;
 354     my $sql=("DELETE FROM files WHERE id IN (" .
 355              "\tSELECT files.id FROM files\n" .
 356              "\tINNER JOIN paths ON paths.id=files.paths_id\n" .
 357              "\tWHERE paths.name=? and files.name=? )\n");
 358     $self->cmd_rows($sql, $path, $file);
 359 }
 360
 361
 362 sub prune_directories
 363 {
 364     my($self)=@_;
 365     my $sql=("SELECT name, id FROM paths\n");
 366     my $pathsref=$self->cmd_rows($sql);
 367     my @ids=();
 368     for my $pathpair (@$pathsref)
 369     {
 370         my($path, $id)=@$pathpair;
 371         my $fullpath="$self->{absbase}/$path";
 372         unless(-d $fullpath)
 373         {
 374             push(@ids, $id)
 375         }
 376     }
 377     $self->prune_paths(@ids);
 378     return scalar(@ids);
 379 }
 380
 381 sub prune_paths
 382 {
 383     my($self, @ids)=@_;
 384     return unless(@ids);
 385     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 386              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 387 #    print "SQL: \n", $sql, "\n";
 388     $self->cmd($sql);
 389 }
 390
 391 sub remove_unused
 392 {
 393     my($self)=@_;
 394     my $sql=<<'EOT';
 395    DELETE FROM artists WHERE id IN (
 396        SELECT artists.id FROM artists
 397        LEFT JOIN files ON files.artists_id=artists.id
 398        WHERE files.id IS NULL);
 399
 400    DELETE FROM albums WHERE id IN (
 401        SELECT albums.id FROM albums
 402        LEFT JOIN files ON files.albums_id=albums.id
 403        WHERE files.id IS NULL);
 404
 405    DELETE FROM paths WHERE id IN (
 406        SELECT paths.id FROM paths
 407        LEFT JOIN files ON files.paths_id=paths.id
 408        WHERE files.id IS NULL);
 409
 410    DELETE FROM files_x_tags WHERE files_id IN (
 411        SELECT files_x_tags.files_id FROM files_x_tags
 412        LEFT JOIN files ON files.id=files_x_tags.files_id
 413        WHERE files.id IS NULL);
 414
 415    DELETE FROM tags WHERE id IN (
 416        SELECT tags.id FROM tags
 417        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 418        WHERE files_x_tags.files_id IS NULL);
 419
 420     VACUUM
 421 EOT
 422 #    print "SQL: $sql\n";
 423     my @sql=split(/\n\n/, $sql);
 424     $self->cmd($_) for (@sql);
 425 }
 426
 427 sub relation_exists
 428 {
 429     my ($self, $relname, $fields)=@_;
 430     my $sql="SELECT count(1) FROM $relname WHERE ";
 431     my @exprs=();
 432     my @vals=();
 433     for my $field (keys %$fields)
 434     {
 435         push(@exprs,$field);
 436         push(@vals,$fields->{$field});
 437     }
 438     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 439     my ($ret)=$self->cmd_onerow($sql, @vals);
 440     return $ret;
 441 }
 442
 443 sub ok
 444 {
 445     my($self, $thing)=@_;
 446     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 447 }
 448
 449 sub cmd_sth
 450 {
 451     my($self, $sql, @params)=@_;
 452     my $sth=$self->{dbh}->prepare($sql);
 453     my $idx=1;
 454     for my $param (@params)
 455     {
 456         $param="" unless(defined($param));
 457         $sth->bind_param($idx++, $param);
 458     }
 459     $sth->execute();
 460     return $sth;
 461 }
 462
 463 sub cmd
 464 {
 465     my ($self, @args)=@_;
 466     # don't care about retcode
 467     $self->cmd_sth(@args);
 468 }
 469
 470 sub cmd_onerow
 471 {
 472     my ($self, @args)=@_;
 473     my $sth=$self->cmd_sth(@args);
 474     return($sth->fetchrow_array());
 475 }
 476
 477 sub cmd_rows
 478 {
 479     my ($self, @args)=@_;
 480     my $sth=$self->cmd_sth(@args);
 481     return $sth->fetchall_arrayref();
 482 }
 483
 484 sub cmd_firstcol
 485 {
 486     my ($self, @args)=@_;
 487     return(map { $_->[0] } @{$self->cmd_rows(@args)});
 488 }
 489
 490 sub cmd_id
 491 {
 492     my ($self, @args)=@_;
 493     $self->cmd_sth(@args);
 494     return($self->last_insert_id());
 495 }
 496
 497 sub last_insert_id
 498 {
 499     my $self=shift;
 500     return $self->{dbh}->last_insert_id("","","","");
 501 }
 502
 503 sub lookup_id
 504 {
 505     my($self, $table, $name, $parent)=@_;
 506     my $sql="SELECT id FROM $table where name=?";
 507     my @args=($name);
 508     if($parent)
 509     {
 510         $sql .= " AND parents_id=?";
 511         push(@args, $parent);
 512     }
 513     my($id)=$self->cmd_onerow($sql, @args);
 514     return $id;
 515 }
 516
 517 __DATA__
 518
 519 CREATE TABLE id3fs (
 520     schema_version INTEGER,
 521     last_update
 522 );
 523
 524 CREATE TABLE paths (
 525     id INTEGER,
 526     name text,
 527     PRIMARY KEY(id DESC)
 528 );
 529
 530 CREATE TABLE artists (
 531     id INTEGER,
 532     name text,
 533     PRIMARY KEY(id DESC)
 534 );
 535
 536 CREATE TABLE albums (
 537     id INTEGER,
 538     name text,
 539     PRIMARY KEY(id DESC)
 540 );
 541
 542 CREATE TABLE files (
 543     id INTEGER,
 544     name text,
 545     artists_id,
 546     albums_id,
 547     paths_id,
 548     PRIMARY KEY(id DESC),
 549     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 550     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 551     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 552 );
 553
 554 CREATE TABLE tags (
 555     id INTEGER,
 556     parents_id INTEGER,
 557     name text,
 558     PRIMARY KEY(id DESC)
 559 );
 560
 561 CREATE TABLE files_x_tags (
 562     files_id INTEGER,
 563     tags_id INTEGER,
 564     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 565     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 566 );
 567
 568 CREATE INDEX idx_fxt_both ON files_x_tags (files_id, tags_id)
 569
 570 CREATE INDEX idx_fxt_tags ON files_x_tags (tags_id)
 571
 572 CREATE INDEX idx_files_id_name ON files (id, name)
 573
 574 CREATE INDEX idx_files_name_id ON files (name, id)
 575
 576 CREATE INDEX idx_tags_id_parent_name ON tags (id, parents_id, name)
 577
 578 CREATE INDEX idx_tags_parent_id_name ON tags (parents_id, id, name)
 579
 580 CREATE INDEX idx_tags_name ON tags (name)