lib/ID3FS/Path.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::Path;
  18
  19 use strict;
  20 use warnings;
  21 use ID3FS::Path::Node;
  22
  23 our ($STATE_INVALID, $STATE_ROOT, $STATE_TAG, $STATE_BOOLEAN,
  24      $STATE_ALBUMS, $STATE_TRACKLIST, $STATE_FILE, $STATE_ALL)=(0..7);
  25
  26 # operator precedence
  27 our %priorities=( "OR" => 0, "AND" => 1, "NOT" => 2 );
  28
  29 our $PATH_ALLTRACKS= "TRACKS";
  30 our $PATH_NOARTIST = "NOARTIST";
  31 our $PATH_NOALBUM  = "NOALBUM";
  32
  33 our $ENABLE_FILTER = 1;
  34
  35 sub new
  36 {
  37     my $proto=shift;
  38     my $class=ref($proto) || $proto;
  39     my $self={};
  40     bless($self,$class);
  41
  42     $self->{elements}=[];
  43     $self->{db}=shift;
  44     $self->{path}=shift;
  45     $self->{verbose}=shift;
  46     $self->{maxtagdepth}=shift;
  47     $self->{curtagdepth}=0;
  48     $self->{path} =~ s/\/\//\//g; # drop doubled slashes
  49
  50     $self->parse();
  51 #    print "STATE: ", $self->state(), "\n";
  52     return $self;
  53 }
  54
  55 sub isdir
  56 {
  57     my($self)=@_;
  58     if(($self->state() == $STATE_FILE) ||
  59        ($self->state() == $STATE_INVALID))
  60     {
  61         return 0;
  62     }
  63     return 1;
  64 }
  65
  66 sub isfile
  67 {
  68     my($self)=@_;
  69     return($self->state() == $STATE_FILE);
  70 }
  71
  72 sub isvalid
  73 {
  74     my($self)=@_;
  75     return($self->state() != $STATE_INVALID);
  76 }
  77
  78 sub dest
  79 {
  80     my($self, $mountpoint)=@_;
  81     if($self->state() == $STATE_FILE)
  82     {
  83         return $self->filename($mountpoint);
  84     }
  85     return "ERROR"; #should never happen?
  86 }
  87
  88 sub dirents
  89 {
  90     my($self)=@_;
  91     my @dents=();
  92     my @fents=();
  93     my $state=$self->state();
  94 #    print "DIRENTS: STATE: $state\n";
  95 #    print "DIRENTS: FILE: $self->{path}\n";
  96     if($state==$STATE_ALL)
  97     {
  98         @dents=($self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
  99     }
 100     elsif($state==$STATE_TAG)
 101     {
 102         my $tail=$self->tail();
 103         if($self->is($TYPE_TAG, $tail) && $self->{db}->tag_has_values($tail->id()))
 104         {
 105             @dents=$self->tags();
 106         }
 107         else
 108         {
 109             if($self->{maxtagdepth} && ($self->{curtagdepth} < $self->{maxtagdepth}))
 110             {
 111                 @dents=qw(AND OR);
 112             }
 113             push(@dents, $self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
 114         }
 115     }
 116     elsif($state==$STATE_BOOLEAN)
 117     {
 118         my $parent=$self->tail();
 119         unless($self->is($TYPE_BOOL, $parent) && $parent->{name} eq "NOT")
 120         {
 121             @dents=("NOT");
 122         }
 123         push(@dents,$self->tags());
 124     }
 125     elsif($state==$STATE_ROOT)
 126     {
 127         @dents=(qw(ALL NOT), $self->tags());
 128     }
 129     elsif($state==$STATE_ALBUMS)
 130     {
 131         @dents=$self->filter($PATH_ALLTRACKS, $PATH_NOALBUM, $self->albums());
 132     }
 133     elsif($state==$STATE_TRACKLIST)
 134     {
 135         @fents=$self->tracks();
 136     }
 137     else
 138     {
 139         print "id3fsd: INTERNAL ERROR: DIRENTS: UNHANDLED STATE: $state\n";
 140     }
 141     return(\@dents, \@fents);
 142 }
 143
 144 # State Machine Of Doom
 145 sub parse
 146 {
 147     my($self)=@_;
 148     $self->state($STATE_ROOT);
 149     return if($self->{path} eq "/");
 150     @{$self->{components}}=split(/\//, $self->{path});
 151     shift @{$self->{components}}; # drop empty field before leading /
 152 #    print "PATH: $self->{path}\n";
 153     my @parts=@{$self->{components}};
 154     my($tag, $tagval);
 155     $self->{elements}=[];
 156     $self->{in_all}=0;
 157     my $root_not=0;
 158     my $tags_seen=0;
 159     while(defined(my $name=shift @parts))
 160     {
 161 #       print "NAME: $name\n";
 162         my $state=$self->state();
 163         if($state==$STATE_INVALID)
 164         {
 165 #           print "SM: INVALID: $name\n";
 166             return;
 167         }
 168         elsif($state==$STATE_ROOT)
 169         {
 170 #           print "SM: ROOT: $name\n";
 171             if($name eq "ALL")
 172             {
 173                 $self->{in_all}=1;
 174                 $self->state($STATE_ALL);
 175             }
 176             elsif($name eq "NOT")
 177             {
 178                 $root_not=1;
 179                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 180                 $self->state($STATE_BOOLEAN);
 181             }
 182             else
 183             {
 184                 $tag=ID3FS::Path::Node->new($self->{db}, $TYPE_TAG, $name);
 185                 if($tag)
 186                 {
 187                     push(@{$self->{elements}}, $tag);
 188                     $tags_seen++;
 189                     $self->state($STATE_TAG);
 190                 }
 191                 else
 192                 {
 193                     $self->state($STATE_INVALID);
 194                 }
 195             }
 196         }
 197         elsif($state==$STATE_TAG)
 198         {
 199             my $tag=$self->tail();
 200 #           print "SM: TAG/TAGVAL($state): $name\n";
 201             if($self->is($TYPE_TAG, $tag) && $self->{db}->tag_has_values($tag->id()))
 202             {
 203 #               print "Parsing: parent: $tag->id()\n";
 204                 my $tagval=ID3FS::Path::Node->new($self->{db}, $TYPE_TAG, $name, $tag->id());
 205                 if(defined($tagval))
 206                 {
 207                     # stay in tag state
 208                     push(@{$self->{elements}}, $tagval);
 209                 }
 210                 else
 211                 {
 212                     $self->state($STATE_INVALID);
 213                 }
 214             }
 215             elsif($name eq $PATH_ALLTRACKS)
 216             {
 217                 $self->state($STATE_TRACKLIST);
 218             }
 219             elsif($name eq $PATH_NOARTIST)
 220             {
 221                 $self->state($STATE_TRACKLIST);
 222             }
 223             elsif($name eq "AND")
 224             {
 225                 $self->state($STATE_BOOLEAN);
 226                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 227             }
 228             elsif($name eq "OR")
 229             {
 230                 $self->state($STATE_BOOLEAN);
 231                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 232             }
 233             else
 234             {
 235                 my $artist=ID3FS::Path::Node->new($self->{db}, $TYPE_ARTIST, $name);
 236                 if($artist)
 237                 {
 238                     push(@{$self->{elements}}, $artist);
 239                     $self->state($STATE_ALBUMS);
 240                 }
 241                 else
 242                 {
 243                     $self->state($STATE_INVALID);
 244                 }
 245             }
 246         }
 247         elsif($state==$STATE_BOOLEAN)
 248         {
 249 #           print "SM: BOOLEAN: $name\n";
 250             my $parent=$self->tail();
 251             my $allownot=1;
 252             if($self->is($TYPE_BOOL, $parent) &&
 253                $parent->{name} eq "NOT")
 254             {
 255                 $allownot=0;
 256             }
 257             if($allownot && $name eq "NOT")
 258             {
 259                 $self->state($STATE_BOOLEAN);
 260                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 261             }
 262             else
 263             {
 264                 my $tag=ID3FS::Path::Node->new($self->{db}, $TYPE_TAG, $name);
 265                 if($tag)
 266                 {
 267                     push(@{$self->{elements}}, $tag);
 268                     $tags_seen++;
 269                     $self->state($STATE_TAG);
 270                 }
 271                 else
 272                 {
 273                     $self->state($STATE_INVALID);
 274                 }
 275             }
 276         }
 277         elsif($state==$STATE_ALBUMS)
 278         {
 279 #           print "SM: ALBUM: $name\n";
 280             if($name eq $PATH_ALLTRACKS)
 281             {
 282                 $self->state($STATE_TRACKLIST);
 283             }
 284             elsif($name eq $PATH_NOALBUM)
 285             {
 286                 $self->state($STATE_TRACKLIST);
 287             }
 288             else
 289             {
 290                 my $album=ID3FS::Path::Node->new($self->{db}, $TYPE_ALBUM, $name);
 291                 if($album)
 292                 {
 293                     push(@{$self->{elements}}, $album);
 294                     $self->state($STATE_TRACKLIST);
 295                 }
 296                 else
 297                 {
 298                     $self->state($STATE_INVALID);
 299                 }
 300             }
 301         }
 302         elsif($state==$STATE_TRACKLIST)
 303         {
 304 #           print "SM: TRACKLIST: $name\n";
 305             my $track=ID3FS::Path::Node->new($self->{db}, $TYPE_FILE, $name);
 306             if($track)
 307             {
 308                 push(@{$self->{elements}}, $track);
 309                 $self->state($STATE_FILE);
 310             }
 311             else
 312             {
 313                 $self->state($STATE_INVALID);
 314             }
 315         }
 316         elsif($state==$STATE_FILE)
 317         {
 318 #           print "SM: FILE: $name\n";
 319             # Can't have anything after a filename
 320             $self->state($STATE_INVALID);
 321         }
 322         elsif($state==$STATE_ALL)
 323         {
 324             if($name eq $PATH_ALLTRACKS)
 325             {
 326                 $self->state($STATE_TRACKLIST);
 327             }
 328             elsif($name eq $PATH_NOARTIST)
 329             {
 330                 $self->state($STATE_TRACKLIST);
 331             }
 332             else
 333             {
 334                 my $artist=ID3FS::Path::Node->new($self->{db}, $TYPE_ARTIST, $name);
 335                 if($artist)
 336                 {
 337                     push(@{$self->{elements}}, $artist);
 338                     $self->state($STATE_ALBUMS);
 339                 }
 340                 else
 341                 {
 342                     $self->state($STATE_INVALID);
 343                 }
 344             }
 345         }
 346         else
 347         {
 348             print "SM: ERROR: UNKNOWN STATE: $self->{state}\n";
 349             $self->state($STATE_INVALID);
 350         }
 351     }
 352
 353     my @elements=@{$self->{elements}};
 354     # remove trailing boolean
 355     while(@elements && $self->is($TYPE_BOOL, $elements[$#elements]))
 356     {
 357         pop @elements;
 358     }
 359     # sort elements by precedence
 360     @elements=$self->sort_elements(@elements);
 361     $self->{tagtree}=$self->elements_to_tree(\@elements);
 362 }
 363
 364 sub state
 365 {
 366     my($self, $newstate)=@_;
 367     if(defined($newstate))
 368     {
 369         $self->{state}=$newstate;
 370         $self->{curtagdepth}++ if($newstate == $STATE_TAG);
 371     }
 372     return $self->{state};
 373 }
 374
 375 # link up precedence-sorted list into a binary tree
 376 sub elements_to_tree
 377 {
 378     my($self, $elements)=@_;
 379     return undef unless(@$elements);
 380     my ($left, $right, $op)=(undef, undef, undef);
 381     my $thing=pop @$elements;
 382     if($self->is($TYPE_BOOL, $thing))
 383     {
 384         $right=$self->elements_to_tree($elements);
 385         if($thing->{name} ne "NOT")
 386         {
 387             $left=$self->elements_to_tree($elements);
 388         }
 389         $thing->left($left);
 390         $thing->right($right);
 391     }
 392     return $thing;
 393 }
 394
 395 # Dijkstra's shunting-yard algorithm
 396 sub sort_elements
 397 {
 398     my ($self, @input)=@_;
 399     my @opstack=();
 400     my @output=();
 401     while(my $thing = shift @input)
 402     {
 403         if($self->is($TYPE_TAG, $thing))
 404         {
 405             # Handle tag values by dropping parent
 406             if(@input && $self->is($TYPE_TAG, $input[0]))
 407             {
 408                 $thing=shift @input;
 409             }
 410             push(@output, $thing);
 411         }
 412         elsif($self->is($TYPE_BOOL, $thing))
 413         {
 414             while(@opstack &&
 415                   ($priorities{$thing->{name}} <= $priorities{$opstack[$#opstack]->{name}}))
 416             {
 417                 push(@output, pop(@opstack));
 418             }
 419             push(@opstack, $thing);
 420         }
 421     }
 422     while(@opstack)
 423     {
 424         push(@output, pop(@opstack));
 425     }
 426     return @output;
 427 }
 428
 429 sub used_tags
 430 {
 431     my($self)=@_;
 432     return() unless(defined($self->{tagtree}));
 433     return($self->{tagtree}->used_tags());
 434 }
 435
 436 sub expecting_values
 437 {
 438     my($self)=@_;
 439     my $tail=$self->tail();
 440     if($self->is($TYPE_TAG, $tail))
 441     {
 442         return($self->{db}->tag_has_values($tail->id()));
 443     }
 444 }
 445
 446 sub trailing_tag_id
 447 {
 448     my($self)=@_;
 449     my $tail=$self->tail();
 450     if($self->is($TYPE_TAG, $tail))
 451     {
 452         return($tail->id());
 453     }
 454     return undef;
 455 }
 456
 457 sub trailing_tag_parent
 458 {
 459     my($self)=@_;
 460     my $tail=$self->tail();
 461     if($self->is($TYPE_TAG, $tail))
 462     {
 463         return($tail->{parents_id});
 464     }
 465     return undef;
 466 }
 467
 468 sub tail
 469 {
 470     my($self)=@_;
 471     return($self->{elements}->[$#{$self->{elements}}]);
 472 }
 473
 474 sub is
 475 {
 476     my($self, $type, $thing)=@_;
 477     return 0 unless($thing);
 478     return 0 unless($thing->type());
 479     return 1 if($type == $thing->type());
 480     return 0;
 481 }
 482
 483 # the one before last
 484 sub tail_parent
 485 {
 486     my($self)=@_;
 487     return($self->{elements}->[($#{$self->{elements}}) - 1]);
 488 }
 489
 490 ######################################################################
 491
 492 sub tags
 493 {
 494     my($self)=@_;
 495     if(!$self->{tagtree}) # / or /NOT
 496     {
 497         my $sql="SELECT DISTINCT name FROM tags WHERE parents_id='';";
 498         return($self->{db}->cmd_firstcol($sql));
 499     }
 500     my $hasvals=$self->expecting_values();
 501     my $sql="SELECT tags.name FROM ";
 502     if($self->want_all_tags())
 503     {
 504         $sql .= "files_x_tags\n";
 505     }
 506     else
 507     {
 508         $sql .= ("(\n" .
 509                  $self->tags_subselect() .
 510                  ") AS subselect\n" .
 511                  "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n");
 512     }
 513     $sql .= "INNER JOIN tags ON files_x_tags.tags_id=tags.id\n";
 514     my @andclauses=();
 515     my $id=$self->trailing_tag_id();
 516
 517     my $parentclause= "tags.parents_id='";
 518     $parentclause .= $id if($hasvals);
 519     $parentclause .= "'";
 520     push(@andclauses, $parentclause);
 521
 522     my @used=$self->used_tags();
 523     if(@used)
 524     {
 525         push(@andclauses, "tags.id NOT IN (" . join(', ', @used) . ")");
 526     }
 527     if(@andclauses)
 528     {
 529         $sql .= "WHERE " . join(' AND ', @andclauses) . "\n";
 530     }
 531
 532     $sql .= "GROUP BY tags.name;";
 533     print "SQL(TAGS): $sql\n" if($self->{verbose});
 534     my @tagnames=$self->{db}->cmd_firstcol($sql);
 535     print("SUBNAMES: ", join(', ', @tagnames), "\n") if($self->{verbose});
 536     return(@tagnames);
 537 }
 538
 539 sub artists
 540 {
 541     my($self)=@_;
 542     if(!@{$self->{elements}}) # /ALL
 543     {
 544         my $sql="SELECT DISTINCT name FROM artists WHERE name!='';";
 545         return($self->{db}->cmd_firstcol($sql));
 546     }
 547     my $sql=$self->sql_start("artists.name");
 548     $sql .= ("INNER JOIN artists ON files.artists_id=artists.id\n" .
 549              "WHERE artists.name != ''\n" .
 550              "GROUP BY artists.name;");
 551     print "SQL(ARTISTS): $sql\n" if($self->{verbose});
 552     my @tagnames=$self->{db}->cmd_firstcol($sql);
 553     print("ARTISTS: ", join(', ', @tagnames), "\n") if($self->{verbose});
 554     return(@tagnames);
 555 }
 556
 557 sub albums
 558 {
 559     my($self)=@_;
 560     my $tail=$self->tail();
 561     if($self->is($TYPE_ARTIST, $tail))
 562     {
 563         return $self->artist_albums($tail->id());
 564     }
 565     my $sql=$self->sql_start("albums.name");
 566     $sql .= ("INNER JOIN albums ON files.albums_id=albums.id\n" .
 567              "WHERE albums.name != ''\n" .
 568              "GROUP BY albums.name;");
 569     print "SQL(ALBUMS): \n$sql\n" if($self->{verbose});
 570     my @names=$self->{db}->cmd_firstcol($sql);
 571     print("ALBUMS: ", join(', ', @names), "\n") if($self->{verbose});
 572     return(@names);
 573 }
 574
 575 sub artist_albums
 576 {
 577     my($self, $artist_id)=@_;
 578     my $sql=$self->sql_start("albums.name");
 579     $sql .= ("INNER JOIN albums ON albums.id=files.albums_id\n" .
 580              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 581              "WHERE artists.id=? and albums.name <> ''\n" .
 582              "GROUP BY albums.name\n");
 583     print "ARTIST_ALBUMS SQL: $sql\n" if($self->{verbose});
 584     my @albums=$self->{db}->cmd_firstcol($sql, $artist_id);
 585     print("ALBUMS: ", join(', ', @albums), "\n") if($self->{verbose});
 586     return(@albums);
 587 }
 588
 589 sub artist_tracks
 590 {
 591     my($self, $artist_id)=@_;
 592     my $sql=$self->sql_start("files.name");
 593     $sql .= ("INNER JOIN artists ON artists.id=files.artists_id\n" .
 594              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 595              "WHERE artists.id=? AND albums.name=''\n" .
 596              "GROUP BY files.name\n");
 597     print "ARTIST_TRACKS SQL: $sql\n" if($self->{verbose});
 598     my @names=$self->{db}->cmd_firstcol($sql, $artist_id);
 599     print("ARTISTTRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 600     return(@names);
 601 }
 602
 603 sub album_tracks
 604 {
 605     my($self, $artist_id, $album_id)=@_;
 606     my $sql=("SELECT files.name FROM files\n" .
 607              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 608              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 609              "WHERE artists.id=? AND albums.id=?\n" .
 610              "GROUP BY files.name\n");
 611     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n" if($self->{verbose});
 612     my @names=$self->{db}->cmd_firstcol($sql, $artist_id, $album_id);
 613     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 614     return(@names);
 615 }
 616
 617 sub tracks
 618 {
 619     my($self)=@_;
 620     my $tail=$self->tail();
 621     if($self->is($TYPE_ARTIST, $tail))
 622     {
 623         return $self->artist_tracks($tail->id());
 624     }
 625     elsif($self->is($TYPE_ALBUM, $tail))
 626     {
 627         my $artist_id=0;
 628         my $artist=$self->tail_parent();
 629         if($self->is($TYPE_ARTIST, $artist))
 630         {
 631             # should always happen
 632             $artist_id=$artist->id();
 633         }
 634         return $self->album_tracks($artist_id, $tail->id());
 635     }
 636     my $sql=$self->sql_start("files.name");
 637     $sql .= "INNER JOIN artists ON files.artists_id=artists.id\n";
 638     if($self->{components}->[$#{$self->{components}}] eq $PATH_NOARTIST)
 639     {
 640         $sql .= "WHERE artists.name =''\n";
 641     }
 642     $sql .= "GROUP BY files.name;";
 643     print "TRACKS SQL($self->{path}): $sql\n" if($self->{verbose});
 644     my @names=$self->{db}->cmd_firstcol($sql);
 645     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 646     return(@names);
 647 }
 648
 649 sub filename
 650 {
 651     my($self, $mountpoint)=@_;
 652     my $tail=$self->tail();
 653     if($self->is($TYPE_FILE, $tail))
 654     {
 655         my $id=$tail->id();
 656         my $sql=("SELECT paths.name, files.name FROM files\n" .
 657                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 658                  "WHERE files.id=?\n" .
 659                  "GROUP BY paths.name, files.name");
 660         print "FILENAME SQL: $sql\n" if($self->{verbose});
 661         my ($path, $name)=$self->{db}->cmd_onerow($sql, $id);
 662         return($self->{db}->relativise($path, $name, $mountpoint, $self->{path}));
 663     }
 664     # should never happen
 665     return "ERROR";
 666 }
 667
 668 sub tags_subselect
 669 {
 670     my($self)=@_;
 671     my $hasvals=$self->expecting_values();
 672     my $tree=$self->{tagtree};
 673     use Data::Dumper;
 674     print Dumper $tree;
 675     my ($sqlclause, @joins)=$tree->to_sql($hasvals) if($tree);
 676     my $sql="\tSELECT fxt1.files_id FROM tags t1";
 677     my @crosses=();
 678     my @inners=();
 679     for(my $i=0; $i <= $#joins; $i++)
 680     {
 681         my $cnt=$i+1;
 682         my $join=$joins[$i];
 683         my $inner=("\t$join JOIN files_x_tags fxt$cnt ON " .
 684                    "t${cnt}.id=fxt${cnt}.tags_id");
 685         if($i > 0)
 686         {
 687             push(@crosses, "CROSS JOIN tags t$cnt");
 688             $inner .= " AND fxt1.files_id=fxt${cnt}.files_id";
 689         }
 690         push(@inners, $inner);
 691     }
 692     $sql .= ("\n\t" . join(" ", @crosses)) if(@crosses);
 693     $sql .= ("\n" . join("\n", @inners)) if(@inners);
 694     $sql .= "\n\tWHERE $sqlclause" if($sqlclause);
 695     $sql .= "\n\tGROUP BY fxt1.files_id\n";
 696     return $sql;
 697 }
 698
 699 sub sql_start
 700 {
 701     my($self, $tables)=@_;
 702     my $sql="SELECT $tables FROM ";
 703     if($self->{in_all})
 704     {
 705         $sql .= "files\n";
 706     }
 707     else
 708     {
 709         $sql .= ("(\n" .
 710                  $self->tags_subselect() .
 711                  ") AS subselect\n" .
 712                  "INNER JOIN files ON subselect.files_id=files.id\n");
 713     }
 714     return $sql;
 715 }
 716
 717 # we just filter $ALLTRACKS, $NOARTIST and $NOALBUM
 718 # filtering tags properly requires up to four levels of recursion
 719 # (tag/tagval/AND/NOT) and is too slow
 720 sub filter
 721 {
 722     my($self, @dirs)=@_;
 723     return(@dirs) unless($ENABLE_FILTER);
 724     my $base=$self->{path};
 725     my @outdirs=();
 726     for my $dir (@dirs)
 727     {
 728         push(@outdirs, $dir) unless($self->empty("$base/$dir"));
 729     }
 730     return(@outdirs);
 731 }
 732
 733 sub empty
 734 {
 735     my($self, $dir)=@_;
 736     my $path=ID3FS::Path->new($self->{db}, $dir, $self->{verbose},
 737                               ($self->{maxtagdepth} - $self->{curtagdepth}));
 738     return 1 unless($path->isvalid());
 739     my($subdirs,$subfiles)=$path->dirents();
 740     return 0 if(@$subfiles || @$subdirs);
 741     return 1;
 742 }
 743
 744 # if path is .../OR/ or .../OR/NOT or .../AND/NOT
 745 sub want_all_tags
 746 {
 747     my($self)=@_;
 748     my $tail=$self->tail();
 749     return 0 unless($tail);
 750     my $parent=$self->tail_parent();
 751     my $parent_valid = ($parent && $parent->type() == $TYPE_BOOL);
 752     if($tail->type() == $TYPE_BOOL)
 753     {
 754         return 1 if($tail->name() eq "OR");
 755         return 0 unless($tail->name() eq "NOT");
 756         return 0 unless($parent_valid);
 757         return 1 if($parent->name() eq "OR");
 758         return 1 if($parent->name() eq "AND");
 759     }
 760     elsif($tail->type() == $TYPE_TAG)
 761     {
 762         return 0 unless($parent_valid);
 763         return 1 if($parent->name() eq "NOT");
 764     }
 765     return 0;
 766 }
 767
 768 1;