lib/ID3FS/Path.pm

   1 package ID3FS::Path;
   2
   3 use strict;
   4 use warnings;
   5 use ID3FS::Path::Node;
   6
   7 our ($STATE_INVALID, $STATE_ROOT, $STATE_TAG, $STATE_TAGVAL,
   8      $STATE_BOOLEAN, $STATE_ALBUMS, $STATE_TRACKLIST,
   9      $STATE_FILE, $STATE_ALL)=(0..8);
  10
  11 our %priorities=( "OR" => 0, "AND" => 1, "NOT" => 2 );
  12
  13 our $PATH_ALLTRACKS= "TRACKS";
  14 our $PATH_NOARTIST = "NOARTIST";
  15 our $PATH_NOALBUM  = "NOALBUM";
  16
  17 our $ENABLE_FILTER = 1;
  18
  19 sub new
  20 {
  21     my $proto=shift;
  22     my $class=ref($proto) || $proto;
  23     my $self={};
  24     bless($self,$class);
  25
  26     $self->{elements}=[];
  27     $self->{db}=shift;
  28     $self->{path}=shift;
  29     $self->{verbose}=shift;
  30     $self->{maxtagdepth}=shift;
  31     $self->{curtagdepth}=0;
  32     $self->{path} =~ s/\/\//\//g; # drop doubled slashes
  33
  34     $self->parse();
  35 #    print "STATE: ", $self->state(), "\n";
  36     return $self;
  37 }
  38
  39 sub isdir
  40 {
  41     my($self)=@_;
  42     if(($self->state() == $STATE_FILE) ||
  43        ($self->state() == $STATE_INVALID))
  44     {
  45         return 0;
  46     }
  47     return 1;
  48 }
  49
  50 sub isfile
  51 {
  52     my($self)=@_;
  53     return($self->state() == $STATE_FILE);
  54 }
  55
  56 sub isvalid
  57 {
  58     my($self)=@_;
  59     return($self->state() != $STATE_INVALID);
  60 }
  61
  62 sub dest
  63 {
  64     my($self, $mountpoint)=@_;
  65     if($self->state() == $STATE_FILE)
  66     {
  67         return $self->filename($mountpoint);
  68     }
  69     return "ERROR"; #should never happen?
  70 }
  71
  72 sub dirents
  73 {
  74     my($self)=@_;
  75     my @dents=();
  76     my @fents=();
  77     my $state=$self->state();
  78 #    print "DIRENTS: STATE: $state\n";
  79 #    print "DIRENTS: FILE: $self->{path}\n";
  80     if($state==$STATE_ALL)
  81     {
  82         @dents=($PATH_ALLTRACKS, $PATH_NOARTIST, $self->artists());
  83     }
  84     elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
  85     {
  86         if($state==$STATE_TAG && $self->at("tag") &&
  87            $self->{db}->tag_has_values($self->tail()->id()))
  88         {
  89             @dents=$self->tags();
  90         }
  91         else
  92         {
  93             if($self->{maxtagdepth} && ($self->{curtagdepth} < $self->{maxtagdepth}))
  94             {
  95                 @dents=qw(AND OR);
  96             }
  97             push(@dents, ($ENABLE_FILTER ?
  98                           $self->filter($PATH_ALLTRACKS, $PATH_NOARTIST) :
  99                           ($PATH_ALLTRACKS, $PATH_NOARTIST)));
 100             push(@dents, $self->artists());
 101         }
 102     }
 103     elsif($state==$STATE_BOOLEAN)
 104     {
 105         my $parent=$self->tail();
 106         unless($self->is("boolean", $parent) &&
 107                $parent->{name} eq "NOT")
 108         {
 109             @dents=("NOT");
 110         }
 111         push(@dents,$self->tags());
 112     }
 113     elsif($state==$STATE_ROOT)
 114     {
 115         @dents=(qw(ALL NOT), $self->tags());
 116     }
 117     elsif($state==$STATE_ALBUMS)
 118     {
 119         @dents=($self->filter($PATH_ALLTRACKS, $PATH_NOALBUM), $self->albums());
 120     }
 121     elsif($state==$STATE_TRACKLIST)
 122     {
 123         @fents=$self->tracks();
 124     }
 125     else
 126     {
 127         print "DIRENTS: UNHANDLED STATE: $state\n";
 128     }
 129     return(\@dents, \@fents);
 130 }
 131
 132 sub parse
 133 {
 134     my($self)=@_;
 135     @{$self->{components}}=split(/\//, $self->{path});
 136     shift @{$self->{components}}; # drop empty field before leading /
 137 #    print "PATH: $self->{path}\n";
 138     $self->state($STATE_ROOT);
 139     return if($self->{path} eq "/");
 140     my @parts=@{$self->{components}};
 141     my($tag, $tagval);
 142     $self->{elements}=[];
 143     $self->{in_all}=0;
 144     my $root_not=0;
 145     my $tags_seen=0;
 146     while(defined(my $name=shift @parts))
 147     {
 148 #       print "NAME: $name\n";
 149         my $state=$self->state();
 150         if($state==$STATE_INVALID)
 151         {
 152 #           print "SM: INVALID: $name\n";
 153             return;
 154         }
 155         elsif($state==$STATE_ROOT)
 156         {
 157 #           print "SM: ROOT: $name\n";
 158             if($name eq "ALL")
 159             {
 160                 $self->{in_all}=1;
 161                 $self->state($STATE_ALL);
 162             }
 163             elsif($name eq "NOT")
 164             {
 165                 $root_not=1;
 166                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 167                 $self->state($STATE_BOOLEAN);
 168             }
 169             else
 170             {
 171                 $tag=ID3FS::Path::Node->new($self->{db},"tag", $name);
 172                 if($tag)
 173                 {
 174                     push(@{$self->{elements}}, $tag);
 175                     $tags_seen++;
 176                     $self->state($STATE_TAG);
 177                 }
 178                 else
 179                 {
 180                     $self->state($STATE_INVALID);
 181                 }
 182             }
 183         }
 184         elsif($state==$STATE_TAG || $state==$STATE_TAGVAL)
 185         {
 186             my $tag=$self->tail();
 187 #           print "SM: TAG/TAGVAL($state): $name\n";
 188             if($state==$STATE_TAG && $self->is("tag", $tag) &&
 189                $self->{db}->tag_has_values($tag->id()))
 190             {
 191 #               print "Parsing: parent: $tag->id()\n";
 192                 my $tagval=ID3FS::Path::Node->new($self->{db}, "tag", $name, $tag->id());
 193                 if(defined($tagval))
 194                 {
 195                     $self->state($STATE_TAGVAL);
 196                     # stay in tag state
 197                     push(@{$self->{elements}}, $tagval);
 198                 }
 199                 else
 200                 {
 201                     $self->state($STATE_INVALID);
 202                 }
 203             }
 204             elsif($name eq $PATH_ALLTRACKS)
 205             {
 206                 $self->state($STATE_TRACKLIST);
 207             }
 208             elsif($name eq $PATH_NOARTIST)
 209             {
 210                 $self->state($STATE_TRACKLIST);
 211             }
 212             elsif($name eq "AND")
 213             {
 214                 $self->state($STATE_BOOLEAN);
 215                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 216             }
 217             elsif($name eq "OR")
 218             {
 219                 $self->state($STATE_BOOLEAN);
 220                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 221             }
 222             else
 223             {
 224                 my $artist=ID3FS::Path::Node->new($self->{db}, "artist", $name);
 225                 if($artist)
 226                 {
 227                     push(@{$self->{elements}}, $artist);
 228                     $self->state($STATE_ALBUMS);
 229                 }
 230                 else
 231                 {
 232                     $self->state($STATE_INVALID);
 233                 }
 234             }
 235         }
 236         elsif($state==$STATE_BOOLEAN)
 237         {
 238 #           print "SM: BOOLEAN: $name\n";
 239             my $parent=$self->tail();
 240             my $allownot=1;
 241             if($self->is("boolean", $parent) &&
 242                $parent->{name} eq "NOT")
 243             {
 244                 $allownot=0;
 245             }
 246             if($allownot && $name eq "NOT")
 247             {
 248                 $self->state($STATE_BOOLEAN);
 249                 push(@{$self->{elements}}, ID3FS::Path::Node->new($self->{db}, "boolean", $name));
 250             }
 251             else
 252             {
 253                 my $tag=ID3FS::Path::Node->new($self->{db}, "tag", $name);
 254                 if($tag)
 255                 {
 256                     push(@{$self->{elements}}, $tag);
 257                     $tags_seen++;
 258                     $self->state($STATE_TAG);
 259                 }
 260                 else
 261                 {
 262                     $self->state($STATE_INVALID);
 263                 }
 264             }
 265         }
 266         elsif($state==$STATE_ALBUMS)
 267         {
 268 #           print "SM: ALBUM: $name\n";
 269             if($name eq $PATH_ALLTRACKS)
 270             {
 271                 $self->state($STATE_TRACKLIST);
 272             }
 273             elsif($name eq $PATH_NOALBUM)
 274             {
 275                 $self->state($STATE_TRACKLIST);
 276             }
 277             else
 278             {
 279                 my $album=ID3FS::Path::Node->new($self->{db}, "album", $name);
 280                 if($album)
 281                 {
 282                     push(@{$self->{elements}}, $album);
 283                     $self->state($STATE_TRACKLIST);
 284                 }
 285                 else
 286                 {
 287                     $self->state($STATE_INVALID);
 288                 }
 289             }
 290         }
 291         elsif($state==$STATE_TRACKLIST)
 292         {
 293 #           print "SM: TRACKLIST: $name\n";
 294             my $track=ID3FS::Path::Node->new($self->{db}, "file", $name);
 295             if($track)
 296             {
 297                 push(@{$self->{elements}}, $track);
 298                 $self->state($STATE_FILE);
 299             }
 300             else
 301             {
 302                 $self->state($STATE_INVALID);
 303             }
 304         }
 305         elsif($state==$STATE_FILE)
 306         {
 307 #           print "SM: FILE: $name\n";
 308             # Can't have anything after a filename
 309             $self->state($STATE_INVALID);
 310         }
 311         elsif($state==$STATE_ALL)
 312         {
 313             if($name eq $PATH_ALLTRACKS)
 314             {
 315                 $self->state($STATE_TRACKLIST);
 316             }
 317             elsif($name eq $PATH_NOARTIST)
 318             {
 319                 $self->state($STATE_TRACKLIST);
 320             }
 321             else
 322             {
 323                 my $artist=ID3FS::Path::Node->new($self->{db}, "artist", $name);
 324                 if($artist)
 325                 {
 326                     push(@{$self->{elements}}, $artist);
 327                     $self->state($STATE_ALBUMS);
 328                 }
 329                 else
 330                 {
 331                     $self->state($STATE_INVALID);
 332                 }
 333             }
 334         }
 335         else
 336         {
 337             print "SM: ERROR: UNKNOWN STATE: $self->{state}\n";
 338             $self->state($STATE_INVALID);
 339         }
 340     }
 341
 342     # remove trailing boolean
 343     my @elements=@{$self->{elements}};
 344     while(@elements && $self->is("boolean", $elements[$#elements]))
 345     {
 346         pop @elements;
 347     }
 348     # sort elements by precedence
 349     @elements=$self->sort_elements(@elements);
 350     $self->{tagtree}=$self->elements_to_tree(\@elements);
 351     if($self->{tagtree})
 352     {
 353 #       my ($conditions, @joins)=$self->{tagtree}->to_sql();
 354 #       print "CONDITIONS(", scalar(@joins), "): ", $conditions, "\n";
 355     }
 356 }
 357
 358 sub state
 359 {
 360     my($self, $newstate)=@_;
 361     if(defined($newstate))
 362     {
 363         $self->{state}=$newstate;
 364         $self->{curtagdepth}++ if($newstate == $STATE_TAG);
 365     }
 366     return $self->{state};
 367 }
 368
 369 sub elements_to_tree
 370 {
 371     my($self, $elements)=@_;
 372     return undef unless(@$elements);
 373     my ($left, $right, $op)=(undef, undef, undef);
 374     my $thing=pop @$elements;
 375     if($self->is("boolean", $thing))
 376     {
 377         $right=$self->elements_to_tree($elements);
 378         if($thing->{name} ne "NOT")
 379         {
 380             $left=$self->elements_to_tree($elements);
 381         }
 382         $thing->left($left);
 383         $thing->right($right);
 384     }
 385     return $thing;
 386 }
 387
 388 # Dijkstra's shunting-yard algorithm
 389 sub sort_elements
 390 {
 391     my ($self, @input)=@_;
 392     my @opstack=();
 393     my @output=();
 394 #    print "INPUT: ", join(', ', map { $_->{name}; } @input), "\n";
 395     while(my $thing = shift @input)
 396     {
 397         if($self->is("tag", $thing))
 398         {
 399             # Handle tag values by dropping parent
 400             if(@input && $self->is("tag", $input[0]))
 401             {
 402                 $thing=shift @input;
 403             }
 404             push(@output, $thing);
 405         }
 406         elsif($self->is("boolean", $thing))
 407         {
 408             # bool
 409             while(@opstack &&
 410                   ($priorities{$thing->{name}} <= $priorities{$opstack[$#opstack]->{name}}))
 411             {
 412                 push(@output, pop(@opstack));
 413             }
 414             push(@opstack, $thing);
 415         }
 416     }
 417     while(@opstack)
 418     {
 419         push(@output, pop(@opstack));
 420     }
 421 #    print "STACK: ", join(', ', map { $_->{name}; } @output), "\n";
 422     return @output;
 423 }
 424
 425 sub used_tags
 426 {
 427     my($self)=@_;
 428     return() unless(defined($self->{tagtree}));
 429     return($self->{tagtree}->used_tags());
 430 }
 431
 432 sub expecting_values
 433 {
 434     my($self)=@_;
 435     my $tail=$self->tail();
 436     if($self->is("tag", $tail))
 437     {
 438         return($self->{db}->tag_has_values($tail->id()));
 439     }
 440 }
 441
 442 sub trailing_tag_id
 443 {
 444     my($self)=@_;
 445     my $tail=$self->tail();
 446     if($self->is("tag", $tail))
 447     {
 448         return($tail->id());
 449     }
 450     return undef;
 451 }
 452
 453 sub trailing_tag_parent
 454 {
 455     my($self)=@_;
 456     my $tail=$self->tail();
 457     if($self->is("tag", $tail))
 458     {
 459         return($tail->{parents_id});
 460     }
 461     return undef;
 462 }
 463
 464 sub tail
 465 {
 466     my($self)=@_;
 467     return($self->{elements}->[$#{$self->{elements}}]);
 468 }
 469
 470 sub at
 471 {
 472     my($self, $type)=@_;
 473     return($self->is($type, $self->tail()));
 474 }
 475
 476 sub is
 477 {
 478     my($self, $type, $thing)=@_;
 479     return 0 unless($thing);
 480     return 0 unless($thing->type());
 481     return 1 if($type eq $thing->type());
 482     return 0;
 483 }
 484
 485 # the one before last
 486 sub tail_parent
 487 {
 488     my($self)=@_;
 489     return($self->{elements}->[($#{$self->{elements}}) - 1]);
 490 }
 491
 492 ######################################################################
 493
 494 sub tags
 495 {
 496     my($self)=@_;
 497     if(!$self->{tagtree}) # / or /NOT
 498     {
 499         my $sql="SELECT DISTINCT name FROM tags WHERE parents_id='';";
 500         return($self->{db}->cmd_firstcol($sql));
 501     }
 502     my $hasvals=$self->expecting_values();
 503     my $parent=$self->trailing_tag_parent();
 504 #    print "THASVALS: $hasvals\n";
 505 #    print "TPARENT: ", (defined($parent)? $parent : "NO"), "\n";
 506     my @ids=();
 507     my $sql=("SELECT tags.name FROM (\n" .
 508              $self->tags_subselect() .
 509              ") AS subselect\n" .
 510              "INNER JOIN files_x_tags ON subselect.files_id=files_x_tags.files_id\n" .
 511              "INNER JOIN tags ON files_x_tags.tags_id=tags.id\n");
 512     my @andclauses=();
 513     my $id=$self->trailing_tag_id();
 514
 515     my $parentclause= "tags.parents_id='";
 516     if($hasvals)
 517     {
 518         $parentclause .= $id;
 519     }
 520     elsif($parent)
 521     {
 522         $parentclause .= $parent;
 523     }
 524     $parentclause .= "'";
 525     push(@andclauses, $parentclause);
 526
 527     my @used=$self->used_tags();
 528     if(@used)
 529     {
 530         push(@andclauses, "tags.id NOT IN (" . join(', ', @used) . ")");
 531     }
 532     if(@andclauses)
 533     {
 534         $sql .= "WHERE " . join(' AND ', @andclauses) . "\n";
 535     }
 536
 537     $sql .= "GROUP BY tags.name;";
 538     print "SQL(TAGS): $sql\n" if($self->{verbose});
 539     my @tagnames=$self->{db}->cmd_firstcol($sql);
 540     print("SUBNAMES: ", join(', ', @tagnames), "\n") if($self->{verbose});
 541     return(@tagnames);
 542 }
 543
 544 sub artists
 545 {
 546     my($self)=@_;
 547     if(!@{$self->{elements}}) # /ALL
 548     {
 549         my $sql="SELECT DISTINCT name FROM artists WHERE name!='';";
 550         return($self->{db}->cmd_firstcol($sql));
 551     }
 552     my @ids=();
 553     my $sql=$self->sql_start("artists.name");
 554     $sql .= ("INNER JOIN artists ON files.artists_id=artists.id\n" .
 555              "WHERE artists.name != ''\n" .
 556              "GROUP BY artists.name;");
 557     print "SQL(ARTISTS): $sql\n" if($self->{verbose});
 558     my @tagnames=$self->{db}->cmd_firstcol($sql);
 559     print("ARTISTS: ", join(', ', @tagnames), "\n") if($self->{verbose});
 560     return(@tagnames);
 561 }
 562
 563 sub albums
 564 {
 565     my($self)=@_;
 566     my @ids=();
 567     my $tail=$self->tail();
 568     if($self->is("artist", $tail))
 569     {
 570         return $self->artist_albums($tail->id());
 571     }
 572     my $sql=$self->sql_start("albums.name");
 573     $sql .= ("INNER JOIN albums ON files.albums_id=albums.id\n" .
 574              "WHERE albums.name != ''\n" .
 575              "GROUP BY albums.name;");
 576     print "SQL(ALBUMS): \n$sql\n" if($self->{verbose});
 577     my @names=$self->{db}->cmd_firstcol($sql);
 578     print("ALBUMS: ", join(', ', @names), "\n") if($self->{verbose});
 579     return(@names);
 580 }
 581
 582 sub artist_albums
 583 {
 584     my($self, $artist_id)=@_;
 585     my $sql=$self->sql_start("albums.name");
 586     $sql .= ("INNER JOIN albums ON albums.id=files.albums_id\n" .
 587              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 588              "WHERE artists.id=? and albums.name <> ''\n" .
 589              "GROUP BY albums.name\n");
 590     print "ARTIST_ALBUMS SQL: $sql\n" if($self->{verbose});
 591     my @albums=$self->{db}->cmd_firstcol($sql, $artist_id);
 592     print("ALBUMS: ", join(', ', @albums), "\n") if($self->{verbose});
 593     return(@albums);
 594 }
 595
 596 sub artist_tracks
 597 {
 598     my($self, $artist_id)=@_;
 599     my $sql=$self->sql_start("files.name");
 600     $sql .= ("INNER JOIN artists ON artists.id=files.artists_id\n" .
 601              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 602              "WHERE artists.id=? AND albums.name=''\n" .
 603              "GROUP BY files.name\n");
 604     print "ARTIST_TRACKS SQL: $sql\n" if($self->{verbose});
 605     my @names=$self->{db}->cmd_firstcol($sql, $artist_id);
 606     print("ARTISTTRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 607     return(@names);
 608 }
 609
 610 sub album_tracks
 611 {
 612     my($self, $artist_id, $album_id)=@_;
 613     my $sql=("SELECT files.name FROM files\n" .
 614              "INNER JOIN albums  ON albums.id=files.albums_id\n" .
 615              "INNER JOIN artists ON artists.id=files.artists_id\n" .
 616              "WHERE artists.id=? AND albums.id=?\n" .
 617              "GROUP BY files.name\n");
 618     print "ALBUM_TRACKS SQL($artist_id, $album_id): $sql\n" if($self->{verbose});
 619     my @names=$self->{db}->cmd_firstcol($sql, $artist_id, $album_id);
 620     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 621     return(@names);
 622 }
 623
 624 sub tracks
 625 {
 626     my($self)=@_;
 627     my $tail=$self->tail();
 628     if($self->is("artist", $tail))
 629     {
 630         return $self->artist_tracks($tail->id());
 631     }
 632     elsif($self->is("album", $tail))
 633     {
 634         my $artist_id=0;
 635         my $artist=$self->tail_parent();
 636         if($self->is("artist", $artist))
 637         {
 638             # should always happen
 639             $artist_id=$artist->id();
 640         }
 641         return $self->album_tracks($artist_id, $tail->id());
 642     }
 643     my $sql=$self->sql_start("files.name");
 644     $sql .= "INNER JOIN artists ON files.artists_id=artists.id\n";
 645     if($self->{components}->[$#{$self->{components}}] eq $PATH_NOARTIST)
 646     {
 647         $sql .= "WHERE artists.name =''\n";
 648     }
 649     $sql .= "GROUP BY files.name;";
 650     print "TRACKS SQL($self->{path}): $sql\n" if($self->{verbose});
 651     my @names=$self->{db}->cmd_firstcol($sql);
 652     print("TRACKS: ", join(', ', @names), "\n") if($self->{verbose});
 653     return(@names);
 654 }
 655
 656 sub filename
 657 {
 658     my($self, $mountpoint)=@_;
 659     my $tail=$self->tail();
 660     if($self->is("file", $tail))
 661     {
 662         my $id=$tail->id();
 663         my $sql=("SELECT paths.name, files.name FROM files\n" .
 664                  "INNER JOIN paths ON files.paths_id=paths.id\n" .
 665                  "WHERE files.id=?\n" .
 666                  "GROUP BY paths.name, files.name");
 667         print "FILENAME SQL: $sql\n" if($self->{verbose});
 668         my ($path, $name)=$self->{db}->cmd_onerow($sql, $id);
 669         my $id3fs_path=join('/', map { $_->{name}; }  @{$self->{elements}});
 670         return($self->{db}->relativise($path, $name, $mountpoint));
 671     }
 672     # should never happen
 673     return "ERROR";
 674 }
 675
 676 sub tags_subselect
 677 {
 678     my($self)=@_;
 679     my $hasvals=$self->expecting_values();
 680     if($self->{in_all})
 681     {
 682         return "\tSELECT id FROM files AS files_id\n";
 683     }
 684     my $tree=$self->{tagtree};
 685     # FIXME
 686     print "UNDEF!!\n" unless($self->{tagtree});
 687     my $parent=$self->trailing_tag_parent();
 688
 689 #    print "ELEMENTS: ", join('/', map { $_->{name}; } @{$self->{elements}}), "\n";
 690 #    print "TREE: ", $tree->print(), "\n";
 691     my $tag=undef;
 692     if($hasvals)
 693     {
 694         $tag=$self->trailing_tag_id();
 695 #       print "Trailing id: $tag\n";
 696     }
 697     my ($sqlclause, @joins)=(undef, ());
 698     ($sqlclause, @joins) = $tree->to_sql($hasvals) if($tree);
 699 #    print "SQL(" . scalar(@joins) ."): $sqlclause\n";
 700     my $sql="\tSELECT fxt1.files_id FROM tags t1";
 701     my @crosses=();
 702     my @inners=();
 703 #    $joinsneeded++ if($tag);
 704     for(my $i=0; $i <= $#joins; $i++)
 705     {
 706         my $cnt=$i+1;
 707         my $join=$joins[$i];
 708         my $inner=("\t$join JOIN files_x_tags fxt$cnt ON " .
 709                    "t${cnt}.id=fxt${cnt}.tags_id");
 710         if($i > 0)
 711         {
 712             push(@crosses, "CROSS JOIN tags t$cnt");
 713             $inner .= " AND fxt1.files_id=fxt${cnt}.files_id";
 714         }
 715         push(@inners, $inner);
 716     }
 717     $sql .= ("\n\t" . join(" ", @crosses)) if(@crosses);
 718     $sql .= ("\n" . join("\n", @inners)) if(@inners);
 719     $sql .= "\n\tWHERE $sqlclause" if($sqlclause);
 720 #    if($tag)
 721 #    {
 722 #       $sql .= " AND t${joinsneeded}.parents_id='$tag'";
 723 #    }
 724     $sql .= "\n\tGROUP BY fxt1.files_id\n";
 725     return $sql;
 726 }
 727
 728 sub sql_start
 729 {
 730     my($self, $tables)=@_;
 731     my $sql="SELECT $tables FROM ";
 732     if($self->{in_all})
 733     {
 734         $sql .= "files\n";
 735     }
 736     else
 737     {
 738         $sql .= ("(\n" .
 739                  $self->tags_subselect() .
 740                  ") AS subselect\n" .
 741                  "INNER JOIN files ON subselect.files_id=files.id\n");
 742     }
 743     return $sql;
 744 }
 745
 746
 747 sub constraints_tag_list
 748 {
 749     my($self, @constraints)=@_;
 750     my $lasttag=undef;
 751     my @tags=();
 752     my @tags_vals=();
 753     for my $constraint (@constraints)
 754     {
 755 #       print ref($constraint), ": ", $constraint->{name}, "\n";
 756         if($self->is("tag", $constraint))
 757         {
 758             if(defined($lasttag))
 759             {
 760 #               print "TAGVAL\n";
 761                 push(@tags_vals, [$lasttag, $constraint->id()]) if defined($constraint->id());
 762                 $lasttag=undef;
 763             }
 764             elsif($self->tag_has_values($constraint->id()))
 765             {
 766 #               print "HASVALUES\n";
 767                 $lasttag=$constraint->id() if defined($constraint->id());
 768             }
 769             else
 770             {
 771 #               print "NOVALUES\n";
 772                 push(@tags, $constraint->id()) if(defined($constraint->id()));
 773             }
 774         }
 775     }
 776     @tags=map{ "\"$_\""; } @tags;
 777     @tags_vals=map( { [ map({ "\"$_\""; } @$_ ) ] } @tags_vals);
 778     $lasttag="\"$lasttag\"" if defined($lasttag);
 779     return(\@tags, \@tags_vals, $lasttag);
 780 }
 781
 782 # we just filter $ALLTRACKS, $NOARTIST and $NOALBUM
 783 # filtering tags properly requires up to four levels of recursion
 784 # (tag/tagval/AND/NOT) and is too slow
 785 sub filter
 786 {
 787     my($self, @dirs)=@_;
 788     my $base=$self->{path};
 789     my @outdirs=();
 790     for my $dir (@dirs)
 791     {
 792 #       print "\nFILTER (",$self->state(), "): $base / $dir\n";
 793         if($self->empty("$base/$dir"))
 794         {
 795 #           print "empty: $base / $dir\n";
 796         }
 797         else
 798         {
 799 #           print "non-empty, accepting: $base / $dir\n";
 800             push(@outdirs, $dir);
 801         }
 802     }
 803     return(@outdirs);
 804 }
 805
 806 sub empty
 807 {
 808     my($self, $dir)=@_;
 809     my $path=ID3FS::Path->new($self->{db}, $dir, $self->{verbose},
 810                               ($self->{maxtagdepth} - $self->{curtagdepth}));
 811     return 1 unless($path->isvalid());
 812     my($subdirs,$subfiles)=$path->dirents();
 813     return 0 if(@$subfiles || @$subdirs);
 814     return 1;
 815 }
 816
 817 1;