lib/ID3FS/DB.pm

   1 package ID3FS::DB;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use ID3FS::File;
   7
   8 our $SCHEMA_VERSION=1;
   9
  10 my $dbfile=".id3fs";
  11
  12 sub new
  13 {
  14     my $proto=shift;
  15     my $class=ref($proto) || $proto;
  16     my $self={};
  17     bless($self,$class);
  18
  19     my($dir, $init, $me)=@_;
  20     $self->{dbpath}="$dir/$dbfile";
  21     $self->{me}=$me;
  22
  23     my $exists=-f $self->{dbpath};
  24     die("$me: $self->{dbpath}: not found. use --init to create.\n") if(!$exists && !$init);
  25     die("$me: --init used but $self->{dbpath} exists.\n")           if($exists && $init);
  26
  27     $self->{dbh}=DBI->connect("dbi:SQLite:dbname=$self->{dbpath}","","",
  28                               { AutoCommit=>1 } );
  29     unless(defined($self->{dbh}))
  30     {
  31         die("$me: DB Error: " . $DBI::errstr . "\n");
  32     }
  33
  34     if($init)
  35     {
  36         $self->create();
  37     }
  38     else
  39     {
  40         $self->checkschema();
  41     }
  42
  43     return $self;
  44 }
  45
  46 sub create
  47 {
  48     my($self,$name)=@_;
  49     my @schema=split(/\n\n/,join("", <DATA>));
  50     close(DATA);
  51     for my $cmd (@schema)
  52     {
  53         $self->{dbh}->do($cmd);
  54     }
  55     $self->cmd("INSERT INTO id3fs (schema_version) VALUES (?)", $SCHEMA_VERSION);
  56 }
  57
  58 sub checkschema
  59 {
  60     my $self=shift;
  61     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
  62     if(!defined($version) || $version != $SCHEMA_VERSION)
  63     {
  64         die("$self->{me}: id3fs database version " .
  65             defined($version) ? $version : '""' .
  66             "not known, current version is $SCHEMA_VERSION.\n");
  67     }
  68 }
  69
  70 sub cmd_sth
  71 {
  72     my($self, $sql, @params)=@_;
  73     my $sth=$self->{dbh}->prepare($sql);
  74     my $idx=1;
  75     for my $param (@params)
  76     {
  77         $param="" unless(defined($param));
  78         $sth->bind_param($idx++, $param);
  79     }
  80     $sth->execute();
  81     return $sth;
  82 }
  83
  84 sub add
  85 {
  86     my($self,$path)=@_;
  87     my $file=ID3FS::File->new($path);
  88     return unless(defined($file));
  89     my $artist=$file->artist();
  90     my $album=$file->album();
  91     my $v1genre=$file->v1genre();
  92     my $year=$file->year();
  93     my $audiotype=$file->album();
  94     my $tags=$file->tags();
  95     my $haspic=$file->haspic();
  96
  97     my $file_id=$self->add_to_table("files", $path);
  98     my $artists_id=$self->add_to_table("artists",  $artist);
  99     my $albums_id=$self->add_to_table("albums",  $album);
 100     for my $tag (keys %$tags)
 101     {
 102         $self->add_tag($file_id, $tag, $tags->{$tag});
 103     }
 104
 105     if($self->ok($year))
 106     {
 107         $self->add_tag($file_id, "year", $year);
 108         if($year=~/^(\d\d\d)\d$/)
 109         {
 110             $self->add_tag($file_id, "decade", "${1}0s");
 111         }
 112     }
 113     if($self->ok($v1genre))
 114     {
 115         $self->add_tag($file_id, "v1genre", $v1genre);
 116     }
 117
 118     if($haspic)
 119     {
 120         $self->add_tag($file_id, "haspic", undef);
 121     }
 122
 123     $self->add_relation("files_x_artists",
 124                         { "files_id" => $file_id,
 125                           "artists_id" => $artists_id });
 126
 127     $self->add_relation("artists_x_albums",
 128                       { "artists_id" => $artists_id,
 129                         "albums_id" => $albums_id});
 130 }
 131
 132 sub add_tag
 133 {
 134     my($self, $file_id, $tag, $val)=@_;
 135     my $tag_id=$self->add_to_table("tags",  $tag);
 136     $self->add_relation("files_x_tags",
 137                         { "files_id" => $file_id,
 138                           "tags_id"  => $tag_id });
 139     if(defined($val))
 140     {
 141         my $val_id=$self->add_to_table("tagvals", $val);
 142         $self->add_relation("tags_x_tagvals",
 143                             { "tags_id"     => $tag_id,
 144                               "tagvals_id"  => $val_id });
 145     }
 146 }
 147
 148 sub add_to_table
 149 {
 150     my($self, $table, $name, $extradata)=@_;
 151     my $id=$self->lookup_id($table, $name);
 152     unless(defined($id))
 153     {
 154         my $sql="INSERT INTO $table (";
 155         my @fields=qw(name);
 156         if(defined($extradata))
 157         {
 158             push(@fields, sort keys(%$extradata));
 159         }
 160         $sql .= join(", ", @fields);
 161         $sql .=") VALUES (";
 162         $sql .= join(", ", map { "?"; } @fields);
 163         $sql .= ");";
 164         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 165     }
 166     return $id;
 167 }
 168
 169 sub add_relation
 170 {
 171     my ($self, $relname, $fields)=@_;
 172     return if($self->relation_exists($relname, $fields));
 173     my $sql="INSERT INTO $relname (";
 174     $sql .= join(", ", sort keys(%$fields));
 175     $sql .= ") VALUES (";
 176     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 177     $sql .= ");";
 178     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 179 }
 180
 181 sub lookup_id
 182 {
 183     my($self, $table, $name)=@_;
 184     my($id)=$self->cmd_onerow("SELECT id FROM $table where name=?", $name);
 185     return $id;
 186 }
 187
 188 sub relation_exists
 189 {
 190     my ($self, $relname, $fields)=@_;
 191     my $sql="SELECT count(1) FROM $relname WHERE ";
 192     my @exprs=();
 193     my @vals=();
 194     for my $field (keys %$fields)
 195     {
 196         push(@exprs,$field);
 197         push(@vals,$fields->{$field});
 198     }
 199     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 200     my ($ret)=$self->cmd_onerow($sql, @vals);
 201     return $ret;
 202 }
 203
 204 sub ok
 205 {
 206     my($self, $thing)=@_;
 207     return(defined($thing) && length($thing));
 208 }
 209
 210 sub cmd
 211 {
 212     my ($self, @args)=@_;
 213     # don't care about retcode
 214     $self->cmd_sth(@args);
 215 }
 216
 217 sub cmd_onerow
 218 {
 219     my ($self, @args)=@_;
 220     my $sth=$self->cmd_sth(@args);
 221     return($sth->fetchrow_array());
 222 }
 223
 224 sub cmd_id
 225 {
 226     my ($self, @args)=@_;
 227     $self->cmd_sth(@args);
 228     return($self->last_insert_id());
 229 }
 230
 231 sub last_insert_id
 232 {
 233     my $self=shift;
 234     return $self->{dbh}->last_insert_id("","","","");
 235 }
 236
 237 __DATA__
 238
 239 CREATE TABLE id3fs (
 240     schema_version
 241 );
 242
 243 CREATE TABLE files (
 244     id INTEGER PRIMARY KEY,
 245     name
 246 );
 247
 248 CREATE TABLE artists (
 249     id INTEGER PRIMARY KEY,
 250     name
 251 );
 252
 253 CREATE TABLE albums (
 254     id INTEGER PRIMARY KEY,
 255     name
 256 );
 257
 258 CREATE TABLE tags (
 259     id INTEGER PRIMARY KEY,
 260     name
 261 );
 262
 263 CREATE TABLE tagvals (
 264     id INTEGER PRIMARY KEY,
 265     name
 266 );
 267
 268 CREATE TABLE files_x_tags (
 269     files_id,
 270     tags_id
 271 );
 272
 273 CREATE TABLE tags_x_tagvals (
 274     tags_id,
 275     tagvals_id
 276 );
 277
 278 CREATE TABLE files_x_artists (
 279     files_id,
 280     artists_id
 281 );
 282
 283 CREATE TABLE artists_x_albums (
 284     artists_id,
 285     albums_id
 286 );