lib/ID3FS/DB.pm

   1 package ID3FS::DB;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use ID3FS::AudioFile;
   7 use Cwd;
   8
   9 our $SCHEMA_VERSION=1;
  10 my $dbfile=".id3fs";
  11
  12 sub new
  13 {
  14     my $proto=shift;
  15     my $class=ref($proto) || $proto;
  16     my $self={};
  17     bless($self,$class);
  18
  19     $self->{me}=shift;
  20     $self->{verbose}=shift;
  21     my $init=shift;
  22     my $dbpath=shift;
  23     $self->{base}=shift;
  24     my $fallbackdir=shift;
  25
  26     $dbpath=$self->find_db($init, $dbpath, $fallbackdir);
  27     return undef unless($dbpath);
  28     $self->{absbase}=Cwd::abs_path($self->{base});
  29
  30     my $connectstr="dbi:SQLite:dbname=$dbpath";
  31     my ($user, $pass)=("", "");
  32     if($self->{postgres})
  33     {
  34         $connectstr="dbi:Pg:dbname=id3fs";
  35         $user="ianb";
  36         $pass="foo";
  37     }
  38     my $exists=-f $dbpath;
  39     $self->{dbh}=DBI->connect($connectstr, $user, $pass,
  40                               { AutoCommit=>1 } );
  41     unless(defined($self->{dbh}))
  42     {
  43         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  44     }
  45
  46     if($exists)
  47     {
  48         $self->checkschema();
  49     }
  50     else
  51     {
  52         $self->create();
  53     }
  54     $self->enable_foreign_keys();
  55     return $self;
  56 }
  57
  58 sub find_db
  59 {
  60     my($self, $init, $dbpath, $fallbackdir)=@_;
  61     my $file=undef;
  62     my $base=undef;
  63     if(defined($dbpath))
  64     {
  65         $file=$dbpath;
  66     }
  67     if(defined ($self->{base}))
  68     {
  69         $file="$self->{base}/$dbfile" unless defined($file);
  70         $base=$self->{base};
  71     }
  72     elsif(defined($fallbackdir) && -d $fallbackdir)
  73     {
  74         my $path=Cwd::abs_path($fallbackdir);
  75         do
  76         {
  77             $file="$path/$dbfile";
  78             $base=$path;
  79             $path=~s/(.*)\/.*/$1/;
  80         }
  81         while(! -f $file && length($path) && -d $path);
  82         if(! -f $file)
  83         {
  84             $file="$fallbackdir/$dbfile";
  85             $base=$fallbackdir;
  86         }
  87     }
  88     if(!-f $file && !$init)
  89     {
  90         print "$self->{me}: db not found at $file\n";
  91         return undef;
  92     }
  93     $self->{base}=$base;
  94     return $file;
  95 }
  96
  97 sub create
  98 {
  99     my($self,$name)=@_;
 100     my @schema=split(/\n\n/,join("", <DATA>));
 101     close(DATA);
 102     for my $cmd (@schema)
 103     {
 104         $self->{dbh}->do($cmd);
 105     }
 106     if($self->{postgres})
 107     {
 108         $self->cmd("CREATE SEQUENCE seq");
 109     }
 110     else
 111     {
 112         my %indexes=( "idx_files_id"  => "files (id)",
 113                       "idx_fxt_both"  => "files_x_tags (files_id, tags_id)",
 114                       "idx_fxt_files" => "files_x_tags (files_id)",
 115                       "idx_fxt_tags"  => "files_x_tags (tags_id)",
 116                       "idx_tags_id"   => "tags (id)",
 117                       "idx_tags_name" => "tags (name)");
 118         for my $index (keys %indexes)
 119         {
 120             $self->{dbh}->do("CREATE INDEX $index ON " . $indexes{$index});
 121         }
 122     }
 123     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 124                $SCHEMA_VERSION, time());
 125 }
 126
 127 sub checkschema
 128 {
 129     my $self=shift;
 130     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 131     if(!defined($version) || $version != $SCHEMA_VERSION)
 132     {
 133         die("$self->{me}: id3fs database version " .
 134             defined($version) ? $version : '""' .
 135             "not known, current version is $SCHEMA_VERSION.\n");
 136     }
 137 }
 138
 139 sub enable_foreign_keys
 140 {
 141     my $self=shift;
 142     $self->cmd("PRAGMA foreign_keys = ON");
 143 }
 144
 145 sub last_update
 146 {
 147     my($self, $newval)=@_;
 148     if(defined($newval))
 149     {
 150         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 151     }
 152     else
 153     {
 154         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 155     }
 156     return $newval;
 157 }
 158
 159 sub cmd_sth
 160 {
 161     my($self, $sql, @params)=@_;
 162     my $sth=$self->{dbh}->prepare($sql);
 163     my $idx=1;
 164     for my $param (@params)
 165     {
 166         $param="" unless(defined($param));
 167         $sth->bind_param($idx++, $param);
 168     }
 169     $sth->execute();
 170     return $sth;
 171 }
 172
 173 sub tags
 174 {
 175     my($self, @constraints)=@_;
 176     if(!@constraints) # /
 177     {
 178         # FIXME: add ALL?
 179         my $sql="SELECT DISTINCT name FROM tags;";
 180         my $tags=$self->cmd_rows($sql);
 181         return(map { $_->[0]; } @$tags);
 182     }
 183     my @ids=();
 184
 185     my $main_sql_start=("SELECT t2.name\n" .
 186                         "\tFROM (SELECT files_id FROM tags t1\n" .
 187                         "\t\tINNER JOIN files_x_tags ON t1.id=files_x_tags.tags_id\n" .
 188                         "\t\tWHERE t1.id in\n\t\t\t(");
 189     my $main_sql_mid=(")\n\t\t) AS subselect\n" .
 190                       "\tINNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n" .
 191                       "\tINNER JOIN tags t2 ON files_x_tags.tags_id=t2.id\n" .
 192                       "\tWHERE t2.id NOT IN (");
 193     my $main_sql_end=")\n\tGROUP BY t2.name;";
 194     while(my $constraint=shift @constraints)
 195     {
 196         my $cid=$constraint->{id};
 197         push(@ids, $cid);
 198     }
 199     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 200     my $tagstr=join(", ", @ids);
 201     my $sql = ($main_sql_start . $tagstr .
 202                $main_sql_mid   . $tagstr .
 203                $main_sql_end);
 204     print "SQL: $sql\n";
 205     my $result=$self->cmd_rows($sql);
 206     my @tagnames=map { $_->[0]; } @$result;
 207     print "SUBNAMES: ", join(', ', @tagnames), "\n";
 208     return(@tagnames);
 209 }
 210
 211 sub tag_values
 212 {
 213     my($self, $tagid)=@_;
 214     my $sql=("SELECT DISTINCT tagvals.name FROM tagvals\n" .
 215              "INNER JOIN tags_x_tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n" .
 216              "WHERE tags_x_tagvals.tags_id=?");
 217     my $tags=$self->cmd_rows($sql, $tagid);
 218     my @tags=map { $_->[0]; } @$tags;
 219     @tags=map { length($_) ? $_ : "NOVALUE"; } @tags;
 220     return @tags;
 221 }
 222
 223 sub artists
 224 {
 225     my($self, @constraints)=@_;
 226     if(!@constraints) # /ALL
 227     {
 228         my $sql="SELECT DISTINCT name FROM artists;";
 229         my $tags=$self->cmd_rows($sql);
 230         return(map { $_->[0]; } @$tags);
 231     }
 232     my @ids=();
 233     my $main_sql_start=("SELECT artists.name\n" .
 234                         "\tFROM (SELECT files_id FROM tags\n" .
 235                         "\t\tINNER JOIN files_x_tags ON tags.id=files_x_tags.tags_id\n" .
 236                         "\t\tWHERE tags.id in\n\t\t\t(");
 237     my $main_sql_end=(")\n\t\t) AS subselect\n" .
 238                       "\tINNER JOIN files ON subselect.files_id=files.id\n" .
 239                       "\tINNER JOIN artists ON files.artists_id=artists.id\n" .
 240                       "\n\tGROUP BY artists.name;");
 241     while(my $constraint=shift @constraints)
 242     {
 243         my $cid=$constraint->{id};
 244         push(@ids, $cid);
 245     }
 246     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 247     my $tagstr=join(", ", @ids);
 248     my $sql = ($main_sql_start . $tagstr .
 249                $main_sql_end);
 250     print "SQL: $sql\n";
 251     my $result=$self->cmd_rows($sql);
 252     my @tagnames=map { $_->[0]; } @$result;
 253     print "ARTISTS: ", join(', ', @tagnames), "\n";
 254     return(@tagnames);
 255 }
 256
 257 sub albums
 258 {
 259     my($self, @constraints)=@_;
 260     my @ids=();
 261     # FIXME: rework PathElements
 262     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Artist")
 263     {
 264         return $self->artist_albums($constraints[$#constraints]->{id});
 265     }
 266     my $main_sql_start=("SELECT albums.name\n" .
 267                         "\tFROM (SELECT files_id FROM tags\n" .
 268                         "\t\tINNER JOIN files_x_tags ON tags.id=files_x_tags.tags_id\n" .
 269                         "\t\tWHERE tags.id in\n\t\t\t(");
 270     my $main_sql_end=(")\n\t\t) AS subselect\n" .
 271                       "\tINNER JOIN files ON subselect.files_id=files.id\n" .
 272                       "\tINNER JOIN albums ON files.albums_id=albums.id\n" .
 273                       "\n\tGROUP BY albums.name;");
 274     while(my $constraint=shift @constraints)
 275     {
 276         my $cid=$constraint->{id};
 277         push(@ids, $cid);
 278     }
 279     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 280     my $str=join(", ", @ids);
 281     my $sql = ($main_sql_start . $str .
 282                $main_sql_end);
 283     my $result=$self->cmd_rows($sql);
 284     my @names=map { $_->[0]; } @$result;
 285     print "ALBUMS: ", join(', ', @names), "\n";
 286     return(@names);
 287 }
 288
 289 sub artist_albums
 290 {
 291     my($self, $artist_id)=@_;
 292     my $sql=("SELECT albums.name FROM files\n\t" .
 293              "INNER JOIN albums ON albums.id=files.albums_id\n\t" .
 294              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 295              "WHERE artists.id=? and albums.name <> ''\n\t" .
 296              "GROUP BY albums.name\n");
 297     print "ARTIST_ALBUMS SQL: $sql\n";
 298     my $result=$self->cmd_rows($sql, $artist_id);
 299     my @albums=map { $_->[0]; } @$result;
 300     print "ALBUMS: ", join(', ', @albums), "\n";
 301     return(@albums);
 302 }
 303
 304 sub artist_tracks
 305 {
 306     my($self, $artist_id)=@_;
 307     my $sql=("SELECT files.name FROM files\n\t" .
 308              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 309              "INNER JOIN albums  ON albums.id=files.albums_id\n\t" .
 310              "WHERE artists.id=? AND albums.name=''\n\t" .
 311              "GROUP BY files.name\n");
 312     print "ARTIST_TRACKS SQL: $sql\n";
 313     my $result=$self->cmd_rows($sql, $artist_id);
 314     my @names=map { $_->[0]; } @$result;
 315     print "ARTISTTRACKS: ", join(', ', @names), "\n";
 316     return(@names);
 317 }
 318
 319 sub album_tracks
 320 {
 321     my($self, $artist_id, $album_id)=@_;
 322     my $sql=("SELECT files.name FROM files\n\t" .
 323              "INNER JOIN albums  ON albums.id=files.albums_id\n\t" .
 324              "INNER JOIN artists ON artists.id=files.artists_id\n\t" .
 325              "WHERE artists.id=? AND albums.id=?\n\t" .
 326              "GROUP BY files.name\n");
 327     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n";
 328     my $result=$self->cmd_rows($sql, $artist_id, $album_id);
 329     my @names=map { $_->[0]; } @$result;
 330     print "TRACKS: ", join(', ', @names), "\n";
 331     return(@names);
 332 }
 333
 334 sub tracks
 335 {
 336     my($self, @constraints)=@_;
 337     # FIXME: rework PathElements
 338     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Artist")
 339     {
 340         return $self->artist_tracks($constraints[$#constraints]->{id});
 341     }
 342     elsif(ref($constraints[$#constraints]) eq "ID3FS::PathElement::Album")
 343     {
 344         my $artist_id=0;
 345         my $artist=$constraints[($#constraints)-1];
 346         if(defined($artist) && (ref($artist) eq "ID3FS::PathElement::Artist"))
 347         {
 348             # should always happen
 349             $artist_id=$artist->{id};
 350         }
 351         return $self->album_tracks($artist_id, $constraints[$#constraints]->{id});
 352     }
 353
 354     my $main_sql_start=("SELECT files.name\n" .
 355                         "\tFROM (SELECT files_id FROM tags\n" .
 356                         "\t\tINNER JOIN files_x_tags ON tags.id=files_x_tags.tags_id\n" .
 357                         "\t\tWHERE tags.id in\n\t\t\t(");
 358     my $main_sql_end=(")\n\t\t) AS subselect\n" .
 359                       "\tINNER JOIN files ON files.id=subselect.files_id" .
 360                       "\tGROUP BY files.name;");
 361     my @ids;
 362     while(my $constraint=shift @constraints)
 363     {
 364         my $cid=$constraint->{id};
 365         push(@ids, $cid);
 366     }
 367     @ids = map( { "\"$_\""; } grep { defined; } @ids) unless($self->{postgres});
 368     my $str=join(", ", @ids);
 369     my $sql = ($main_sql_start . $str .
 370                $main_sql_end);
 371     print "SQL: $sql\n";
 372     my $result=$self->cmd_rows($sql);
 373     my @names=map { $_->[0]; } @$result;
 374     print "TRACKS: ", join(', ', @names), "\n";
 375     return(@names);
 376 }
 377
 378 sub filename
 379 {
 380     my($self, @constraints)=@_;
 381     if(ref($constraints[$#constraints]) eq "ID3FS::PathElement::File")
 382     {
 383         my $id=$constraints[$#constraints]->{id};
 384         my $sql=("SELECT paths.name, files.name FROM files\n" .
 385                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 386                  "WHERE files.id=?\n" .
 387                  "GROUP BY paths.name, files.name");
 388         print "FILENAME SQL: $sql\n";
 389         my ($path, $name)=$self->cmd_onerow($sql, $id);
 390         return($self->{absbase} . "/$path/$name");
 391     }
 392     die("DB::filename: unhandled case\n"); #FIXME
 393 }
 394
 395 sub bare_tags
 396 {
 397     my($self)=@_;
 398     my $sql=("SELECT tags.name FROM tags\n" .
 399              "LEFT JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n" .
 400              "WHERE tags_x_tagvals.tags_id IS NULL\n" .
 401              "GROUP BY tags.name\n");
 402     my $result=$self->cmd_rows($sql);
 403     my @names=map { $_->[0]; } @$result;
 404     return (@names);
 405 }
 406
 407 sub tags_with_values
 408 {
 409     my($self)=@_;
 410     my $sql=("SELECT tags.name, tagvals.name FROM tags\n" .
 411              "INNER JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n" .
 412              "INNER JOIN tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n" .
 413              "GROUP BY tags.name, tagvals.name\n");
 414     my $result=$self->cmd_rows($sql);
 415     my $tags={};
 416     for my $pair (@$result)
 417     {
 418         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 419     }
 420     return $tags;
 421 }
 422
 423 sub id
 424 {
 425     my($self, $type, $val)=@_;
 426     my $sql="SELECT id FROM $type WHERE name=?";
 427     my ($id)=$self->cmd_onerow($sql, $val);
 428     return($id);
 429 }
 430
 431 sub add
 432 {
 433     my($self,$path)=@_;
 434     my $relpath=$path;
 435     $relpath =~ s/^\Q$self->{base}\E\/?//;
 436     my($filepart,$pathpart);
 437     if($path !~ /\//)
 438     {
 439         $pathpart='';
 440         $filepart=$relpath;
 441     }
 442     else
 443     {
 444         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 445     }
 446     my $file=ID3FS::AudioFile->new($path);
 447     return unless(defined($file));
 448     my $artist=$file->artist();
 449     my $album=$file->album();
 450     my $v1genre=$file->v1genre();
 451     my $year=$file->year();
 452     my $audiotype=$file->audiotype();
 453     my $tags=$file->tags();
 454     my $haspic=$file->haspic();
 455
 456     $artist=undef unless($self->ok($artist));
 457     my $artist_id=$self->add_to_table("artists",  $artist);
 458     my $path_id=$self->add_to_table("paths", $pathpart);
 459     $album=undef unless($self->ok($album));
 460     my $albums_id=$self->add_to_table("albums", $album);
 461     my $file_id=$self->add_to_table("files", $filepart,
 462                                     { "artists_id" => $artist_id,
 463                                       "albums_id"  => $albums_id,
 464                                       "paths_id"   => $path_id });
 465     for my $tag (keys %$tags)
 466     {
 467         $self->add_tag($file_id, $tag, $tags->{$tag});
 468     }
 469
 470     if($self->ok($year))
 471     {
 472         $self->add_tag($file_id, "year", $year);
 473         if($year=~/^(\d\d\d)\d$/)
 474         {
 475             $self->add_tag($file_id, "decade", "${1}0s");
 476         }
 477     }
 478
 479     if($self->ok($v1genre))
 480     {
 481         $self->add_tag($file_id, "v1genre", $v1genre);
 482     }
 483
 484     if($haspic)
 485     {
 486         $self->add_tag($file_id, "haspic", undef);
 487     }
 488 }
 489
 490 sub add_tag
 491 {
 492     my($self, $file_id, $tag, $val)=@_;
 493     my $tag_id=$self->add_to_table("tags",  $tag);
 494     $self->add_relation("files_x_tags",
 495                         { "files_id" => $file_id,
 496                           "tags_id"  => $tag_id });
 497     if(defined($val))
 498     {
 499         my $val_id=$self->add_to_table("tagvals", $val);
 500         $self->add_relation("tags_x_tagvals",
 501                             { "tags_id"     => $tag_id,
 502                               "tagvals_id"  => $val_id });
 503     }
 504 }
 505
 506 sub add_to_table
 507 {
 508     my($self, $table, $name, $extradata)=@_;
 509     my $id=$self->lookup_id($table, $name);
 510     unless(defined($id))
 511     {
 512         my $sql="INSERT INTO $table (";
 513         $sql .= "id, " if($self->{postgres});
 514         my @fields=qw(name);
 515         if(defined($extradata))
 516         {
 517             push(@fields, sort keys(%$extradata));
 518         }
 519         $sql .= join(", ", @fields);
 520         $sql .=") VALUES (";
 521         $sql .=") nextval('seq'), " if($self->{postgres});
 522         $sql .= join(", ", map { "?"; } @fields);
 523         $sql .= ");";
 524         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 525     }
 526     return $id;
 527 }
 528
 529 sub add_relation
 530 {
 531     my ($self, $relname, $fields)=@_;
 532     return if($self->relation_exists($relname, $fields));
 533     my $sql="INSERT INTO $relname (";
 534     $sql .= join(", ", sort keys(%$fields));
 535     $sql .= ") VALUES (";
 536     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 537     $sql .= ");";
 538     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 539 }
 540
 541 sub lookup_id
 542 {
 543     my($self, $table, $name)=@_;
 544     my($id)=$self->cmd_onerow("SELECT id FROM $table where name=?", $name);
 545     return $id;
 546 }
 547
 548 sub tag_has_values
 549 {
 550     my($self, $id)=@_;
 551     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 552              "INNER JOIN tags_x_tagvals ON tags.id=tags_x_tagvals.tags_id\n\t" .
 553              "INNER JOIN tagvals ON tagvals.id=tags_x_tagvals.tagvals_id\n\t" .
 554              "WHERE tags.id=?\n");
 555     my ($rows)=$self->cmd_onerow($sql, $id);
 556     return $rows;
 557 }
 558
 559 sub files_in
 560 {
 561     my ($self, $dir)=@_;
 562     $dir=~s/^$self->{base}\/?//;
 563     print "Munged dir: $dir\n";
 564     my $sql=("SELECT files.name FROM files\n" .
 565              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 566              "WHERE paths.name=?\n");
 567     my $files=$self->cmd_rows($sql, $dir);
 568     return(map { $_->[0]; } @$files);
 569 }
 570
 571 sub prune_directories
 572 {
 573     my($self)=@_;
 574     my $sql=("SELECT name, id FROM paths ORDER BY name\n");
 575     my $pathsref=$self->cmd_rows($sql);
 576     my @ids=();
 577     for my $pathpair (@$pathsref)
 578     {
 579         my($path, $id)=@$pathpair;
 580         my $fullpath="$self->{absbase}/$path";
 581         print "PRUNING PATH $fullpath: ";
 582         unless(-d $fullpath)
 583         {
 584             push(@ids, $id)
 585         }
 586     }
 587     $self->prune_paths(@ids);
 588     return scalar(@ids);
 589 }
 590
 591 sub prune_paths
 592 {
 593     my($self, @ids)=@_;
 594     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 595              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 596     print "SQL: \n", $sql, "\n";
 597     $self->cmd($sql);
 598 }
 599
 600 sub remove_unused
 601 {
 602     my($self)=@_;
 603     my $sql=<<'EOT';
 604    DELETE FROM artists WHERE id IN (
 605        SELECT artists.id FROM artists
 606        LEFT JOIN files ON files.artists_id=artists.id
 607        WHERE files.id IS NULL);
 608
 609    DELETE FROM albums WHERE id IN (
 610        SELECT albums.id FROM albums
 611        LEFT JOIN files ON files.albums_id=albums.id
 612        WHERE files.id IS NULL);
 613
 614    DELETE FROM paths WHERE id IN (
 615        SELECT paths.id FROM paths
 616        LEFT JOIN files ON files.paths_id=paths.id
 617        WHERE files.id IS NULL);
 618
 619    DELETE FROM files_x_tags WHERE files_id IN (
 620        SELECT files_x_tags.files_id FROM files_x_tags
 621        LEFT JOIN files ON files.id=files_x_tags.files_id
 622        WHERE files.id IS NULL);
 623
 624    DELETE FROM tags WHERE id IN (
 625        SELECT tags.id FROM tags
 626        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 627        WHERE files_x_tags.files_id IS NULL);
 628
 629    DELETE FROM tags_x_tagvals WHERE tags_id IN (
 630        SELECT tags_x_tagvals.tags_id FROM tags_x_tagvals
 631        LEFT JOIN tags ON tags.id=tags_x_tagvals.tags_id
 632        WHERE tags.id IS NULL);
 633
 634    DELETE FROM tagvals WHERE id IN (
 635        SELECT tagvals.id FROM tagvals
 636        LEFT JOIN tags_x_tagvals ON tags_x_tagvals.tagvals_id=tagvals.id
 637        WHERE tags_x_tagvals.tagvals_id IS NULL);
 638 EOT
 639     print "SQL: $sql\n";
 640     my @sql=split(/\n\n/, $sql);
 641     $self->cmd($_) for (@sql);
 642 }
 643
 644 sub relation_exists
 645 {
 646     my ($self, $relname, $fields)=@_;
 647     my $sql="SELECT count(1) FROM $relname WHERE ";
 648     my @exprs=();
 649     my @vals=();
 650     for my $field (keys %$fields)
 651     {
 652         push(@exprs,$field);
 653         push(@vals,$fields->{$field});
 654     }
 655     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 656     my ($ret)=$self->cmd_onerow($sql, @vals);
 657     return $ret;
 658 }
 659
 660 sub ok
 661 {
 662     my($self, $thing)=@_;
 663     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 664 }
 665
 666 sub cmd
 667 {
 668     my ($self, @args)=@_;
 669     # don't care about retcode
 670     $self->cmd_sth(@args);
 671 }
 672
 673 sub cmd_onerow
 674 {
 675     my ($self, @args)=@_;
 676     my $sth=$self->cmd_sth(@args);
 677     return($sth->fetchrow_array());
 678 }
 679
 680 sub cmd_rows
 681 {
 682     my ($self, @args)=@_;
 683     my $sth=$self->cmd_sth(@args);
 684     return $sth->fetchall_arrayref();
 685 }
 686
 687 sub cmd_id
 688 {
 689     my ($self, @args)=@_;
 690     $self->cmd_sth(@args);
 691     return($self->last_insert_id());
 692 }
 693
 694 sub last_insert_id
 695 {
 696     my $self=shift;
 697     if($self->{postgres})
 698     {
 699         return $self->{dbh}->last_insert_id(undef, undef, undef, undef,
 700                                             { sequence => "seq" });
 701     }
 702     else
 703     {
 704         return $self->{dbh}->last_insert_id("","","","");
 705     }
 706 }
 707
 708 __DATA__
 709
 710 CREATE TABLE id3fs (
 711     schema_version INTEGER,
 712     last_update
 713 );
 714
 715 CREATE TABLE paths (
 716     id INTEGER PRIMARY KEY,
 717     name text
 718 );
 719
 720 CREATE TABLE artists (
 721     id INTEGER PRIMARY KEY,
 722     name text
 723 );
 724
 725 CREATE TABLE albums (
 726     id INTEGER PRIMARY KEY,
 727     name text
 728 );
 729
 730 CREATE TABLE files (
 731     id INTEGER PRIMARY KEY,
 732     name text,
 733     artists_id,
 734     albums_id,
 735     paths_id,
 736     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 737     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 738     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 739 );
 740
 741 CREATE TABLE tags (
 742     id INTEGER PRIMARY KEY,
 743     name text
 744 );
 745
 746 CREATE TABLE tagvals (
 747     id INTEGER PRIMARY KEY,
 748     name text
 749 );
 750
 751 CREATE TABLE files_x_tags (
 752     files_id INTEGER,
 753     tags_id INTEGER,
 754     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 755     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 756 );
 757
 758 CREATE TABLE tags_x_tagvals (
 759     tags_id INTEGER,
 760     tagvals_id INTEGER,
 761     FOREIGN KEY(tags_id) REFERENCES tags(id) ON DELETE CASCADE ON UPDATE CASCADE,
 762     FOREIGN KEY(tagvals_id) REFERENCES tagvals(id) ON DELETE CASCADE ON UPDATE CASCADE
 763 );
 764