lib/ID3FS/DB.pm

   1 package ID3FS::DB;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use ID3FS::AudioFile;
   7 use Cwd;
   8
   9 our $SCHEMA_VERSION=1;
  10 my $dbfile=".id3fs";
  11
  12 sub new
  13 {
  14     my $proto=shift;
  15     my $class=ref($proto) || $proto;
  16     my $self={};
  17     bless($self,$class);
  18
  19     $self->{me}=shift;
  20     $self->{verbose}=shift;
  21     my $init=shift;
  22     my $dbpath=shift;
  23     $self->{base}=shift;
  24     my $fallbackdir=shift;
  25
  26     $dbpath=$self->find_db($init, $dbpath, $fallbackdir);
  27     return undef unless($dbpath);
  28     $self->{absbase}=Cwd::abs_path($self->{base});
  29
  30     my $connectstr="dbi:SQLite:dbname=$dbpath";
  31     my ($user, $pass)=("", "");
  32     if($self->{postgres})
  33     {
  34         $connectstr="dbi:Pg:dbname=id3fs";
  35         $user="ianb";
  36         $pass="foo";
  37     }
  38     my $exists=-f $dbpath;
  39     $self->{dbh}=DBI->connect($connectstr, $user, $pass,
  40                               { AutoCommit=>1 } );
  41     unless(defined($self->{dbh}))
  42     {
  43         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  44     }
  45
  46     if($exists)
  47     {
  48         $self->checkschema();
  49     }
  50     else
  51     {
  52         $self->create();
  53     }
  54     $self->enable_foreign_keys();
  55     return $self;
  56 }
  57
  58 sub find_db
  59 {
  60     my($self, $init, $dbpath, $fallbackdir)=@_;
  61     my $file=undef;
  62     my $base=undef;
  63     if(defined($dbpath))
  64     {
  65         $file=$dbpath;
  66     }
  67     if(defined ($self->{base}))
  68     {
  69         $file="$self->{base}/$dbfile" unless defined($file);
  70         $base=$self->{base};
  71     }
  72     elsif(defined($fallbackdir) && -d $fallbackdir)
  73     {
  74         my $path=Cwd::abs_path($fallbackdir);
  75         do
  76         {
  77             $file="$path/$dbfile";
  78             $base=$path;
  79             $path=~s/(.*)\/.*/$1/;
  80         }
  81         while(! -f $file && length($path) && -d $path);
  82         if(! -f $file)
  83         {
  84             $file="$fallbackdir/$dbfile";
  85             $base=$fallbackdir;
  86         }
  87     }
  88     if(!-f $file && !$init)
  89     {
  90         print "$self->{me}: db not found at $file\n";
  91         return undef;
  92     }
  93     $self->{base}=$base;
  94     return $file;
  95 }
  96
  97 sub base_dir { return shift->{base}; }
  98
  99 sub create
 100 {
 101     my($self,$name)=@_;
 102     my @schema=split(/\n\n/,join("", <DATA>));
 103     close(DATA);
 104     for my $cmd (@schema)
 105     {
 106         $self->{dbh}->do($cmd);
 107     }
 108     if($self->{postgres})
 109     {
 110         $self->cmd("CREATE SEQUENCE seq");
 111     }
 112     else
 113     {
 114         my %indexes=( "idx_files_id"  => "files (id)",
 115                       "idx_fxt_both"  => "files_x_tags (files_id, tags_id)",
 116                       "idx_fxt_files" => "files_x_tags (files_id)",
 117                       "idx_fxt_tags"  => "files_x_tags (tags_id)",
 118                       "idx_tags_id"   => "tags (id)",
 119                       "idx_tags_name" => "tags (name)");
 120         for my $index (keys %indexes)
 121         {
 122             $self->{dbh}->do("CREATE INDEX $index ON " . $indexes{$index});
 123         }
 124     }
 125     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 126                $SCHEMA_VERSION, time());
 127 }
 128
 129 sub checkschema
 130 {
 131     my $self=shift;
 132     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 133     if(!defined($version) || $version != $SCHEMA_VERSION)
 134     {
 135         die("$self->{me}: id3fs database version " .
 136             defined($version) ? $version : '""' .
 137             "not known, current version is $SCHEMA_VERSION.\n");
 138     }
 139 }
 140
 141 sub analyze
 142 {
 143     my $self=shift;
 144     $self->cmd("ANALYZE");
 145 }
 146
 147 sub enable_foreign_keys
 148 {
 149     my $self=shift;
 150     $self->cmd("PRAGMA foreign_keys = ON");
 151 }
 152
 153 sub last_update
 154 {
 155     my($self, $newval)=@_;
 156     if(defined($newval))
 157     {
 158         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 159     }
 160     else
 161     {
 162         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 163     }
 164     return $newval;
 165 }
 166
 167 sub cmd_sth
 168 {
 169     my($self, $sql, @params)=@_;
 170     my $sth=$self->{dbh}->prepare($sql);
 171     my $idx=1;
 172     for my $param (@params)
 173     {
 174         $param="" unless(defined($param));
 175         $sth->bind_param($idx++, $param);
 176     }
 177     $sth->execute();
 178     return $sth;
 179 }
 180
 181 sub tags
 182 {
 183     my($self, @constraints)=@_;
 184     if(!@constraints) # /
 185     {
 186         # FIXME: add ALL?
 187         my $sql="SELECT DISTINCT name FROM tags;";
 188         my $tags=$self->cmd_rows($sql);
 189         return(map { $_->[0]; } @$tags);
 190     }
 191     my @ids=();
 192
 193     my $main_sql_start=("SELECT t2.name\n" .
 194                         "\tFROM (\n" .
 195                         $self->tags_subselect(@constraints) .
 196                         ") AS subselect\n" .
 197                       "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n" .
 198                       "INNER JOIN tags t2 ON files_x_tags.tags_id=t2.id\n" .
 199                       "WHERE t2.id NOT IN (");
 200     my $main_sql_end=")\nGROUP BY t2.name;";
 201     # FIXME: generalise more?
 202
 203     while(my $constraint=shift @constraints)
 204     {
 205         my $cid=$constraint->{id};
 206         push(@ids, $cid);
 207     }
 208     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 209     my $tagstr=join(", ", @ids);
 210     my $sql = ($main_sql_start . $tagstr .
 211                $main_sql_end);
 212     print "SQL: $sql\n";
 213     my $result=$self->cmd_rows($sql);
 214     my @tagnames=map { $_->[0]; } @$result;
 215     print "SUBNAMES: ", join(', ', @tagnames), "\n";
 216     return(@tagnames);
 217 }
 218
 219 sub tag_values
 220 {
 221     my($self, $tagid)=@_;
 222     my $sql=("SELECT DISTINCT tagvals.name FROM tagvals\n" .
 223              "INNER JOIN tags_x_tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n" .
 224              "WHERE tags_x_tagvals.tags_id=?");
 225     my $tags=$self->cmd_rows($sql, $tagid);
 226     my @tags=map { $_->[0]; } @$tags;
 227     @tags=map { length($_) ? $_ : "NOVALUE"; } @tags;
 228     return @tags;
 229 }
 230
 231 sub artists
 232 {
 233     my($self, @constraints)=@_;
 234     if(!@constraints) # /ALL
 235     {
 236         my $sql="SELECT DISTINCT name FROM artists;";
 237         my $tags=$self->cmd_rows($sql);
 238         return(map { $_->[0]; } @$tags);
 239     }
 240     my @ids=();
 241     my $sql=("SELECT artists.name FROM (\n" .
 242              $self->tags_subselect(@constraints) .
 243              ") AS subselect\n" .
 244              "INNER JOIN files ON subselect.files_id=files.id\n" .
 245              "INNER JOIN artists ON files.artists_id=artists.id\n" .
 246              "GROUP BY artists.name;");
 247     print "SQL: $sql\n";
 248     my $result=$self->cmd_rows($sql);
 249     my @tagnames=map { $_->[0]; } @$result;
 250     print "ARTISTS: ", join(', ', @tagnames), "\n";
 251     return(@tagnames);
 252 }
 253
 254 sub albums
 255 {
 256     my($self, @constraints)=@_;
 257     my @ids=();
 258     # FIXME: rework PathElements
 259     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Artist")
 260     {
 261         return $self->artist_albums($constraints[$#constraints]->{id}, @constraints);
 262     }
 263     my $sql=("SELECT albums.name\n" .
 264              "\tFROM (\n" .
 265              $self->tags_subselect(@constraints) .
 266              "\t) AS subselect\n" .
 267              "INNER JOIN files ON subselect.files_id=files.id\n" .
 268              "INNER JOIN albums ON files.albums_id=albums.id\n" .
 269              "GROUP BY albums.name;");
 270     my $result=$self->cmd_rows($sql);
 271     my @names=map { $_->[0]; } @$result;
 272     print "ALBUMS: ", join(', ', @names), "\n";
 273     return(@names);
 274 }
 275
 276 sub artist_albums
 277 {
 278     my($self, $artist_id, @constraints)=@_;
 279     my $sql=("SELECT albums.name FROM (\n" .
 280              $self->tags_subselect(@constraints) .
 281              "\t) AS subselect\n" .
 282              "INNER JOIN files ON subselect.files_id=files.id\n" .
 283              "INNER JOIN albums ON albums.id=files.albums_id\n\t" .
 284              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 285              "WHERE artists.id=? and albums.name <> ''\n\t" .
 286              "GROUP BY albums.name\n");
 287     print "ARTIST_ALBUMS SQL: $sql\n";
 288     my $result=$self->cmd_rows($sql, $artist_id);
 289     my @albums=map { $_->[0]; } @$result;
 290     print "ALBUMS: ", join(', ', @albums), "\n";
 291     return(@albums);
 292 }
 293
 294 sub artist_tracks
 295 {
 296     my($self, $artist_id, @constraints)=@_;
 297     my $sql=("SELECT files.name FROM (\n" .
 298              $self->tags_subselect(@constraints) .
 299              "\t) AS subselect\n" .
 300              "INNER JOIN files ON subselect.files_id=files.id\n" .
 301              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 302              "INNER JOIN albums  ON albums.id=files.albums_id\n\t" .
 303              "WHERE artists.id=? AND albums.name=''\n\t" .
 304              "GROUP BY files.name\n");
 305     print "ARTIST_TRACKS SQL: $sql\n";
 306     my $result=$self->cmd_rows($sql, $artist_id);
 307     my @names=map { $_->[0]; } @$result;
 308     print "ARTISTTRACKS: ", join(', ', @names), "\n";
 309     return(@names);
 310 }
 311
 312 sub album_tracks
 313 {
 314     my($self, $artist_id, $album_id)=@_;
 315     my $sql=("SELECT files.name FROM files\n\t" .
 316              "INNER JOIN albums  ON albums.id=files.albums_id\n\t" .
 317              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 318              "WHERE artists.id=? AND albums.id=?\n\t" .
 319              "GROUP BY files.name\n");
 320     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n";
 321     my $result=$self->cmd_rows($sql, $artist_id, $album_id);
 322     my @names=map { $_->[0]; } @$result;
 323     print "TRACKS: ", join(', ', @names), "\n";
 324     return(@names);
 325 }
 326
 327 sub tracks
 328 {
 329     my($self, @constraints)=@_;
 330     # FIXME: rework PathElements
 331     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Artist")
 332     {
 333         return $self->artist_tracks($constraints[$#constraints]->{id}, @constraints);
 334     }
 335     elsif(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Album")
 336     {
 337         my $artist_id=0;
 338         my $artist=$constraints[($#constraints)-1];
 339         if(defined($artist) && (ref($artist) eq "ID3FS::PathElement::Artist"))
 340         {
 341             # should always happen
 342             $artist_id=$artist->{id};
 343         }
 344         return $self->album_tracks($artist_id, $constraints[$#constraints]->{id});
 345     }
 346
 347     my $sql=("SELECT files.name\n" .
 348              "\tFROM (\n" .
 349              $self->tags_subselect(@constraints) .
 350              "\t) AS subselect\n" .
 351              "INNER JOIN files ON files.id=subselect.files_id\n" .
 352              "GROUP BY files.name;");
 353     print "SQL: $sql\n";
 354     my $result=$self->cmd_rows($sql);
 355     my @names=map { $_->[0]; } @$result;
 356     print "TRACKS: ", join(', ', @names), "\n";
 357     return(@names);
 358 }
 359
 360 sub filename
 361 {
 362     my($self, $mountpoint, @constraints)=@_;
 363     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::File")
 364     {
 365         my $id=$constraints[$#constraints]->{id};
 366         my $sql=("SELECT paths.name, files.name FROM files\n" .
 367                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 368                  "WHERE files.id=?\n" .
 369                  "GROUP BY paths.name, files.name");
 370         print "FILENAME SQL: $sql\n";
 371         my ($path, $name)=$self->cmd_onerow($sql, $id);
 372         my $id3fs_path=join('/', map { $_->{name}; }  @constraints);
 373         return($self->relativise($path, $name, $mountpoint, $id3fs_path));
 374     }
 375     die("DB::filename: unhandled case\n"); #FIXME
 376 }
 377
 378 sub tags_subselect
 379 {
 380     my($self,@constraints)=@_;
 381     use Data::Dumper;
 382     my @tags=();
 383     my @tags_vals=();
 384     my $lasttag='';
 385 #    print "CONSTRAINTS: \n", Dumper \@constraints;
 386     for my $constraint (@constraints)
 387     {
 388 #       print ref($constraint),"\n";
 389         if(ref($constraint) eq "ID3FS::PathElement::Tag")
 390         {
 391             if($self->tag_has_values($constraint->{id}))
 392             {
 393 #               print "HASVALUES\n";
 394                 $lasttag=$constraint->{id} if defined($constraint->{id});
 395             }
 396             else
 397             {
 398 #               print "NOVALUES\n";
 399                 push(@tags, $constraint->{id}) if(defined($constraint->{id}));
 400             }
 401         }
 402         elsif(ref($constraint) eq "ID3FS::PathElement::Tagval")
 403         {
 404 #           print "TAGVAL\n";
 405             push(@tags_vals, [$lasttag, $constraint->{id}]) if defined($constraint->{id});
 406         }
 407     }
 408     unless($self->{postgres})
 409     {
 410         @tags=map{ "\"$_\""; } @tags;
 411         @tags_vals=map( { [ map({ "\"$_\""; } @$_ ) ] } @tags_vals);
 412     }
 413 #    print "TAGS\n", Dumper \@tags;
 414 #    print "\nVALS\n", Dumper(\@tags_vals), "\n";
 415     my $sql=("\tSELECT files_id FROM tags t1\n" .
 416              "\tINNER JOIN files_x_tags ON t1.id=files_x_tags.tags_id\n" .
 417              "\tINNER JOIN tags_x_tagvals ON t1.id=tags_x_tagvals.tags_id\n");
 418     my @clauses=();
 419     if(@tags)
 420     {
 421         push(@clauses, "(t1.id IN ( " . join(', ', @tags) ." ) )");
 422     }
 423     for my $pair (@tags_vals)
 424     {
 425         my($tag, $val)=@$pair;
 426         push(@clauses, "( t1.id=$tag AND tags_x_tagvals.tagvals_id=$val )");
 427     }
 428     if(@clauses)
 429     {
 430         $sql .= "\tWHERE\n\t\t" . join("\n\t\tOR ", @clauses) . "\n";
 431     }
 432     return $sql;
 433 }
 434
 435
 436 sub relativise
 437 {
 438     my($self, $path, $name, $mountpoint, $id3fs_path)=@_;
 439     $id3fs_path=~s/(.*)\/.*/$1/;
 440     my $rpath="$self->{absbase}/$path";
 441     my $vpath="$mountpoint/$id3fs_path";
 442     my @path=split(/\//,$rpath);
 443     my @rel=split(/\//,$vpath);
 444     #absolute paths have empty first element due to leading /
 445     shift(@path) if($path[0] eq "");
 446     shift(@rel)  if($rel[0]  eq "");
 447     if($path[0] ne $rel[0])
 448     {
 449         #no path in common, return absolute
 450         print "FAIL: NO PATHS IN COMMON\n";
 451         return $name;
 452     }
 453     # f: /home/foo/bar/baz.mp3
 454     # r: /home/ianb/music/albums
 455     while(@path && @rel && ($path[0] eq $rel[0]))
 456     {
 457         shift(@path);
 458         shift(@rel);
 459         print "POP ";
 460     }
 461     print "\n";
 462     my $upcount=scalar(@rel);
 463     my $result="../" x $upcount;
 464     $result .= join("/",@path);
 465     $result .= "/$name";
 466     return $result;
 467 }
 468
 469 sub bare_tags
 470 {
 471     my($self)=@_;
 472     my $sql=("SELECT tags.name FROM tags\n" .
 473              "WHERE tags.parents_id=''\n" .
 474              "GROUP BY tags.name\n");
 475     my $result=$self->cmd_rows($sql);
 476     my @names=map { $_->[0]; } @$result;
 477     return (@names);
 478 }
 479
 480 sub tags_with_values
 481 {
 482     # FIXME: only shows one level of tag depth
 483     my($self)=@_;
 484     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 485              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 486              "GROUP BY p.name, t.name\n");
 487 #    print "SQL: $sql\n";
 488     my $result=$self->cmd_rows($sql);
 489     my $tags={};
 490     for my $pair (@$result)
 491     {
 492         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 493     }
 494     return $tags;
 495 }
 496
 497 sub id
 498 {
 499     my($self, $type, $val)=@_;
 500     my $sql="SELECT id FROM $type WHERE name=?";
 501     my ($id)=$self->cmd_onerow($sql, $val);
 502     return($id);
 503 }
 504
 505 sub add
 506 {
 507     my($self,$path)=@_;
 508     my $relpath=$path;
 509     $relpath =~ s/^\Q$self->{base}\E\/?//;
 510     my($filepart,$pathpart);
 511     if($path !~ /\//)
 512     {
 513         $pathpart='';
 514         $filepart=$relpath;
 515     }
 516     else
 517     {
 518         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 519     }
 520     my $file=ID3FS::AudioFile->new($path, $self->{me});
 521     return unless(defined($file));
 522     my $artist=$file->artist();
 523     my $album=$file->album();
 524     my $v1genre=$file->v1genre();
 525     my $year=$file->year();
 526     my $audiotype=$file->audiotype();
 527     my @tags=$file->tags();
 528     my $haspic=$file->haspic();
 529
 530     $artist=undef unless($self->ok($artist));
 531     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 532     my $artist_id=$self->add_to_table("artists",  $artist);
 533     my $path_id=$self->add_to_table("paths", $pathpart);
 534     $album=undef unless($self->ok($album));
 535     if($self->{verbose} && !defined($album))
 536     {
 537         print "$self->{me}: $path: no album tag defined\n";
 538     }
 539
 540     my $albums_id=$self->add_to_table("albums", $album);
 541     my $file_id=$self->add_to_table("files", $filepart,
 542                                     { "artists_id" => $artist_id,
 543                                       "albums_id"  => $albums_id,
 544                                       "paths_id"   => $path_id });
 545     for my $tag (@tags)
 546     {
 547         $self->add_tag($file_id, @$tag);
 548     }
 549
 550     if($self->ok($year))
 551     {
 552         $self->add_tag($file_id, "year", $year);
 553         if($year=~/^(\d\d\d)\d$/)
 554         {
 555             $self->add_tag($file_id, "decade", "${1}0s");
 556         }
 557     }
 558
 559     if($self->ok($v1genre))
 560     {
 561         $self->add_tag($file_id, "v1genre", $v1genre);
 562     }
 563
 564     if($haspic)
 565     {
 566         $self->add_tag($file_id, "haspic", undef);
 567     }
 568 }
 569
 570 sub add_tag
 571 {
 572     my($self, $file_id, @tags)=@_;
 573     my $parent_id=undef;
 574     for my $tag (@tags)
 575     {
 576         my $tag_id=$self->add_to_table("tags",  $tag,
 577                                        { "parents_id" => $parent_id });
 578         $self->add_relation("files_x_tags",
 579                             { "files_id" => $file_id,
 580                               "tags_id"  => $tag_id });
 581         $parent_id=$tag_id;
 582     }
 583 }
 584
 585 sub add_to_table
 586 {
 587     my($self, $table, $name, $extradata)=@_;
 588     my $id=$self->lookup_id($table, $name);
 589     unless(defined($id))
 590     {
 591         my $sql="INSERT INTO $table (";
 592         $sql .= "id, " if($self->{postgres});
 593         my @fields=qw(name);
 594         if(defined($extradata))
 595         {
 596             push(@fields, sort keys(%$extradata));
 597         }
 598         $sql .= join(", ", @fields);
 599         $sql .=") VALUES (";
 600         $sql .=") nextval('seq'), " if($self->{postgres});
 601         $sql .= join(", ", map { "?"; } @fields);
 602         $sql .= ");";
 603         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 604     }
 605     return $id;
 606 }
 607
 608 sub add_relation
 609 {
 610     my ($self, $relname, $fields)=@_;
 611     return if($self->relation_exists($relname, $fields));
 612     my $sql="INSERT INTO $relname (";
 613     $sql .= join(", ", sort keys(%$fields));
 614     $sql .= ") VALUES (";
 615     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 616     $sql .= ");";
 617     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 618 }
 619
 620 sub lookup_id
 621 {
 622     my($self, $table, $name)=@_;
 623     my($id)=$self->cmd_onerow("SELECT id FROM $table where name=?", $name);
 624     return $id;
 625 }
 626
 627 sub tag_has_values
 628 {
 629     my($self, $id)=@_;
 630     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 631              "INNER JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n\t" .
 632              "INNER JOIN tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n\t" .
 633              "WHERE tags.id=?\n");
 634     my ($rows)=$self->cmd_onerow($sql, $id);
 635     return $rows;
 636 }
 637
 638 sub files_in
 639 {
 640     my ($self, $dir)=@_;
 641     $dir=~s/^$self->{base}\/?//;
 642     my $sql=("SELECT files.name FROM files\n" .
 643              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 644              "WHERE paths.name=?\n");
 645     my $files=$self->cmd_rows($sql, $dir);
 646     return(map { $_->[0]; } @$files);
 647 }
 648
 649 sub prune_directories
 650 {
 651     my($self)=@_;
 652     my $sql=("SELECT name, id FROM paths ORDER BY name\n");
 653     my $pathsref=$self->cmd_rows($sql);
 654     my @ids=();
 655     for my $pathpair (@$pathsref)
 656     {
 657         my($path, $id)=@$pathpair;
 658         my $fullpath="$self->{absbase}/$path";
 659         unless(-d $fullpath)
 660         {
 661             push(@ids, $id)
 662         }
 663     }
 664     $self->prune_paths(@ids);
 665     return scalar(@ids);
 666 }
 667
 668 sub prune_paths
 669 {
 670     my($self, @ids)=@_;
 671     return unless(@ids);
 672     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 673              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 674     print "SQL: \n", $sql, "\n";
 675     $self->cmd($sql);
 676 }
 677
 678 sub remove_unused
 679 {
 680     my($self)=@_;
 681     my $sql=<<'EOT';
 682    DELETE FROM artists WHERE id IN (
 683        SELECT artists.id FROM artists
 684        LEFT JOIN files ON files.artists_id=artists.id
 685        WHERE files.id IS NULL);
 686
 687    DELETE FROM albums WHERE id IN (
 688        SELECT albums.id FROM albums
 689        LEFT JOIN files ON files.albums_id=albums.id
 690        WHERE files.id IS NULL);
 691
 692    DELETE FROM paths WHERE id IN (
 693        SELECT paths.id FROM paths
 694        LEFT JOIN files ON files.paths_id=paths.id
 695        WHERE files.id IS NULL);
 696
 697    DELETE FROM files_x_tags WHERE files_id IN (
 698        SELECT files_x_tags.files_id FROM files_x_tags
 699        LEFT JOIN files ON files.id=files_x_tags.files_id
 700        WHERE files.id IS NULL);
 701
 702    DELETE FROM tags WHERE id IN (
 703        SELECT tags.id FROM tags
 704        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 705        WHERE files_x_tags.files_id IS NULL);
 706
 707    DELETE FROM tags_x_tagvals WHERE tags_id IN (
 708        SELECT tags_x_tagvals.tags_id FROM tags_x_tagvals
 709        LEFT JOIN tags ON tags.id=tags_x_tagvals.tags_id
 710        WHERE tags.id IS NULL);
 711
 712    DELETE FROM tagvals WHERE id IN (
 713        SELECT tagvals.id FROM tagvals
 714        LEFT JOIN tags_x_tagvals ON tags_x_tagvals.tagvals_id=tagvals.id
 715        WHERE tags_x_tagvals.tagvals_id IS NULL);
 716 EOT
 717     print "SQL: $sql\n";
 718     my @sql=split(/\n\n/, $sql);
 719     $self->cmd($_) for (@sql);
 720 }
 721
 722 sub relation_exists
 723 {
 724     my ($self, $relname, $fields)=@_;
 725     my $sql="SELECT count(1) FROM $relname WHERE ";
 726     my @exprs=();
 727     my @vals=();
 728     for my $field (keys %$fields)
 729     {
 730         push(@exprs,$field);
 731         push(@vals,$fields->{$field});
 732     }
 733     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 734     my ($ret)=$self->cmd_onerow($sql, @vals);
 735     return $ret;
 736 }
 737
 738 sub ok
 739 {
 740     my($self, $thing)=@_;
 741     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 742 }
 743
 744 sub cmd
 745 {
 746     my ($self, @args)=@_;
 747     # don't care about retcode
 748     $self->cmd_sth(@args);
 749 }
 750
 751 sub cmd_onerow
 752 {
 753     my ($self, @args)=@_;
 754     my $sth=$self->cmd_sth(@args);
 755     return($sth->fetchrow_array());
 756 }
 757
 758 sub cmd_rows
 759 {
 760     my ($self, @args)=@_;
 761     my $sth=$self->cmd_sth(@args);
 762     return $sth->fetchall_arrayref();
 763 }
 764
 765 sub cmd_id
 766 {
 767     my ($self, @args)=@_;
 768     $self->cmd_sth(@args);
 769     return($self->last_insert_id());
 770 }
 771
 772 sub last_insert_id
 773 {
 774     my $self=shift;
 775     if($self->{postgres})
 776     {
 777         return $self->{dbh}->last_insert_id(undef, undef, undef, undef,
 778                                             { sequence => "seq" });
 779     }
 780     else
 781     {
 782         return $self->{dbh}->last_insert_id("","","","");
 783     }
 784 }
 785
 786 __DATA__
 787
 788 CREATE TABLE id3fs (
 789     schema_version INTEGER,
 790     last_update
 791 );
 792
 793 CREATE TABLE paths (
 794     id INTEGER PRIMARY KEY,
 795     name text
 796 );
 797
 798 CREATE TABLE artists (
 799     id INTEGER PRIMARY KEY,
 800     name text
 801 );
 802
 803 CREATE TABLE albums (
 804     id INTEGER PRIMARY KEY,
 805     name text
 806 );
 807
 808 CREATE TABLE files (
 809     id INTEGER PRIMARY KEY,
 810     name text,
 811     artists_id,
 812     albums_id,
 813     paths_id,
 814     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 815     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 816     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 817 );
 818
 819 CREATE TABLE tags (
 820     id INTEGER PRIMARY KEY,
 821     parents_id INTEGER,
 822     name text
 823 );
 824
 825 CREATE TABLE tagvals (
 826     id INTEGER PRIMARY KEY,
 827     name text
 828 );
 829
 830 CREATE TABLE files_x_tags (
 831     files_id INTEGER,
 832     tags_id INTEGER,
 833     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 834     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 835 );
 836
 837 CREATE TABLE tags_x_tagvals (
 838     tags_id INTEGER,
 839     tagvals_id INTEGER,
 840     FOREIGN KEY(tags_id) REFERENCES tags(id) ON DELETE CASCADE ON UPDATE CASCADE,
 841     FOREIGN KEY(tagvals_id) REFERENCES tagvals(id) ON DELETE CASCADE ON UPDATE CASCADE
 842 );
 843