lib/ID3FS/Path.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::Path;
  18
  19 use strict;
  20 use warnings;
  21 use ID3FS::Path::Node;
  22
  23 our ($STATE_INVALID, $STATE_ROOT, $STATE_TAG, $STATE_BOOLEAN,
  24      $STATE_ALBUMS, $STATE_TRACKLIST, $STATE_FILE, $STATE_ALL)=(0..7);
  25
  26 # operator precedence
  27 our %priorities=( "OR" => 0, "AND" => 1, "NOT" => 2 );
  28
  29 our $PATH_ALLTRACKS= "TRACKS";
  30 our $PATH_NOARTIST = "NOARTIST";
  31 our $PATH_NOALBUM  = "NOALBUM";
  32
  33 our $ENABLE_FILTER = 0;
  34
  35 sub new
  36 {
  37     my $proto=shift;
  38     my $class=ref($proto) || $proto;
  39     my $self={};
  40     bless($self,$class);
  41
  42     $self->{elements}=[];
  43     $self->{db}=shift;
  44     $self->{path}=shift;
  45     $self->{verbose}=shift;
  46     $self->{maxtagdepth}=shift;
  47     $self->{curtagdepth}=0;
  48     $self->{path} =~ s/\/\//\//g; # drop doubled slashes
  49
  50     $self->parse();
  51 #    print "STATE: ", $self->state(), "\n";
  52     return $self;
  53 }
  54
  55 sub isdir
  56 {
  57     my($self)=@_;
  58     if(($self->state() == $STATE_FILE) ||
  59        ($self->state() == $STATE_INVALID))
  60     {
  61         return 0;
  62     }
  63     return 1;
  64 }
  65
  66 sub isfile
  67 {
  68     my($self)=@_;
  69     return($self->state() == $STATE_FILE);
  70 }
  71
  72 sub isvalid
  73 {
  74     my($self)=@_;
  75     return($self->state() != $STATE_INVALID);
  76 }
  77
  78 sub dest
  79 {
  80     my($self, $mountpoint)=@_;
  81     if($self->state() == $STATE_FILE)
  82     {
  83         return $self->filename($mountpoint);
  84     }
  85     return "ERROR"; #should never happen?
  86 }
  87
  88 sub dirents
  89 {
  90     my($self)=@_;
  91     my @dents=();
  92     my @fents=();
  93     my $state=$self->state();
  94 #    print "DIRENTS: STATE: $state\n";
  95 #    print "DIRENTS: FILE: $self->{path}\n";
  96     if($state==$STATE_ALL)
  97     {
  98         @dents=($self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
  99     }
 100     elsif($state==$STATE_TAG)
 101     {
 102         my $tail=$self->tail();
 103         if($self->is($TYPE_TAG, $tail) && $self->{db}->tag_has_values($tail->id()))
 104         {
 105             @dents=$self->tags();
 106         }
 107         else
 108         {
 109             if($self->{maxtagdepth} && ($self->{curtagdepth} < $self->{maxtagdepth}))
 110             {
 111                 @dents=qw(AND OR);
 112             }
 113             push(@dents, $self->filter($PATH_ALLTRACKS, $PATH_NOARTIST), $self->artists());
 114         }
 115     }
 116     elsif($state==$STATE_BOOLEAN)
 117     {
 118         my $parent=$self->tail();
 119         unless($self->is($TYPE_BOOL, $parent) && $parent->{name} eq "NOT")
 120         {
 121             @dents=("NOT");
 122         }
 123         push(@dents,$self->tags());
 124     }
 125     elsif($state==$STATE_ROOT)
 126     {
 127         @dents=(qw(ALL NOT), $self->tags());
 128     }
 129     elsif($state==$STATE_ALBUMS)
 130     {
 131         @dents=$self->filter($PATH_ALLTRACKS, $PATH_NOALBUM, $self->albums());
 132     }
 133     elsif($state==$STATE_TRACKLIST)
 134     {
 135         @fents=$self->tracks();
 136     }
 137     else
 138     {
 139         print "id3fsd: INTERNAL ERROR: DIRENTS: UNHANDLED STATE: $state\n";
 140     }
 141     return(\@dents, \@fents);
 142 }
 143
 144 # State Machine Of Doom
 145 sub parse
 146 {
 147     my($self)=@_;
 148     $self->state($STATE_ROOT);
 149     return if($self->{path} eq "/");
 150     @{$self->{components}}=split(/\//, $self->{path});
 151     shift @{$self->{components}}; # drop empty field before leading /
 152 #    print "PATH: $self->{path}\n";
 153     my @parts=@{$self->{components}};
 154     my($tag, $tagval);
 155     $self->{elements}=[];
 156     $self->{in_all}=0;
 157     my $root_not=0;
 158     my $tags_seen=0;
 159     while(defined(my $name=shift @parts))
 160     {
 161 #       print "NAME: $name\n";
 162         my $state=$self->state();
 163         if($state==$STATE_INVALID)
 164         {
 165 #           print "SM: INVALID: $name\n";
 166             return;
 167         }
 168         elsif($state==$STATE_ROOT)
 169         {
 170 #           print "SM: ROOT: $name\n";
 171             if($name eq "ALL")
 172             {
 173                 $self->{in_all}=1;
 174                 $self->state($STATE_ALL);
 175             }
 176             elsif($name eq "NOT")
 177             {
 178                 $root_not=1;
 179                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 180                 $self->state($STATE_BOOLEAN);
 181             }
 182             else
 183             {
 184                 $tag=ID3FS::Path::Node->new($self->{db}, $TYPE_TAG, $name);
 185                 if($tag)
 186                 {
 187                     push(@{$self->{elements}}, $tag);
 188                     $tags_seen++;
 189                     $self->state($STATE_TAG);
 190                 }
 191                 else
 192                 {
 193                     $self->state($STATE_INVALID);
 194                 }
 195             }
 196         }
 197         elsif($state==$STATE_TAG)
 198         {
 199             my $tag=$self->tail();
 200 #           print "SM: TAG/TAGVAL($state): $name\n";
 201             if($self->is($TYPE_TAG, $tag) && $self->{db}->tag_has_values($tag->id()))
 202             {
 203 #               print "Parsing: parent: $tag->id()\n";
 204                 my $tagval=ID3FS::Path::Node->new($self->{db}, $TYPE_TAG, $name, $tag->id());
 205                 if(defined($tagval))
 206                 {
 207                     # stay in tag state
 208                     push(@{$self->{elements}}, $tagval);
 209                 }
 210                 else
 211                 {
 212                     $self->state($STATE_INVALID);
 213                 }
 214             }
 215             elsif($name eq $PATH_ALLTRACKS)
 216             {
 217                 $self->state($STATE_TRACKLIST);
 218             }
 219             elsif($name eq $PATH_NOARTIST)
 220             {
 221                 $self->state($STATE_TRACKLIST);
 222             }
 223             elsif($name eq "AND")
 224             {
 225                 $self->state($STATE_BOOLEAN);
 226                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 227             }
 228             elsif($name eq "OR")
 229             {
 230                 $self->state($STATE_BOOLEAN);
 231                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 232             }
 233             else
 234             {
 235                 my $artist=ID3FS::Path::Node->new($self->{db}, $TYPE_ARTIST, $name);
 236                 if($artist)
 237                 {
 238                     push(@{$self->{elements}}, $artist);
 239                     $self->state($STATE_ALBUMS);
 240                 }
 241                 else
 242                 {
 243                     $self->state($STATE_INVALID);
 244                 }
 245             }
 246         }
 247         elsif($state==$STATE_BOOLEAN)
 248         {
 249 #           print "SM: BOOLEAN: $name\n";
 250             my $parent=$self->tail();
 251             my $allownot=1;
 252             if($self->is($TYPE_BOOL, $parent) &&
 253                $parent->{name} eq "NOT")
 254             {
 255                 $allownot=0;
 256             }
 257             if($allownot && $name eq "NOT")
 258             {
 259                 $self->state($STATE_BOOLEAN);
 260                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, $TYPE_BOOL, $name));
 261             }
 262             else
 263             {
 264                 my $tag=ID3FS::Path::Node->new($self->{db}, $TYPE_TAG, $name);
 265                 if($tag)
 266                 {
 267                     push(@{$self->{elements}}, $tag);
 268                     $tags_seen++;
 269                     $self->state($STATE_TAG);
 270                 }
 271                 else
 272                 {
 273                     $self->state($STATE_INVALID);
 274                 }
 275             }
 276         }
 277         elsif($state==$STATE_ALBUMS)
 278         {
 279 #           print "SM: ALBUM: $name\n";
 280             if($name eq $PATH_ALLTRACKS)
 281             {
 282                 $self->state($STATE_TRACKLIST);
 283             }
 284             elsif($name eq $PATH_NOALBUM)
 285             {
 286                 $self->state($STATE_TRACKLIST);
 287             }
 288             else
 289             {
 290                 my $album=ID3FS::Path::Node->new($self->{db}, $TYPE_ALBUM, $name);
 291                 if($album)
 292                 {
 293                     push(@{$self->{elements}}, $album);
 294                     $self->state($STATE_TRACKLIST);
 295                 }
 296                 else
 297                 {
 298                     $self->state($STATE_INVALID);
 299                 }
 300             }
 301         }
 302         elsif($state==$STATE_TRACKLIST)
 303         {
 304 #           print "SM: TRACKLIST: $name\n";
 305             my $track=ID3FS::Path::Node->new($self->{db}, $TYPE_FILE, $name);
 306             if($track)
 307             {
 308                 push(@{$self->{elements}}, $track);
 309                 $self->state($STATE_FILE);
 310             }
 311             else
 312             {
 313                 $self->state($STATE_INVALID);
 314             }
 315         }
 316         elsif($state==$STATE_FILE)
 317         {
 318 #           print "SM: FILE: $name\n";
 319             # Can't have anything after a filename
 320             $self->state($STATE_INVALID);
 321         }
 322         elsif($state==$STATE_ALL)
 323         {
 324             if($name eq $PATH_ALLTRACKS)
 325             {
 326                 $self->state($STATE_TRACKLIST);
 327             }
 328             elsif($name eq $PATH_NOARTIST)
 329             {
 330                 $self->state($STATE_TRACKLIST);
 331             }
 332             else
 333             {
 334                 my $artist=ID3FS::Path::Node->new($self->{db}, $TYPE_ARTIST, $name);
 335                 if($artist)
 336                 {
 337                     push(@{$self->{elements}}, $artist);
 338                     $self->state($STATE_ALBUMS);
 339                 }
 340                 else
 341                 {
 342                     $self->state($STATE_INVALID);
 343                 }
 344             }
 345         }
 346         else
 347         {
 348             print "SM: ERROR: UNKNOWN STATE: $self->{state}\n";
 349             $self->state($STATE_INVALID);
 350         }
 351     }
 352
 353     my @elements=@{$self->{elements}};
 354     # remove trailing boolean
 355     while(@elements && $self->is($TYPE_BOOL, $elements[$#elements]))
 356     {
 357         pop @elements;
 358     }
 359 #    print "\nELEMENTS: ", join(' ', map { $_->name(); } @elements), "\n";
 360     my @joins=$self->number_joins(@elements);
 361     @joins=qw(INNER) unless(@joins);
 362     $self->{joins}=\@joins;
 363 #    print "AFTER: ", join(' ', map { $_->name() . "(" . $_->{table} . ")"; } @elements), "\n";
 364 #    print "JOINS: ", join(', ', @joins), "\n";
 365     # sort elements by precedence
 366     @elements=$self->sort_elements(@elements);
 367     $self->{tagtree}=$self->elements_to_tree(\@elements);
 368 }
 369
 370 sub number_joins
 371 {
 372     my($self, @elements)=@_;
 373     my @joins=("INNER");
 374     my $table=1;
 375     my $nextjoin=undef;
 376     my $lastop=undef;
 377     return (@joins) unless(@elements);
 378     while(my $thing=shift @elements)
 379     {
 380         if($thing->type() == $TYPE_BOOL)
 381         {
 382             my $op=$thing->name();
 383             if($op eq "AND")
 384             {
 385                 $nextjoin="INNER";
 386             }
 387             elsif($op eq "NOT")
 388             {
 389                 $nextjoin="LEFT";
 390             }
 391             elsif($op eq "OR")
 392             {
 393                 # NOT/foo/OR needs an extra join
 394                 $nextjoin="INNER" if($lastop && $lastop eq "NOT");
 395             }
 396             $lastop=$op;
 397         }
 398         else
 399         {
 400             if(@elements)
 401             {
 402                 # if tag has a value, eat the tag, shifting to the value
 403                 $thing=shift(@elements) if($elements[0]->type() == $TYPE_TAG);
 404             }
 405             elsif($self->{db}->tag_has_values($thing->id()))
 406             {
 407                 # if the expression ends in a tag that has a value
 408                 # (ie we have the tag and want the value)
 409                 # use an INNER join even if we were in a NOT
 410                 $nextjoin="INNER" if($nextjoin);
 411             }
 412             if($nextjoin)
 413             {
 414                 $table++;
 415                 push(@joins, $nextjoin);
 416                 $nextjoin=undef;
 417             }
 418             $thing->table($table);
 419         }
 420     }
 421     return @joins;
 422 }
 423
 424 sub state
 425 {
 426     my($self, $newstate)=@_;
 427     if(defined($newstate))
 428     {
 429         $self->{state}=$newstate;
 430         $self->{curtagdepth}++ if($newstate == $STATE_TAG);
 431     }
 432     return $self->{state};
 433 }
 434
 435 # link up precedence-sorted list into a binary tree
 436 sub elements_to_tree
 437 {
 438     my($self, $elements)=@_;
 439     return undef unless(@$elements);
 440     my ($left, $right, $op)=(undef, undef, undef);
 441     my $thing=pop @$elements;
 442     if($self->is($TYPE_BOOL, $thing))
 443     {
 444         $right=$self->elements_to_tree($elements);
 445         if($thing->{name} ne "NOT")
 446         {
 447             $left=$self->elements_to_tree($elements);
 448         }
 449         $thing->left($left);
 450         $thing->right($right);
 451     }
 452     return $thing;
 453 }
 454
 455 # Dijkstra's shunting-yard algorithm
 456 sub sort_elements
 457 {
 458     my ($self, @input)=@_;
 459     my @opstack=();
 460     my @output=();
 461     while(my $thing = shift @input)
 462     {
 463         if($self->is($TYPE_TAG, $thing))
 464         {
 465             # Handle tag values by dropping parent
 466             if(@input && $self->is($TYPE_TAG, $input[0]))
 467             {
 468                 $thing=shift @input;
 469             }
 470             push(@output, $thing);
 471         }
 472         elsif($self->is($TYPE_BOOL, $thing))
 473         {
 474             while(@opstack &&
 475                   ($priorities{$thing->{name}} <= $priorities{$opstack[$#opstack]->{name}}))
 476             {
 477                 push(@output, pop(@opstack));
 478             }
 479             push(@opstack, $thing);
 480         }
 481     }
 482     while(@opstack)
 483     {
 484         push(@output, pop(@opstack));
 485     }
 486     return @output;
 487 }
 488
 489 sub used_tags
 490 {
 491     my($self)=@_;
 492     return() unless(defined($self->{tagtree}));
 493     return($self->{tagtree}->used_tags());
 494 }
 495
 496 sub expecting_values
 497 {
 498     my($self)=@_;
 499     my $tail=$self->tail();
 500     if($self->is($TYPE_TAG, $tail))
 501     {
 502         return($self->{db}->tag_has_values($tail->id()));
 503     }
 504 }
 505
 506 sub trailing_tag_id
 507 {
 508     my($self)=@_;
 509     my $tail=$self->tail();
 510     if($self->is($TYPE_TAG, $tail))
 511     {
 512         return($tail->id());
 513     }
 514     return undef;
 515 }
 516
 517 sub trailing_tag_parent
 518 {
 519     my($self)=@_;
 520     my $tail=$self->tail();
 521     if($self->is($TYPE_TAG, $tail))
 522     {
 523         return($tail->{parents_id});
 524     }
 525     return undef;
 526 }
 527
 528 sub tail
 529 {
 530     my($self)=@_;
 531     return($self->{elements}->[$#{$self->{elements}}]);
 532 }
 533
 534 sub is
 535 {
 536     my($self, $type, $thing)=@_;
 537     return 0 unless($thing);
 538     return 0 unless($thing->type());
 539     return 1 if($type == $thing->type());
 540     return 0;
 541 }
 542
 543 # the one before last
 544 sub tail_parent
 545 {
 546     my($self)=@_;
 547     return($self->{elements}->[($#{$self->{elements}}) - 1]);
 548 }
 549
 550 ######################################################################
 551
 552 sub tags
 553 {
 554     my($self)=@_;
 555     if(!$self->{tagtree}) # / or /NOT
 556     {
 557         my $sql="SELECT DISTINCT name FROM tags WHERE parents_id='';";
 558         return($self->{db}->cmd_firstcol($sql));
 559     }
 560     my $hasvals=$self->expecting_values();
 561     my $sql="SELECT tags.name FROM ";
 562     if($self->want_all_tags())
 563     {
 564         $sql .= "files_x_tags\n";
 565     }
 566     else
 567     {
 568         $sql .= ("(\n" .
 569                  $self->tags_subselect() .
 570                  ") AS subselect\n" .
 571                  "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n");
 572     }
 573     $sql .= "INNER JOIN tags ON files_x_tags.tags_id=tags.id\n";
 574     my @andclauses=();
 575     my $id=$self->trailing_tag_id();
 576
 577     my $parentclause= "tags.parents_id='";
 578     $parentclause .= $id if($hasvals);
 579     $parentclause .= "'";
 580     push(@andclauses, $parentclause);
 581
 582     my @used=$self->used_tags();
 583     if(@used)
 584     {
 585         push(@andclauses, "tags.id NOT IN (" . join(', ', @used) . ")");
 586     }
 587     if(@andclauses)
 588     {
 589         $sql .= "WHERE " . join(' AND ', @andclauses) . "\n";
 590     }
 591
 592     $sql .= "GROUP BY tags.name;";
 593     print "SQL(TAGS): $sql\n" if($self->{verbose});
 594     my @tagnames=$self->{db}->cmd_firstcol($sql);
 595     print("SUBNAMES: ", join(', ', @tagnames), "\n") if($self->{verbose});
 596     return(@tagnames);
 597 }
 598
 599 sub artists
 600 {
 601     my($self)=@_;
 602     if(!@{$self->{elements}}) # /ALL
 603     {
 604         my $sql="SELECT DISTINCT name FROM artists WHERE name!='';";
 605         return($self->{db}->cmd_firstcol($sql));
 606     }
 607     my $sql=$self->sql_start("artists.name");
 608     $sql .= ("INNER JOIN artists ON files.artists_id=artists.id\n" .
 609              "WHERE artists.name != ''\n" .
 610              "GROUP BY artists.name;");
 611     print "SQL(ARTISTS): $sql\n" if($self->{verbose});
 612     my @tagnames=$self->{db}->cmd_firstcol($sql);
 613     print("ARTISTS: ", join(', ', @tagnames), "\n") if($self->{verbose});
 614     return(@tagnames);
 615 }
 616
 617 sub albums
 618 {
 619     my($self)=@_;
 620     my $tail=$self->tail();
 621     if($self->is($TYPE_ARTIST, $tail))
 622     {
 623         return $self->artist_albums($tail->id());
 624     }
 625     my $sql=$self->sql_start("albums.name");
 626     $sql .= ("INNER JOIN albums ON files.albums_id=albums.id\n" .
 627              "WHERE albums.name != ''\n" .
 628              "GROUP BY albums.name;");
 629     print "SQL(ALBUMS): \n$sql\n" if($self->{verbose});
 630     my @names=$self->{db}->cmd_firstcol($sql);
 631     print("ALBUMS: ", join(', ', @names), "\n") if($self->{verbose});
 632     return(@names);
 633 }
 634
 635 sub artist_albums
 636 {
 637     my($self, $artist_id)=@_;
 638     my $sql=$self->sql_start("albums.name");
 639     $sql .= ("INNER JOIN albums ON albums.id=files.albums_id\n" .
 640              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 641              "WHERE artists.id=? and albums.name <> ''\n" .
 642              "GROUP BY albums.name\n");
 643     print "ARTIST_ALBUMS SQL: $sql\n" if($self->{verbose});
 644     my @albums=$self->{db}->cmd_firstcol($sql, $artist_id);
 645     print("ALBUMS: ", join(', ', @albums), "\n") if($self->{verbose});
 646     return(@albums);
 647 }
 648
 649 sub artist_tracks
 650 {
 651     my($self, $artist_id)=@_;
 652     my $sql=$self->sql_start("files.name");
 653     $sql .= ("INNER JOIN artists ON artists.id=files.artists_id\n" .
 654              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 655              "WHERE artists.id=? AND albums.name=''\n" .
 656              "GROUP BY files.name\n");
 657     print "ARTIST_TRACKS SQL: $sql\n" if($self->{verbose});
 658     my @names=$self->{db}->cmd_firstcol($sql, $artist_id);
 659     print("ARTISTTRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 660     return(@names);
 661 }
 662
 663 sub album_tracks
 664 {
 665     my($self, $artist_id, $album_id)=@_;
 666     my $sql=("SELECT files.name FROM files\n" .
 667              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 668              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 669              "WHERE artists.id=? AND albums.id=?\n" .
 670              "GROUP BY files.name\n");
 671     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n" if($self->{verbose});
 672     my @names=$self->{db}->cmd_firstcol($sql, $artist_id, $album_id);
 673     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 674     return(@names);
 675 }
 676
 677 sub tracks
 678 {
 679     my($self)=@_;
 680     my $tail=$self->tail();
 681     if($self->is($TYPE_ARTIST, $tail))
 682     {
 683         return $self->artist_tracks($tail->id());
 684     }
 685     elsif($self->is($TYPE_ALBUM, $tail))
 686     {
 687         my $artist_id=0;
 688         my $artist=$self->tail_parent();
 689         if($self->is($TYPE_ARTIST, $artist))
 690         {
 691             # should always happen
 692             $artist_id=$artist->id();
 693         }
 694         return $self->album_tracks($artist_id, $tail->id());
 695     }
 696     my $sql=$self->sql_start("files.name");
 697     $sql .= "INNER JOIN artists ON files.artists_id=artists.id\n";
 698     if($self->{components}->[$#{$self->{components}}] eq $PATH_NOARTIST)
 699     {
 700         $sql .= "WHERE artists.name =''\n";
 701     }
 702     $sql .= "GROUP BY files.name;";
 703     print "TRACKS SQL($self->{path}): $sql\n" if($self->{verbose});
 704     my @names=$self->{db}->cmd_firstcol($sql);
 705     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 706     return(@names);
 707 }
 708
 709 sub filename
 710 {
 711     my($self, $mountpoint)=@_;
 712     my $tail=$self->tail();
 713     if($self->is($TYPE_FILE, $tail))
 714     {
 715         my $id=$tail->id();
 716         my $sql=("SELECT paths.name, files.name FROM files\n" .
 717                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 718                  "WHERE files.id=?\n" .
 719                  "GROUP BY paths.name, files.name");
 720         print "FILENAME SQL: $sql\n" if($self->{verbose});
 721         my ($path, $name)=$self->{db}->cmd_onerow($sql, $id);
 722         return($self->{db}->relativise($path, $name, $mountpoint, $self->{path}));
 723     }
 724     # should never happen
 725     return "ERROR";
 726 }
 727
 728 sub tags_subselect
 729 {
 730     my($self)=@_;
 731     my $hasvals=$self->expecting_values();
 732     my $tree=$self->{tagtree};
 733 #    use Data::Dumper;
 734 #    print Dumper $tree;
 735     my ($sqlclause, @joins)=$tree->to_sql($hasvals) if($tree);
 736     my $sql="\tSELECT fxt1.files_id FROM tags t1";
 737     my @crosses=();
 738     my @inners=();
 739     @joins=@{$self->{joins}};
 740     for(my $i=0; $i <= $#joins; $i++)
 741     {
 742         my $cnt=$i+1;
 743         my $join=$joins[$i];
 744         my $inner=("\t$join JOIN files_x_tags fxt$cnt ON " .
 745                    "t${cnt}.id=fxt${cnt}.tags_id");
 746         if($i > 0)
 747         {
 748             push(@crosses, "CROSS JOIN tags t$cnt");
 749             $inner .= " AND fxt1.files_id=fxt${cnt}.files_id";
 750         }
 751         push(@inners, $inner);
 752     }
 753     $sql .= ("\n\t" . join(" ", @crosses)) if(@crosses);
 754     $sql .= ("\n" . join("\n", @inners)) if(@inners);
 755     $sql .= "\n\tWHERE $sqlclause" if($sqlclause);
 756     $sql .= "\n\tGROUP BY fxt1.files_id\n";
 757     return $sql;
 758 }
 759
 760 sub sql_start
 761 {
 762     my($self, $tables)=@_;
 763     my $sql="SELECT $tables FROM ";
 764     if($self->{in_all})
 765     {
 766         $sql .= "files\n";
 767     }
 768     else
 769     {
 770         $sql .= ("(\n" .
 771                  $self->tags_subselect() .
 772                  ") AS subselect\n" .
 773                  "INNER JOIN files ON subselect.files_id=files.id\n");
 774     }
 775     return $sql;
 776 }
 777
 778 # we just filter $ALLTRACKS, $NOARTIST and $NOALBUM
 779 # filtering tags properly requires up to four levels of recursion
 780 # (tag/tagval/AND/NOT) and is too slow
 781 sub filter
 782 {
 783     my($self, @dirs)=@_;
 784     return(@dirs) unless($ENABLE_FILTER);
 785     my $base=$self->{path};
 786     my @outdirs=();
 787     for my $dir (@dirs)
 788     {
 789         push(@outdirs, $dir) unless($self->empty("$base/$dir"));
 790     }
 791     return(@outdirs);
 792 }
 793
 794 sub empty
 795 {
 796     my($self, $dir)=@_;
 797     my $path=ID3FS::Path->new($self->{db}, $dir, $self->{verbose},
 798                               ($self->{maxtagdepth} - $self->{curtagdepth}));
 799     return 1 unless($path->isvalid());
 800     my($subdirs,$subfiles)=$path->dirents();
 801     return 0 if(@$subfiles || @$subdirs);
 802     return 1;
 803 }
 804
 805 # if path is .../OR/ or .../OR/NOT or .../AND/NOT
 806 sub want_all_tags
 807 {
 808     my($self)=@_;
 809     my $tail=$self->tail();
 810     return 0 unless($tail);
 811     my $parent=$self->tail_parent();
 812     my $parent_valid = ($parent && $parent->type() == $TYPE_BOOL);
 813     if($tail->type() == $TYPE_BOOL)
 814     {
 815         return 1 if($tail->name() eq "OR");
 816         return 0 unless($tail->name() eq "NOT");
 817         return 0 unless($parent_valid);
 818         return 1 if($parent->name() eq "OR");
 819         return 1 if($parent->name() eq "AND");
 820     }
 821     elsif($tail->type() == $TYPE_TAG)
 822     {
 823         return 0 unless($parent_valid);
 824         return 1 if($parent->name() eq "NOT");
 825     }
 826     return 0;
 827 }
 828
 829 1;