lib/ID3FS/DB.pm

   1 package ID3FS::DB;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use ID3FS::AudioFile;
   7 use Cwd;
   8
   9 our $SCHEMA_VERSION=1;
  10 my $dbfile=".id3fs";
  11
  12 sub new
  13 {
  14     my $proto=shift;
  15     my $class=ref($proto) || $proto;
  16     my $self={};
  17     bless($self,$class);
  18
  19     $self->{me}=shift;
  20     $self->{verbose}=shift;
  21     my $init=shift;
  22     my $dbpath=shift;
  23     $self->{base}=shift;
  24     my $fallbackdir=shift;
  25
  26     $dbpath=$self->find_db($init, $dbpath, $fallbackdir);
  27     return undef unless($dbpath);
  28     $self->{absbase}=Cwd::abs_path($self->{base});
  29
  30     my $connectstr="dbi:SQLite:dbname=$dbpath";
  31     my ($user, $pass)=("", "");
  32     if($self->{postgres})
  33     {
  34         $connectstr="dbi:Pg:dbname=id3fs";
  35         $user="ianb";
  36         $pass="foo";
  37     }
  38     my $exists=-f $dbpath;
  39     $self->{dbh}=DBI->connect($connectstr, $user, $pass,
  40                               { AutoCommit=>1 } );
  41     unless(defined($self->{dbh}))
  42     {
  43         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  44     }
  45
  46     if($exists)
  47     {
  48         $self->checkschema();
  49     }
  50     else
  51     {
  52         $self->create();
  53     }
  54     $self->enable_foreign_keys();
  55     return $self;
  56 }
  57
  58 sub find_db
  59 {
  60     my($self, $init, $dbpath, $fallbackdir)=@_;
  61     my $file=undef;
  62     my $base=undef;
  63     if(defined($dbpath))
  64     {
  65         $file=$dbpath;
  66     }
  67     if(defined ($self->{base}))
  68     {
  69         $file="$self->{base}/$dbfile" unless defined($file);
  70         $base=$self->{base};
  71     }
  72     elsif(defined($fallbackdir) && -d $fallbackdir)
  73     {
  74         my $path=Cwd::abs_path($fallbackdir);
  75         do
  76         {
  77             $file="$path/$dbfile";
  78             $base=$path;
  79             $path=~s/(.*)\/.*/$1/;
  80         }
  81         while(! -f $file && length($path) && -d $path);
  82         if(! -f $file)
  83         {
  84             $file="$fallbackdir/$dbfile";
  85             $base=$fallbackdir;
  86         }
  87     }
  88     if(!-f $file && !$init)
  89     {
  90         print "$self->{me}: db not found at $file\n";
  91         return undef;
  92     }
  93     $self->{base}=$base;
  94     return $file;
  95 }
  96
  97 sub base_dir { return shift->{base}; }
  98
  99 sub create
 100 {
 101     my($self,$name)=@_;
 102     my @schema=split(/\n\n/,join("", <DATA>));
 103     close(DATA);
 104     for my $cmd (@schema)
 105     {
 106         $self->{dbh}->do($cmd);
 107     }
 108     if($self->{postgres})
 109     {
 110         $self->cmd("CREATE SEQUENCE seq");
 111     }
 112     else
 113     {
 114         my %indexes=( "idx_files_id"  => "files (id)",
 115                       "idx_fxt_both"  => "files_x_tags (files_id, tags_id)",
 116                       "idx_fxt_files" => "files_x_tags (files_id)",
 117                       "idx_fxt_tags"  => "files_x_tags (tags_id)",
 118                       "idx_tags_id"   => "tags (id)",
 119                       "idx_tags_name" => "tags (name)");
 120         for my $index (keys %indexes)
 121         {
 122             $self->{dbh}->do("CREATE INDEX $index ON " . $indexes{$index});
 123         }
 124     }
 125     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 126                $SCHEMA_VERSION, time());
 127 }
 128
 129 sub checkschema
 130 {
 131     my $self=shift;
 132     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 133     if(!defined($version) || $version != $SCHEMA_VERSION)
 134     {
 135         die("$self->{me}: id3fs database version " .
 136             defined($version) ? $version : '""' .
 137             "not known, current version is $SCHEMA_VERSION.\n");
 138     }
 139 }
 140
 141 sub analyze
 142 {
 143     my $self=shift;
 144     $self->cmd("ANALYZE");
 145 }
 146
 147 sub enable_foreign_keys
 148 {
 149     my $self=shift;
 150     $self->cmd("PRAGMA foreign_keys = ON");
 151 }
 152
 153 sub last_update
 154 {
 155     my($self, $newval)=@_;
 156     if(defined($newval))
 157     {
 158         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 159     }
 160     else
 161     {
 162         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 163     }
 164     return $newval;
 165 }
 166
 167 sub cmd_sth
 168 {
 169     my($self, $sql, @params)=@_;
 170     my $sth=$self->{dbh}->prepare($sql);
 171     my $idx=1;
 172     for my $param (@params)
 173     {
 174         $param="" unless(defined($param));
 175         $sth->bind_param($idx++, $param);
 176     }
 177     $sth->execute();
 178     return $sth;
 179 }
 180
 181 sub tags
 182 {
 183     my($self, @constraints)=@_;
 184     if(!@constraints) # /
 185     {
 186         # FIXME: add ALL?
 187         my $sql="SELECT DISTINCT name FROM tags;";
 188         my $tags=$self->cmd_rows($sql);
 189         return(map { $_->[0]; } @$tags);
 190     }
 191     my @ids=();
 192
 193     my $main_sql_start=("SELECT t2.name\n" .
 194                         "\tFROM (SELECT files_id FROM tags t1\n" .
 195                         "\t\tINNER JOIN files_x_tags ON t1.id=files_x_tags.tags_id\n" .
 196                         "\t\tWHERE t1.id in\n\t\t\t(");
 197     my $main_sql_mid=(")\n\t\t) AS subselect\n" .
 198                       "\tINNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n" .
 199                       "\tINNER JOIN tags t2 ON files_x_tags.tags_id=t2.id\n" .
 200                       "\tWHERE t2.id NOT IN (");
 201     my $main_sql_end=")\n\tGROUP BY t2.name;";
 202     while(my $constraint=shift @constraints)
 203     {
 204         my $cid=$constraint->{id};
 205         push(@ids, $cid);
 206     }
 207     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 208     my $tagstr=join(", ", @ids);
 209     my $sql = ($main_sql_start . $tagstr .
 210                $main_sql_mid   . $tagstr .
 211                $main_sql_end);
 212     print "SQL: $sql\n";
 213     my $result=$self->cmd_rows($sql);
 214     my @tagnames=map { $_->[0]; } @$result;
 215     print "SUBNAMES: ", join(', ', @tagnames), "\n";
 216     return(@tagnames);
 217 }
 218
 219 sub tag_values
 220 {
 221     my($self, $tagid)=@_;
 222     my $sql=("SELECT DISTINCT tagvals.name FROM tagvals\n" .
 223              "INNER JOIN tags_x_tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n" .
 224              "WHERE tags_x_tagvals.tags_id=?");
 225     my $tags=$self->cmd_rows($sql, $tagid);
 226     my @tags=map { $_->[0]; } @$tags;
 227     @tags=map { length($_) ? $_ : "NOVALUE"; } @tags;
 228     return @tags;
 229 }
 230
 231 sub artists
 232 {
 233     my($self, @constraints)=@_;
 234     if(!@constraints) # /ALL
 235     {
 236         my $sql="SELECT DISTINCT name FROM artists;";
 237         my $tags=$self->cmd_rows($sql);
 238         return(map { $_->[0]; } @$tags);
 239     }
 240     my @ids=();
 241     my $main_sql_start=("SELECT artists.name\n" .
 242                         "\tFROM (SELECT files_id FROM tags\n" .
 243                         "\t\tINNER JOIN files_x_tags ON tags.id=files_x_tags.tags_id\n" .
 244                         "\t\tWHERE tags.id in\n\t\t\t(");
 245     my $main_sql_end=(")\n\t\t) AS subselect\n" .
 246                       "\tINNER JOIN files ON subselect.files_id=files.id\n" .
 247                       "\tINNER JOIN artists ON files.artists_id=artists.id\n" .
 248                       "\n\tGROUP BY artists.name;");
 249     while(my $constraint=shift @constraints)
 250     {
 251         my $cid=$constraint->{id};
 252         push(@ids, $cid);
 253     }
 254     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 255     my $tagstr=join(", ", @ids);
 256     my $sql = ($main_sql_start . $tagstr .
 257                $main_sql_end);
 258     print "SQL: $sql\n";
 259     my $result=$self->cmd_rows($sql);
 260     my @tagnames=map { $_->[0]; } @$result;
 261     print "ARTISTS: ", join(', ', @tagnames), "\n";
 262     return(@tagnames);
 263 }
 264
 265 sub albums
 266 {
 267     my($self, @constraints)=@_;
 268     my @ids=();
 269     # FIXME: rework PathElements
 270     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Artist")
 271     {
 272         return $self->artist_albums($constraints[$#constraints]->{id});
 273     }
 274     my $main_sql_start=("SELECT albums.name\n" .
 275                         "\tFROM (SELECT files_id FROM tags\n" .
 276                         "\t\tINNER JOIN files_x_tags ON tags.id=files_x_tags.tags_id\n" .
 277                         "\t\tWHERE tags.id in\n\t\t\t(");
 278     my $main_sql_end=(")\n\t\t) AS subselect\n" .
 279                       "\tINNER JOIN files ON subselect.files_id=files.id\n" .
 280                       "\tINNER JOIN albums ON files.albums_id=albums.id\n" .
 281                       "\n\tGROUP BY albums.name;");
 282     while(my $constraint=shift @constraints)
 283     {
 284         my $cid=$constraint->{id};
 285         push(@ids, $cid);
 286     }
 287     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 288     my $str=join(", ", @ids);
 289     my $sql = ($main_sql_start . $str .
 290                $main_sql_end);
 291     my $result=$self->cmd_rows($sql);
 292     my @names=map { $_->[0]; } @$result;
 293     print "ALBUMS: ", join(', ', @names), "\n";
 294     return(@names);
 295 }
 296
 297 sub artist_albums
 298 {
 299     my($self, $artist_id)=@_;
 300     my $sql=("SELECT albums.name FROM files\n\t" .
 301              "INNER JOIN albums ON albums.id=files.albums_id\n\t" .
 302              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 303              "WHERE artists.id=? and albums.name <> ''\n\t" .
 304              "GROUP BY albums.name\n");
 305     print "ARTIST_ALBUMS SQL: $sql\n";
 306     my $result=$self->cmd_rows($sql, $artist_id);
 307     my @albums=map { $_->[0]; } @$result;
 308     print "ALBUMS: ", join(', ', @albums), "\n";
 309     return(@albums);
 310 }
 311
 312 sub artist_tracks
 313 {
 314     my($self, $artist_id)=@_;
 315     my $sql=("SELECT files.name FROM files\n\t" .
 316              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 317              "INNER JOIN albums  ON albums.id=files.albums_id\n\t" .
 318              "WHERE artists.id=? AND albums.name=''\n\t" .
 319              "GROUP BY files.name\n");
 320     print "ARTIST_TRACKS SQL: $sql\n";
 321     my $result=$self->cmd_rows($sql, $artist_id);
 322     my @names=map { $_->[0]; } @$result;
 323     print "ARTISTTRACKS: ", join(', ', @names), "\n";
 324     return(@names);
 325 }
 326
 327 sub album_tracks
 328 {
 329     my($self, $artist_id, $album_id)=@_;
 330     my $sql=("SELECT files.name FROM files\n\t" .
 331              "INNER JOIN albums  ON albums.id=files.albums_id\n\t" .
 332              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 333              "WHERE artists.id=? AND albums.id=?\n\t" .
 334              "GROUP BY files.name\n");
 335     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n";
 336     my $result=$self->cmd_rows($sql, $artist_id, $album_id);
 337     my @names=map { $_->[0]; } @$result;
 338     print "TRACKS: ", join(', ', @names), "\n";
 339     return(@names);
 340 }
 341
 342 sub tracks
 343 {
 344     my($self, @constraints)=@_;
 345     # FIXME: rework PathElements
 346     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Artist")
 347     {
 348         return $self->artist_tracks($constraints[$#constraints]->{id});
 349     }
 350     elsif(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Album")
 351     {
 352         my $artist_id=0;
 353         my $artist=$constraints[($#constraints)-1];
 354         if(defined($artist) && (ref($artist) eq "ID3FS::PathElement::Artist"))
 355         {
 356             # should always happen
 357             $artist_id=$artist->{id};
 358         }
 359         return $self->album_tracks($artist_id, $constraints[$#constraints]->{id});
 360     }
 361
 362     my $main_sql_start=("SELECT files.name\n" .
 363                         "\tFROM (SELECT files_id FROM tags\n" .
 364                         "\t\tINNER JOIN files_x_tags ON tags.id=files_x_tags.tags_id\n" .
 365                         "\t\tWHERE tags.id in\n\t\t\t(");
 366     my $main_sql_end=(")\n\t\t) AS subselect\n" .
 367                       "\tINNER JOIN files ON files.id=subselect.files_id" .
 368                       "\tGROUP BY files.name;");
 369     my @ids;
 370     while(my $constraint=shift @constraints)
 371     {
 372         my $cid=$constraint->{id};
 373         push(@ids, $cid);
 374     }
 375     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 376     my $str=join(", ", @ids);
 377     my $sql = ($main_sql_start . $str .
 378                $main_sql_end);
 379     print "SQL: $sql\n";
 380     my $result=$self->cmd_rows($sql);
 381     my @names=map { $_->[0]; } @$result;
 382     print "TRACKS: ", join(', ', @names), "\n";
 383     return(@names);
 384 }
 385
 386 sub filename
 387 {
 388     my($self, @constraints)=@_;
 389     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::File")
 390     {
 391         my $id=$constraints[$#constraints]->{id};
 392         my $sql=("SELECT paths.name, files.name FROM files\n" .
 393                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 394                  "WHERE files.id=?\n" .
 395                  "GROUP BY paths.name, files.name");
 396         print "FILENAME SQL: $sql\n";
 397         my ($path, $name)=$self->cmd_onerow($sql, $id);
 398         return($self->{absbase} . "/$path/$name");
 399     }
 400     die("DB::filename: unhandled case\n"); #FIXME
 401 }
 402
 403 sub bare_tags
 404 {
 405     my($self)=@_;
 406     my $sql=("SELECT tags.name FROM tags\n" .
 407              "LEFT JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n" .
 408              "WHERE tags_x_tagvals.tags_id IS NULL\n" .
 409              "GROUP BY tags.name\n");
 410     my $result=$self->cmd_rows($sql);
 411     my @names=map { $_->[0]; } @$result;
 412     return (@names);
 413 }
 414
 415 sub tags_with_values
 416 {
 417     my($self)=@_;
 418     my $sql=("SELECT tags.name, tagvals.name FROM tags\n" .
 419              "INNER JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n" .
 420              "INNER JOIN tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n" .
 421              "GROUP BY tags.name, tagvals.name\n");
 422     my $result=$self->cmd_rows($sql);
 423     my $tags={};
 424     for my $pair (@$result)
 425     {
 426         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 427     }
 428     return $tags;
 429 }
 430
 431 sub id
 432 {
 433     my($self, $type, $val)=@_;
 434     my $sql="SELECT id FROM $type WHERE name=?";
 435     my ($id)=$self->cmd_onerow($sql, $val);
 436     return($id);
 437 }
 438
 439 sub add
 440 {
 441     my($self,$path)=@_;
 442     my $relpath=$path;
 443     $relpath =~ s/^\Q$self->{base}\E\/?//;
 444     my($filepart,$pathpart);
 445     if($path !~ /\//)
 446     {
 447         $pathpart='';
 448         $filepart=$relpath;
 449     }
 450     else
 451     {
 452         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 453     }
 454     my $file=ID3FS::AudioFile->new($path, $self->{me});
 455     return unless(defined($file));
 456     my $artist=$file->artist();
 457     my $album=$file->album();
 458     my $v1genre=$file->v1genre();
 459     my $year=$file->year();
 460     my $audiotype=$file->audiotype();
 461     my $tags=$file->tags();
 462     my $haspic=$file->haspic();
 463
 464     $artist=undef unless($self->ok($artist));
 465     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 466     my $artist_id=$self->add_to_table("artists",  $artist);
 467     my $path_id=$self->add_to_table("paths", $pathpart);
 468     $album=undef unless($self->ok($album));
 469     if($self->{verbose} && !defined($album))
 470     {
 471         print "$self->{me}: $path: no album tag defined\n";
 472     }
 473
 474     my $albums_id=$self->add_to_table("albums", $album);
 475     my $file_id=$self->add_to_table("files", $filepart,
 476                                     { "artists_id" => $artist_id,
 477                                       "albums_id"  => $albums_id,
 478                                       "paths_id"   => $path_id });
 479     for my $tag (keys %$tags)
 480     {
 481         $self->add_tag($file_id, $tag, $tags->{$tag});
 482     }
 483
 484     if($self->ok($year))
 485     {
 486         $self->add_tag($file_id, "year", $year);
 487         if($year=~/^(\d\d\d)\d$/)
 488         {
 489             $self->add_tag($file_id, "decade", "${1}0s");
 490         }
 491     }
 492
 493     if($self->ok($v1genre))
 494     {
 495         $self->add_tag($file_id, "v1genre", $v1genre);
 496     }
 497
 498     if($haspic)
 499     {
 500         $self->add_tag($file_id, "haspic", undef);
 501     }
 502 }
 503
 504 sub add_tag
 505 {
 506     my($self, $file_id, $tag, $val)=@_;
 507     my $tag_id=$self->add_to_table("tags",  $tag);
 508     $self->add_relation("files_x_tags",
 509                         { "files_id" => $file_id,
 510                           "tags_id"  => $tag_id });
 511     if(defined($val))
 512     {
 513         my $val_id=$self->add_to_table("tagvals", $val);
 514         $self->add_relation("tags_x_tagvals",
 515                             { "tags_id"     => $tag_id,
 516                               "tagvals_id"  => $val_id });
 517     }
 518 }
 519
 520 sub add_to_table
 521 {
 522     my($self, $table, $name, $extradata)=@_;
 523     my $id=$self->lookup_id($table, $name);
 524     unless(defined($id))
 525     {
 526         my $sql="INSERT INTO $table (";
 527         $sql .= "id, " if($self->{postgres});
 528         my @fields=qw(name);
 529         if(defined($extradata))
 530         {
 531             push(@fields, sort keys(%$extradata));
 532         }
 533         $sql .= join(", ", @fields);
 534         $sql .=") VALUES (";
 535         $sql .=") nextval('seq'), " if($self->{postgres});
 536         $sql .= join(", ", map { "?"; } @fields);
 537         $sql .= ");";
 538         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 539     }
 540     return $id;
 541 }
 542
 543 sub add_relation
 544 {
 545     my ($self, $relname, $fields)=@_;
 546     return if($self->relation_exists($relname, $fields));
 547     my $sql="INSERT INTO $relname (";
 548     $sql .= join(", ", sort keys(%$fields));
 549     $sql .= ") VALUES (";
 550     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 551     $sql .= ");";
 552     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 553 }
 554
 555 sub lookup_id
 556 {
 557     my($self, $table, $name)=@_;
 558     my($id)=$self->cmd_onerow("SELECT id FROM $table where name=?", $name);
 559     return $id;
 560 }
 561
 562 sub tag_has_values
 563 {
 564     my($self, $id)=@_;
 565     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 566              "INNER JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n\t" .
 567              "INNER JOIN tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n\t" .
 568              "WHERE tags.id=?\n");
 569     my ($rows)=$self->cmd_onerow($sql, $id);
 570     return $rows;
 571 }
 572
 573 sub files_in
 574 {
 575     my ($self, $dir)=@_;
 576     $dir=~s/^$self->{base}\/?//;
 577     my $sql=("SELECT files.name FROM files\n" .
 578              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 579              "WHERE paths.name=?\n");
 580     my $files=$self->cmd_rows($sql, $dir);
 581     return(map { $_->[0]; } @$files);
 582 }
 583
 584 sub prune_directories
 585 {
 586     my($self)=@_;
 587     my $sql=("SELECT name, id FROM paths ORDER BY name\n");
 588     my $pathsref=$self->cmd_rows($sql);
 589     my @ids=();
 590     for my $pathpair (@$pathsref)
 591     {
 592         my($path, $id)=@$pathpair;
 593         my $fullpath="$self->{absbase}/$path";
 594         unless(-d $fullpath)
 595         {
 596             push(@ids, $id)
 597         }
 598     }
 599     $self->prune_paths(@ids);
 600     return scalar(@ids);
 601 }
 602
 603 sub prune_paths
 604 {
 605     my($self, @ids)=@_;
 606     return unless(@ids);
 607     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 608              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 609     print "SQL: \n", $sql, "\n";
 610     $self->cmd($sql);
 611 }
 612
 613 sub remove_unused
 614 {
 615     my($self)=@_;
 616     my $sql=<<'EOT';
 617    DELETE FROM artists WHERE id IN (
 618        SELECT artists.id FROM artists
 619        LEFT JOIN files ON files.artists_id=artists.id
 620        WHERE files.id IS NULL);
 621
 622    DELETE FROM albums WHERE id IN (
 623        SELECT albums.id FROM albums
 624        LEFT JOIN files ON files.albums_id=albums.id
 625        WHERE files.id IS NULL);
 626
 627    DELETE FROM paths WHERE id IN (
 628        SELECT paths.id FROM paths
 629        LEFT JOIN files ON files.paths_id=paths.id
 630        WHERE files.id IS NULL);
 631
 632    DELETE FROM files_x_tags WHERE files_id IN (
 633        SELECT files_x_tags.files_id FROM files_x_tags
 634        LEFT JOIN files ON files.id=files_x_tags.files_id
 635        WHERE files.id IS NULL);
 636
 637    DELETE FROM tags WHERE id IN (
 638        SELECT tags.id FROM tags
 639        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 640        WHERE files_x_tags.files_id IS NULL);
 641
 642    DELETE FROM tags_x_tagvals WHERE tags_id IN (
 643        SELECT tags_x_tagvals.tags_id FROM tags_x_tagvals
 644        LEFT JOIN tags ON tags.id=tags_x_tagvals.tags_id
 645        WHERE tags.id IS NULL);
 646
 647    DELETE FROM tagvals WHERE id IN (
 648        SELECT tagvals.id FROM tagvals
 649        LEFT JOIN tags_x_tagvals ON tags_x_tagvals.tagvals_id=tagvals.id
 650        WHERE tags_x_tagvals.tagvals_id IS NULL);
 651 EOT
 652     print "SQL: $sql\n";
 653     my @sql=split(/\n\n/, $sql);
 654     $self->cmd($_) for (@sql);
 655 }
 656
 657 sub relation_exists
 658 {
 659     my ($self, $relname, $fields)=@_;
 660     my $sql="SELECT count(1) FROM $relname WHERE ";
 661     my @exprs=();
 662     my @vals=();
 663     for my $field (keys %$fields)
 664     {
 665         push(@exprs,$field);
 666         push(@vals,$fields->{$field});
 667     }
 668     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 669     my ($ret)=$self->cmd_onerow($sql, @vals);
 670     return $ret;
 671 }
 672
 673 sub ok
 674 {
 675     my($self, $thing)=@_;
 676     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 677 }
 678
 679 sub cmd
 680 {
 681     my ($self, @args)=@_;
 682     # don't care about retcode
 683     $self->cmd_sth(@args);
 684 }
 685
 686 sub cmd_onerow
 687 {
 688     my ($self, @args)=@_;
 689     my $sth=$self->cmd_sth(@args);
 690     return($sth->fetchrow_array());
 691 }
 692
 693 sub cmd_rows
 694 {
 695     my ($self, @args)=@_;
 696     my $sth=$self->cmd_sth(@args);
 697     return $sth->fetchall_arrayref();
 698 }
 699
 700 sub cmd_id
 701 {
 702     my ($self, @args)=@_;
 703     $self->cmd_sth(@args);
 704     return($self->last_insert_id());
 705 }
 706
 707 sub last_insert_id
 708 {
 709     my $self=shift;
 710     if($self->{postgres})
 711     {
 712         return $self->{dbh}->last_insert_id(undef, undef, undef, undef,
 713                                             { sequence => "seq" });
 714     }
 715     else
 716     {
 717         return $self->{dbh}->last_insert_id("","","","");
 718     }
 719 }
 720
 721 __DATA__
 722
 723 CREATE TABLE id3fs (
 724     schema_version INTEGER,
 725     last_update
 726 );
 727
 728 CREATE TABLE paths (
 729     id INTEGER PRIMARY KEY,
 730     name text
 731 );
 732
 733 CREATE TABLE artists (
 734     id INTEGER PRIMARY KEY,
 735     name text
 736 );
 737
 738 CREATE TABLE albums (
 739     id INTEGER PRIMARY KEY,
 740     name text
 741 );
 742
 743 CREATE TABLE files (
 744     id INTEGER PRIMARY KEY,
 745     name text,
 746     artists_id,
 747     albums_id,
 748     paths_id,
 749     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 750     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 751     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 752 );
 753
 754 CREATE TABLE tags (
 755     id INTEGER PRIMARY KEY,
 756     name text
 757 );
 758
 759 CREATE TABLE tagvals (
 760     id INTEGER PRIMARY KEY,
 761     name text
 762 );
 763
 764 CREATE TABLE files_x_tags (
 765     files_id INTEGER,
 766     tags_id INTEGER,
 767     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 768     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 769 );
 770
 771 CREATE TABLE tags_x_tagvals (
 772     tags_id INTEGER,
 773     tagvals_id INTEGER,
 774     FOREIGN KEY(tags_id) REFERENCES tags(id) ON DELETE CASCADE ON UPDATE CASCADE,
 775     FOREIGN KEY(tagvals_id) REFERENCES tagvals(id) ON DELETE CASCADE ON UPDATE CASCADE
 776 );
 777