lib/ID3FS/DB.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::DB;
  18
  19 use strict;
  20 use warnings;
  21 use DBI;
  22 use ID3FS::AudioFile;
  23 use Cwd;
  24
  25 our $SCHEMA_VERSION=1;
  26 my $dbfile=".id3fs"; # default
  27
  28 sub new
  29 {
  30     my $proto=shift;
  31     my $class=ref($proto) || $proto;
  32     my $self={};
  33     bless($self,$class);
  34
  35     $self->{me}=shift;
  36     $self->{verbose}=shift;
  37     my $init=shift;
  38     $self->{base}=shift;
  39     $self->{dbpath}=shift || ($self->{base} . "/" . $dbfile);
  40     $self->{dbpath}=Cwd::abs_path($self->{dbpath});
  41     $self->{absbase}=Cwd::abs_path($self->{base});
  42
  43     my $connectstr="dbi:SQLite:dbname=$self->{dbpath}";
  44     my $exists=-f $self->{dbpath};
  45     $self->{dbh}=DBI->connect($connectstr, undef, undef,
  46                               { AutoCommit=>1 } );
  47     unless(defined($self->{dbh}))
  48     {
  49         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  50     }
  51
  52     if($exists)
  53     {
  54         $self->checkschema();
  55     }
  56     else
  57     {
  58         $self->create();
  59     }
  60     $self->enable_foreign_keys();
  61     return $self;
  62 }
  63
  64 # search parent directories for db
  65 sub find_db
  66 {
  67     # class method
  68     shift if(ref($_[0]) eq "ID3FS::DB");
  69
  70     my($me, $init, @dirs)=@_;
  71     my $base=undef;
  72     for my $dir (@dirs)
  73     {
  74         my $path=Cwd::abs_path($dir);
  75         do
  76         {
  77             $base=$path;
  78             $path=~s/(.*)\/.*/$1/;
  79         }
  80         while(! -f "$base/$dbfile" && length($path) && -d $path);
  81         if(-f "$base/$dbfile")
  82         {
  83             return $base;
  84         }
  85     }
  86     if(!-f "$base/$dbfile")
  87     {
  88         unless($init)
  89         {
  90             print "$me: db not found at $base/$dbfile\n";
  91             return undef;
  92         }
  93         $base=$dirs[0];
  94
  95     }
  96     return $base;
  97 }
  98
  99 sub base_dir { return shift->{base}; }
 100
 101 sub create
 102 {
 103     my($self,$name)=@_;
 104     my @schema=split(/\n\n/,join("", <DATA>));
 105     close(DATA);
 106     for my $cmd (@schema)
 107     {
 108         $self->{dbh}->do($cmd);
 109     }
 110     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 111                $SCHEMA_VERSION, time());
 112 }
 113
 114 sub checkschema
 115 {
 116     my $self=shift;
 117     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 118     if(!defined($version) || $version != $SCHEMA_VERSION)
 119     {
 120         die("$self->{me}: id3fs database version " .
 121             defined($version) ? $version : '""' .
 122             "not known, current version is $SCHEMA_VERSION.\n");
 123     }
 124 }
 125
 126 sub analyze
 127 {
 128     my $self=shift;
 129     $self->cmd("ANALYZE");
 130 }
 131
 132 sub enable_foreign_keys
 133 {
 134     my $self=shift;
 135     $self->cmd("PRAGMA foreign_keys = ON");
 136 }
 137
 138 sub last_update
 139 {
 140     my($self, $newval)=@_;
 141     if(defined($newval))
 142     {
 143         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 144     }
 145     else
 146     {
 147         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 148     }
 149     return $newval;
 150 }
 151
 152 sub bare_tags
 153 {
 154     my($self)=@_;
 155     my $sql=("SELECT tags.name FROM tags\n" .
 156              "WHERE tags.parents_id=''\n" .
 157              "GROUP BY tags.name\n");
 158     my @names=$self->cmd_firstcol($sql);
 159     return (@names);
 160 }
 161
 162 sub tags_with_values
 163 {
 164     my($self)=@_;
 165     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 166              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 167              "GROUP BY p.name, t.name\n");
 168     my $result=$self->cmd_rows($sql);
 169     my $tags={};
 170     for my $pair (@$result)
 171     {
 172         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 173     }
 174     return $tags;
 175 }
 176
 177 sub tag_has_values
 178 {
 179     my($self, $id)=@_;
 180     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 181              "WHERE tags.parents_id=?\n");
 182     my ($rows)=$self->cmd_onerow($sql, $id);
 183     return $rows;
 184 }
 185
 186 sub relativise
 187 {
 188     my($self, $path, $name, $mountpoint, $querypath)=@_;
 189     my $rpath="$self->{absbase}/$path";
 190     my $vpath=$mountpoint . $querypath;
 191     my @path=split(/\//,$rpath);
 192     my @rel=split(/\//,$vpath);
 193     # drop filename from rel
 194     pop @rel;
 195     # absolute paths have empty first element due to leading /
 196     shift(@path) if($path[0] eq "");
 197     shift(@rel)  if($rel[0]  eq "");
 198     # f: /home/foo/bar/baz.mp3
 199     # r: /home/ianb/music/albums
 200     while(@path && @rel && ($path[0] eq $rel[0]))
 201     {
 202         shift(@path);
 203         shift(@rel);
 204     }
 205     my $upcount=scalar(@rel);
 206     my $result="../" x $upcount;
 207     $result .= join("/",@path);
 208     $result .= "/$name";
 209     return $result;
 210 }
 211
 212 sub add
 213 {
 214     my($self,$path)=@_;
 215     my $relpath=Cwd::abs_path($path);
 216     $relpath =~ s/^\Q$self->{absbase}\E\/?//;
 217     my($filepart,$pathpart);
 218     if($relpath !~ /\//)
 219     {
 220         $pathpart='';
 221         $filepart=$relpath;
 222     }
 223     else
 224     {
 225         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 226     }
 227     my $file=ID3FS::AudioFile->new($path, $self->{me});
 228     return unless(defined($file));
 229     my $artist=$file->artist();
 230     my $album=$file->album();
 231     my $v1genre=$file->v1genre();
 232     my $year=$file->year();
 233     my $audiotype=$file->audiotype();
 234     my @tags=$file->tags();
 235     my $haspic=$file->haspic();
 236
 237     $artist=undef unless($self->ok($artist));
 238     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 239     my $artist_id=$self->add_to_table("artists",  $artist);
 240     my $path_id=$self->add_to_table("paths", $pathpart);
 241     $album=undef unless($self->ok($album));
 242     if($self->{verbose} && !defined($album))
 243     {
 244         print "$self->{me}: $path: no album tag defined\n";
 245     }
 246
 247     my $albums_id=$self->add_to_table("albums", $album);
 248     my $file_id=$self->add_to_table("files", $filepart,
 249                                     { "artists_id" => $artist_id,
 250                                       "albums_id"  => $albums_id,
 251                                       "paths_id"   => $path_id });
 252     for my $tag (@tags)
 253     {
 254         $self->add_tag($file_id, @$tag);
 255     }
 256
 257     $year="UNKNOWN" unless($self->ok($year));
 258     $self->add_tag($file_id, "year", $year);
 259     if($year=~/^(\d\d\d)\d$/)
 260     {
 261         $self->add_tag($file_id, "decade", "${1}0s");
 262     }
 263     else
 264     {
 265         $self->add_tag($file_id, "decade", "UNKNOWN");
 266     }
 267
 268     if($self->ok($v1genre))
 269     {
 270         $self->add_tag($file_id, "v1genre", $v1genre);
 271     }
 272
 273     if($haspic)
 274     {
 275         $self->add_tag($file_id, "haspic", undef);
 276     }
 277
 278     if($self->ok($audiotype))
 279     {
 280         $self->add_tag($file_id, "audiotype", $audiotype);
 281     }
 282 }
 283
 284 sub add_tag
 285 {
 286     my($self, $file_id, $tag, $value)=@_;
 287     my $tag_id=$self->add_to_table("tags",  $tag,
 288                                    { "parents_id" => undef });
 289     $self->add_relation("files_x_tags",
 290                         { "files_id" => $file_id,
 291                           "tags_id"  => $tag_id });
 292     if(defined($value) && length($value))
 293     {
 294         my $val_id=$self->add_to_table("tags",  $value,
 295                                        { "parents_id" => $tag_id });
 296         $self->add_relation("files_x_tags",
 297                             { "files_id" => $file_id,
 298                               "tags_id"  => $val_id });
 299     }
 300 }
 301
 302 sub add_to_table
 303 {
 304     my($self, $table, $name, $extradata)=@_;
 305     my $parent=undef;
 306     if($extradata && $extradata->{parents_id})
 307     {
 308         $parent=$extradata->{parents_id};
 309     }
 310     my $id=$self->lookup_id($table, $name, $parent);
 311     unless(defined($id))
 312     {
 313         my $sql="INSERT INTO $table (";
 314         my @fields=qw(name);
 315         if(defined($extradata))
 316         {
 317             push(@fields, sort keys(%$extradata));
 318         }
 319         $sql .= join(", ", @fields);
 320         $sql .=") VALUES (";
 321         $sql .= join(", ", map { "?"; } @fields);
 322         $sql .= ");";
 323         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 324     }
 325     return $id;
 326 }
 327
 328 sub add_relation
 329 {
 330     my ($self, $relname, $fields)=@_;
 331     return if($self->relation_exists($relname, $fields));
 332     my $sql="INSERT INTO $relname (";
 333     $sql .= join(", ", sort keys(%$fields));
 334     $sql .= ") VALUES (";
 335     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 336     $sql .= ");";
 337     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 338 }
 339
 340 sub files_in
 341 {
 342     my ($self, $dir)=@_;
 343     my $sql=("SELECT files.name FROM files\n" .
 344              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 345              "WHERE paths.name=?\n");
 346     return($self->cmd_firstcol($sql, $dir));
 347 }
 348
 349 sub unindex
 350 {
 351     my($self, $path, $file)=@_;
 352     my $sql=("DELETE FROM files WHERE id IN (" .
 353              "\tSELECT files.id FROM files\n" .
 354              "\tINNER JOIN paths ON paths.id=files.paths_id\n" .
 355              "\tWHERE paths.name=? and files.name=? )\n");
 356     $self->cmd_rows($sql, $path, $file);
 357 }
 358
 359
 360 sub prune_directories
 361 {
 362     my($self)=@_;
 363     my $sql=("SELECT name, id FROM paths\n");
 364     my $pathsref=$self->cmd_rows($sql);
 365     my @ids=();
 366     for my $pathpair (@$pathsref)
 367     {
 368         my($path, $id)=@$pathpair;
 369         my $fullpath="$self->{absbase}/$path";
 370         unless(-d $fullpath)
 371         {
 372             push(@ids, $id)
 373         }
 374     }
 375     $self->prune_paths(@ids);
 376     return scalar(@ids);
 377 }
 378
 379 sub prune_paths
 380 {
 381     my($self, @ids)=@_;
 382     return unless(@ids);
 383     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 384              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 385     $self->cmd($sql);
 386 }
 387
 388 sub remove_unused
 389 {
 390     my($self)=@_;
 391     my $sql=<<'EOT';
 392    DELETE FROM artists WHERE id IN (
 393        SELECT artists.id FROM artists
 394        LEFT JOIN files ON files.artists_id=artists.id
 395        WHERE files.id IS NULL);
 396
 397    DELETE FROM albums WHERE id IN (
 398        SELECT albums.id FROM albums
 399        LEFT JOIN files ON files.albums_id=albums.id
 400        WHERE files.id IS NULL);
 401
 402    DELETE FROM paths WHERE id IN (
 403        SELECT paths.id FROM paths
 404        LEFT JOIN files ON files.paths_id=paths.id
 405        WHERE files.id IS NULL);
 406
 407    DELETE FROM files_x_tags WHERE files_id IN (
 408        SELECT files_x_tags.files_id FROM files_x_tags
 409        LEFT JOIN files ON files.id=files_x_tags.files_id
 410        WHERE files.id IS NULL);
 411
 412    DELETE FROM tags WHERE id IN (
 413        SELECT tags.id FROM tags
 414        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 415        WHERE files_x_tags.files_id IS NULL);
 416
 417     VACUUM
 418 EOT
 419 #    print "SQL: $sql\n";
 420     my @sql=split(/\n\n/, $sql);
 421     $self->cmd($_) for (@sql);
 422 }
 423
 424 sub relation_exists
 425 {
 426     my ($self, $relname, $fields)=@_;
 427     my $sql="SELECT count(1) FROM $relname WHERE ";
 428     my @exprs=();
 429     my @vals=();
 430     for my $field (keys %$fields)
 431     {
 432         push(@exprs,$field);
 433         push(@vals,$fields->{$field});
 434     }
 435     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 436     my ($ret)=$self->cmd_onerow($sql, @vals);
 437     return $ret;
 438 }
 439
 440 sub ok
 441 {
 442     my($self, $thing)=@_;
 443     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 444 }
 445
 446 # actually call the database
 447 sub cmd_sth
 448 {
 449     my($self, $sql, @params)=@_;
 450     my $sth=$self->{dbh}->prepare($sql);
 451     my $idx=1;
 452     for my $param (@params)
 453     {
 454         $param="" unless(defined($param));
 455         $sth->bind_param($idx++, $param);
 456     }
 457     $sth->execute();
 458     return $sth;
 459 }
 460
 461 # pass cmd to db, ignore response
 462 sub cmd
 463 {
 464     my ($self, @args)=@_;
 465     # don't care about retcode
 466     $self->cmd_sth(@args);
 467 }
 468
 469 # return one row
 470 sub cmd_onerow
 471 {
 472     my ($self, @args)=@_;
 473     my $sth=$self->cmd_sth(@args);
 474     return($sth->fetchrow_array());
 475 }
 476
 477 # returns all rows
 478 sub cmd_rows
 479 {
 480     my ($self, @args)=@_;
 481     my $sth=$self->cmd_sth(@args);
 482     return $sth->fetchall_arrayref();
 483 }
 484
 485 # returns just the first column
 486 sub cmd_firstcol
 487 {
 488     my ($self, @args)=@_;
 489     return(map { $_->[0] } @{$self->cmd_rows(@args)});
 490 }
 491
 492 # runs cmd, returns id of last insert
 493 sub cmd_id
 494 {
 495     my ($self, @args)=@_;
 496     $self->cmd_sth(@args);
 497     return($self->last_insert_id());
 498 }
 499
 500 sub last_insert_id
 501 {
 502     my $self=shift;
 503     return $self->{dbh}->last_insert_id("","","","");
 504 }
 505
 506 # lookup id of $name in $table, also matching on $parent if needed
 507 sub lookup_id
 508 {
 509     my($self, $table, $name, $parent)=@_;
 510     my $sql="SELECT id FROM $table where name=?";
 511     my @args=($name);
 512     if($parent)
 513     {
 514         $sql .= " AND parents_id=?";
 515         push(@args, $parent);
 516     }
 517     my($id)=$self->cmd_onerow($sql, @args);
 518     return $id;
 519 }
 520
 521 __DATA__
 522
 523 CREATE TABLE id3fs (
 524     schema_version INTEGER,
 525     last_update
 526 );
 527
 528 CREATE TABLE paths (
 529     id INTEGER,
 530     name text,
 531     PRIMARY KEY(id ASC)
 532 );
 533
 534 CREATE TABLE artists (
 535     id INTEGER,
 536     name text,
 537     PRIMARY KEY(id ASC)
 538 );
 539
 540 CREATE TABLE albums (
 541     id INTEGER,
 542     name text,
 543     PRIMARY KEY(id ASC)
 544 );
 545
 546 CREATE TABLE files (
 547     id INTEGER,
 548     name text,
 549     artists_id,
 550     albums_id,
 551     paths_id,
 552     PRIMARY KEY(id ASC),
 553     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 554     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 555     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 556 );
 557
 558 CREATE TABLE tags (
 559     id INTEGER,
 560     parents_id INTEGER,
 561     name text,
 562     PRIMARY KEY(id ASC)
 563 );
 564
 565 CREATE TABLE files_x_tags (
 566     files_id INTEGER,
 567     tags_id INTEGER,
 568     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 569     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 570 );
 571
 572 CREATE INDEX idx_fxt_both ON files_x_tags (files_id, tags_id)
 573
 574 CREATE INDEX idx_fxt_tags ON files_x_tags (tags_id)
 575
 576 CREATE INDEX idx_files_id_name ON files (id, name)
 577
 578 CREATE INDEX idx_files_name_id ON files (name, id)
 579
 580 CREATE INDEX idx_tags_id_parent_name ON tags (id, parents_id, name)
 581
 582 CREATE INDEX idx_tags_parent_id_name ON tags (parents_id, id, name)
 583
 584 CREATE INDEX idx_tags_name ON tags (name)